topic Re: Is there a way to set the plot ranges for all plots in a platform the same? in Discussions

Is there a way to set the plot ranges for all plots in a platform the same?

TheDude — Sun, 11 Jun 2023 11:26:06 GMT

I think the subject is self-explanatory:

I run a platform and have many generated plots. Now in many cases it makes a lot of sense to have all the plot axes ranges to be the same. It is very tedious to do this by hand.

I tried holding the Ctrl key when changing the axes on one plot, but that does not propagate to the other plots.

Re: Is there a way to set the plot ranges for all plots in a platform the same?

jthi — Thu, 21 Jul 2022 19:26:45 GMT

Not sure if it can be done interactively, but it can be scripted. Here is fairly simple example

Names Default To Here(1);
dt = Open("$SAMPLE_DATA/Semiconductor Capability.jmp");

dist = dt << Distribution(
	Continuous Distribution(Column(:NPN1), Process Capability(0)),
	Histograms Only,
	By(:lot_id)
);

wait(1);
(dist << XPath("//AxisBox")) << Min(0);

Re: Is there a way to set the plot ranges for all plots in a platform the same?

David_Burnham — Thu, 21 Jul 2022 19:55:04 GMT

I think the answer probably depends on which platform that you refer to. For the distribution there is a uniform scaling option, shown here in the associated JSL, but can be turned on from the red triangle.

Distribution(
	Uniform Scaling( 1 ),
	Continuous Distribution( Column( :NPN1 ), Process Capability( 0 ) ),
	Histograms Only,
	Where( :lot_id == "lot01" )
);

Re: Is there a way to set the plot ranges for all plots in a platform the same?

Hegedus1 — Thu, 21 Jul 2022 20:26:37 GMT

Hi,

I propagated the settings for the ranges successfully but perhaps slightly differently. My method:

1. Set the ranges in in one graph

2. Right -Click on the axis and "Edit > Copy Axis Settings"

3. Ctrl-Right-Click "Edit>Paste Axis Settings"

The simple ctrl - Axis settings doesn't do it as you have already found out.

Andy

Re: Is there a way to set the plot ranges for all plots in a platform the same?

TheDude — Thu, 21 Jul 2022 20:52:28 GMT

Hi David, specifically, I am using the Measurement Systems Analysis (Gauge R&R) platform.

Re: Is there a way to set the plot ranges for all plots in a platform the same?

TheDude — Thu, 21 Jul 2022 20:53:10 GMT

Andy, this is almost as tedious as changing the axes limits by hand one by one.

Re: Is there a way to set the plot ranges for all plots in a platform the same?

mikedriscoll — Thu, 21 Jul 2022 21:27:42 GMT

The 'ctrl' in step 3 will apply the settings to all plots in the window. It's pretty quick and likely the fastest way to do it without scripting.

Re: Is there a way to set the plot ranges for all plots in a platform the same?

David_Burnham — Thu, 21 Jul 2022 22:04:33 GMT

As has been pointed out, the interactive method is to use the control key whilst selecting the option to paste axis settings (having previously copied the settings).

With scripting you can do something like this:

names default to here(1);

open("$SAMPLE_DATA/Variability Data/3 Factors Nested & Crossed.jmp");

vc = Variability Chart( Y( :Y ), X( :Instrument, :Part ), By( :Operator ) );

// get a list of outlines that contain variability charts
lstOutlines = vc << xpath("//OutlineBox[starts-with(., 'Variability Chart')]");

// each outline contains 2 charts (Y and StdDev)
// and each chart contains 2 axes (1st = y-axis, 2nd = x-axis)

// build a list of y-axes for the Y chart and also determine
// the minimum min and maximum max
lstAxes = {};
minmin = 1e6;
maxmax = -1e6;
for each({outline},lstOutlines,
	yAxis = outline[1][AxisBox(1)];
	minmin = min(minmin,yAxis<<getmin);
	maxmax = max(maxmax,yAxis<<getmax);
);

// apply common scaling to the y-axis of the Y plots
for each({outline},lstOutlines,
	yAxis = outline[1][AxisBox(1)];
	yAxis << max(maxmax);
	yAxis << min(minmin);
);

Re: Is there a way to set the plot ranges for all plots in a platform the same?

TheDude — Fri, 22 Jul 2022 20:27:13 GMT

I see.

Thank you for this.

It is a completely non-intuitive method (typical JMP).

Re: Is there a way to set the plot ranges for all plots in a platform the same?

txnelson — Fri, 22 Jul 2022 21:10:28 GMT

@TheDude, If you have a methodology that you think would be better, I suggest that you place that in the JMP Wish List. The JMP folks will then take a look and hopefully come up with an improved methodology. I have done this in the past, and have had the JMP Folks come back and show me why my suggestion was short sighted.......and I have also had to opposite happen, where they came back to me and worked through my suggested methodology, and it was implemented into the next release of JMP.

Re: Is there a way to set the plot ranges for all plots in a platform the same?

Dan_Obermiller — Sat, 23 Jul 2022 00:51:58 GMT

Well, here is another approach.

Select all of your columns that are to have the same axis.

Go to the columns menu and choose Standardize Attributes.

Under Standardize Properties choose Axis from the list of Column Properties.

It may not be necessary, but I would recommend that you change the "Save to column" to "All Axis Properties"

Click the Set Default Axis Settings button and specify how you want the axis to look.

Click the OK boxes to get out of the dialog.

Now every plot you create with those columns will have the same axis properties.