topic Re: Import x and y values from the text file to jmp table and create wafer map in Discussions

Import x and y values from the text file to jmp table

Jackie_ — Fri, 09 Jun 2023 17:03:41 GMT

Hi,

Reading each line in text file and import each string as a separate row in the jmp data table

Re: Import x and y values from the text file to jmp table and create wafer map

txnelson — Wed, 13 Jul 2022 12:44:21 GMT

Search the jmp addin and the past discussions for wafermaps. Lots of answers there

Re: Import x and y values from the text file to jmp table and create wafer map

jthi — Fri, 08 Jul 2022 05:35:44 GMT

I have formatted couple of different kinds of wafermaps with JMP into XY coordinates (and map file) based on text files. Doing it by "manually" scripting I think the process was something like this:

Parse the text file and get important information (Regex, Words and other character functions are helpful here)
1. Row count, Column count
2. X size, Y size
3. Bin types (especially null/empty type)
4. Wafermap
5. Any other information (WAFER ID, type...)
Create new datatable in which you can collect the results into
1. Row count is most likely row count * column count
2. You need at least X and Y columns, and if you are interested in different bins add column for that also
Loop over the wafermap string by using Words(wafermap_txt, "\!N") to get each line and build the values by multiplying xsize/ysize depending on which column you are filling.
1. This step is much easier if you don't care about the widths and heights and can just use 1 / fixed value
2. Also might be a good idea to just code them as coordinates that JMP map files would need, this allows you to build map shape files by using the sizes.
If you are only interested in the wafermap you could leave out null bins but you have to take it into account when building the map and

Re: Import x and y values from the text file to jmp table and create wafer map

Jackie_ — Fri, 08 Jul 2022 12:33:13 GMT

Thanks @jthi
Would you mind sharing the code just so I can refer?

Thanks,

Jack

Re: Import x and y values from the text file to jmp table and create wafer map

Jackie_ — Fri, 08 Jul 2022 13:04:21 GMT

@jthi
I want to store the die location and the letters in the jmp data table columns X and Y from the attached text file. How to use JSL to process such txt file as tabular data?

JMP table:

Re: Import x and y values from the text file to jmp table and create wafer map

jthi — Fri, 08 Jul 2022 13:25:26 GMT

I cannot share the code I use but here is a quick example with some ideas

Names Default To Here(1);

// load text file
// parse interesting things
// get map to string

map_str =
".....GGG.....
....BGGGG....
...BGGGGGG...
..GGGGGGGGG..
.GGGGGGBBGGG.
GGGGGGGBBGGGB
GGGGGGGGGGGGB
GGGGGGGGGGGGB
.GGGGGGGGGGG.
..GGGGGGGGG..
...GGGGGGG...
....GGGGG....
.....GGG.....";

l = Words(map_str, "\!N");
rowc = N Items(l);
colc = N Items(Words(l[1], ""));

dt = New Table("Untitled",
	Add Rows(rowc * colc),
	New Column("X", Numeric, Continuous),
	New Column("Y", Numeric, Continuous),
	New Column("bin", Character, Nominal, Label(1))
);

For Each({line, idx}, l,
	cur_rows = ((idx - 1) * colc::(idx * colc - 1)) + 1;
	dt[cur_rows, "X"] = ((1::colc))`;
	dt[cur_rows, "Y"] = (J(1, colc) * (idx))`;
	dt[cur_rows, "bin"] = Words(line, "");
);

nw = New Window("test",
	H List Box(
		align("center"),
		Text Box(map_str, <<Set Font Name("Courier New")),
		dt << Graph Builder(
			Size(529, 457),
			Show Control Panel(0),
			Variables(X(:X), Y(:Y), Color(:bin)),
			Elements(Points(X, Y, Legend(9))),
			SendToReport(
				Dispatch(
					{},
					"X",
					ScaleBox,
					{Min(0.461038514127673), Max(13.543406057392), Inc(1), Minor Ticks(0),
					Label Row(Show Major Grid(1))}
				),
				Dispatch(
					{},
					"Y",
					ScaleBox,
					{Min(14), Max(0), Inc(1), Minor Ticks(0), Label Row(Show Major Grid(1))}
				),
				Dispatch(
					{},
					"400",
					ScaleBox,
					{Legend Model(
						9,
						Properties(0, {Marker Size(20)}, Item ID(".", 1)),
						Properties(1, {Marker Size(20)}, Item ID("B", 1)),
						Properties(2, {Marker Size(20)}, Item ID("G", 1))
					)}
				)
			)
		),
		dt << Graph Builder(
			Size(529, 457),
			Show Control Panel(0),
			Variables(X(:X), Y(:Y), Color(:bin)),
			Elements(Heatmap(X, Y, Legend(10), Label("Label by Value"))),
			SendToReport(
				Dispatch({}, "X", ScaleBox, {Min(0.461038514127673), Max(14.3842387539345), Inc(1), Minor Ticks(0), Label Row(Show Major Grid(1))}),
				Dispatch({}, "Y", ScaleBox, {Min(14.3060372430966), Max(0.789075991529451), Inc(1), Minor Ticks(0), Label Row(Show Major Grid(1))})
			)
		)
	)
);

Re: Import x and y values from the text file to jmp table and create wafer map

Jackie_ — Fri, 08 Jul 2022 13:56:05 GMT

It works like charm. Thanks alot @jthi,

I'm trying to import the words from the text file to jmp data table, and then assign a different letters to those bins in the jmp table and then convert back to text file with the original formatting

map_str =
".....GGG.....
....BGGGG....
...BGGGGGG...
..GGGGGGGGG..
.GGGGGGBBGGG.
GGGGGGGBBGGGB
GGGGGGGGGGGGB
GGGGGGGGGGGGB
.GGGGGGGGGGG.
..GGGGGGGGG..
...GGGGGGG...
....GGGGG....
.....GGG.....";

How do I convert the data table X , Y and bins back in the text file format with the formatting maintained. Any suggestion?

Re: Import x and y values from the text file to jmp table and create wafer map

jthi — Fri, 08 Jul 2022 14:23:38 GMT

Initialize empty string, loop over the tables Y values in order, get row numbers for current y, use those row numbers to get bins, add those bins to initialized string (Concat Items() should help with this), add row change and continue to next Y. After looping trim whitespaces if needed.

Re: Import x and y values from the text file to jmp table and create wafer map

Jackie_ — Fri, 08 Jul 2022 14:30:00 GMT

Appreciated @jthi
I am new to JSL coding. Can you share an example? Just as a reference

Re: Import x and y values from the text file to jmp table and create wafer map

jthi — Fri, 08 Jul 2022 14:42:54 GMT

Using simpler table

Names Default To Here(1);

// Simple example table
dt = New Table(
	"Untitled",
	Add Rows(9),
	New Column("X", Numeric, "Continuous", Format("Best", 12), Set Values([1, 2, 3, 1, 2, 3, 1, 2, 3])),
	New Column("Y", Numeric, "Continuous", Format("Best", 12), Set Values([1, 1, 1, 2, 2, 2, 3, 3, 3])),
	New Column("bin", Character, "Nominal", Set Values({".", "X", ".", "X", "X", "X", ".", "X", "."}))
);

//empty string initialization
str = ""; 

// get unique values for Y
// I will use Associative array instead of Summarize to keep correct format of values
// Summarize would change them to strings
y_uniq = Associative Array(:Y) << get keys; 
For Each({cur_y}, y_uniq,
	cur_line_rows = Loc(dt[0, "Y"], cur_y); // Loc() with datatable subscripting
	line_bins = dt[cur_line_rows, "bin"]; // more datatable subscripting
	bin_str = Concat Items(line_bins, "");
	str = str || bin_str || "\!N"; 
);

// remove extra whitespace
str = Trim Whitespace(str);
Write(str);

Re: Import x and y values from the text file to jmp table and create wafer map

Jackie_ — Fri, 08 Jul 2022 14:54:09 GMT

It's a masterpiece. Thank you very much! :grinning_face:

Re: Import x and y values from the text file to jmp table and create wafer map

Jackie_ — Fri, 08 Jul 2022 18:56:09 GMT

@jthi
Just a quick question

The actual text file contains wafer information in the beginning. I want to store the data from row 21. I modified jsl as below. It does read as expected. Any suggestions?

			map_str = Load Text File();


			l = Words( map_str, "\!N" );
			rowc = N Items( l );
			colc = N Items( Words( l[21], "" ) ); //// edits

			dt = New Table( "Untitled",
				Add Rows( rowc * colc ),
				New Column( "X", Numeric, Continuous ),
				New Column( "Y", Numeric, Continuous ),
				New Column( "bin", Character, Nominal, Label( 1 ) )
			);

			For Each( {line, idx}, l,
				cur_rows = ((idx - 1) * colc :: (idx * colc - 1)) + 1;
				dt[cur_rows, "X"] = ((1 :: colc))`;
				dt[cur_rows, "Y"] = (J( 1, colc ) * (idx))`;
				dt[cur_rows, "bin"] = Words( line, "" );
			);

Re: Import x and y values from the text file to jmp table and create wafer map

jthi — Sat, 09 Jul 2022 06:16:28 GMT

You should use some method to get only the wafermap (if you only care about it). Currently you are using the whole text file. Some options for that are

Regex
Substr with Contains
Words and split on {}
Words and split on row change and combine that with Contains to
hard coding lines and getting wafermap based on those (usually very bad idea)

Re: Import x and y values from the text file to jmp table and create wafer map

Jackie_ — Sat, 09 Jul 2022 21:17:10 GMT

Sorry to bother you again. I tried substr but there's something not correct in the code. If you could modify, it would be great

			map_str = Load Text File();


			l = Words( map_str, "\!N" );
			rowc = N Items( l );
			colc = N Items( Words( l[21], "" ) ); //// edits

			dt = New Table( "Untitled",
				Add Rows( rowc * colc ),
				New Column( "X", Numeric, Continuous ),
				New Column( "Y", Numeric, Continuous ),
				New Column( "bin", Character, Nominal, Label( 1 ) )
			);

			For Each( {line, idx}, l,
				cur_rows = ((idx - 1) * colc :: (idx * colc - 1)) + 1;
				dt[cur_rows, "X"] = ((1 :: colc))`;
				dt[cur_rows, "Y"] = (J( 1, colc ) * (idx))`;
				dt[cur_rows, "bin"] = substr( line, 1 );
			);

Re: Import x and y values from the text file to jmp table and create wafer map

jthi — Sun, 10 Jul 2022 06:48:39 GMT

You need to manipulate the string you get from Load Text File() in such a way that you end up with string which contains only the wafermap part of the text file. This won't give final string needed but gives one idea what you could do. See Scripting Index (and JMP Help) on how Substr and Contains work. It also has one option on using Words and Contains, which also needs some modifications to get correct list.

Names Default To Here(1);

demo_str = "SOMETHING
TEXT
EXAMPLE
MAP = {
.X.
XXX
.X.
}";

map_str = Substr(demo_str, Contains(demo_str, "MAP = {"));
show(map_str);

stop();
demo_list = Words(demo_str, "\!N");
map_start = Contains(demo_list, "MAP = {");
map_list = demo_list[map_start::N Items(demo_list)];
show(map_list);

Re: Import x and y values from the text file to jmp table and create wafer map

Jackie_ — Sun, 10 Jul 2022 17:13:09 GMT

That's good explanation @jthi .

Quick question:

The below statement will start reading data from second row of the list. I don't want to read the last row which contains brace "}".

How can I define the end line in the script

map_str = Substr(demo_str, Contains(demo_str, ".X."));

Re: Import x and y values from the text file to jmp table and create wafer map

txnelson — Sun, 10 Jul 2022 17:23:41 GMT

map_str = Substr(
	demo_str,
	Contains( demo_str, ".X." ),
	Length( demo_str ) - Contains( demo_str, ".X." ) -1
);

Note: Look in the Scripting Index for definition and examples for the Stbstr() function

Re: Import x and y values from the text file to jmp table and create wafer map

Jackie_ — Mon, 11 Jul 2022 14:20:06 GMT

@txnelson ,

Your approach works if the pattern in the first row matches with the contain statement. I have several wafer maps which won't have same patterns. The only similarity is the wafer pattern starts at row number 21 in the text file. Is there a way to define the row number where the script will start reading?. I have attached a wafer map text file for reference (better view on note pad ++)

Re: Import x and y values from the text file to jmp table and create wafer map

jthi — Mon, 11 Jul 2022 14:52:00 GMT

You could try Contains with "MAP = {". This should give you the location of "MAP = {" in the string and then use that knowledge with Substr to get what you want

Re: Import x and y values from the text file to jmp table and create wafer map

jthi — Mon, 11 Jul 2022 14:55:22 GMT

You could try Contains with "MAP = {". This should give you the location of "MAP = {" in the string and then use that knowledge with Substr to get what you want. Also check scripting index (and possibly JMP Help which you can open from Scripting Index) to understand how Substr (and other functions) work.