topic Re: How to check if list of columns exist and report those that are missing using a pop-up window? in Discussions

How to check if list of columns exist and report those that are missing using a pop-up window?

Lavik17 — Fri, 09 Jun 2023 17:02:44 GMT

Hi all!

I would like to test if a list of 5 column names exist in a data table.

If one or more are missing, I would like to have a window pop up telling the user which columns are missing. If all columns are present the script should continue its run.

Could you please point me in the right direction on how to write it?

Thanks!

Re: How to check if list of columns exist and report those that are missing using a pop-up window?

DirtyDataCoLLC — Tue, 28 Jun 2022 23:04:15 GMT

Hi Lavik17,

Have you tried using the Columns View Selector in the column drop-down menu? Then, using the summary statistics function, you can effortlessly search your five-column names and determine if they are missing data.

I hope this helps,

Rob

Re: How to check if list of columns exist and report those that are missing using a pop-up window?

Lavik17 — Tue, 28 Jun 2022 23:14:25 GMT

Hi Rob!

Thank you for the suggestion! I would like to conduct this task using JSL because I am planning to incorporate it in some of my scripts, but would also like to have a user friendly GUI message for the users in case columns are missing.

Thanks though!

Adi

Re: How to check if list of columns exist and report those that are missing using a pop-up window?

txnelson — Wed, 29 Jun 2022 01:04:46 GMT

Here is a simple example of one way to do this

Names Default To Here( 1 );

// Open Data Table: big class.jmp
// → Data Table( "big class" )
dt = Open( "$SAMPLE_DATA/big class.jmp" );

colList = dt << get column names( string );

requiredList = {"name", "sex", "shoe size"};

For( i = N Items( requiredList ), i >= 1, i--,
	If( Contains( colList, requiredList[i] ),
		Remove From( requiredList, i, 1 )
	)
);

stop = "NO";
If( N Items( requiredList ) > 0,
	stop = "YES";
	New Window( "Error",
		Modal,
		V List Box(
			Text Box( "The following column(s) are required" ),
			Text Box( "but were not found in the data table." ),
			Spacer Box( size( 1, 10 ) ),
			List Box( requiredList )
		)
	);
);
If( stop == "YES", Throw() );

Re: How to check if list of columns exist and report those that are missing using a pop-up window?

ErraticAttack — Wed, 29 Jun 2022 02:16:24 GMT

You can use the Remove() method of Associative Arrays to do this without any JSL loops:

Names Default to Here( 1 );

reference table = New Table( "TEST",
	<<New Column( "A" ),
	<<New Column( "B" ),
//	<<New Column( "C" ),
	<<New Column( "D" ),
//	<<New Column( "E" ),
	<<New Column( "F" ),
//	<<New Column( "G" ),
	<<New Column( "H" ),
	<<New Column( "I" ),
	<<New Column( "J" ),
	<<New Column( "K" ),
	<<New Column( "L" ),
	<<New Column( "M" ),
	<<New Column( "N" ),
	<<New Column( "O" )
);

cols of interest = {"B","C","D","E","F"};

table cols = reference table << Get Column Names( "String" );

table cols aa = Associative Array( table cols );
cols of interest aa = Associative Array( cols of interest );

cols of interest aa << Remove( table cols aa );

cols missing = cols of interest aa << Get Keys;

If( N Items( cols missing ),
	New Window( "Error",
		<<Modal,
		Text Box( "Some columns are missing!" ),
		Text Box( Concat Items( cols missing, ", " ) )
	);
	Throw()
);

Print( "rest of script..." )

Re: How to check if list of columns exist and report those that are missing using a pop-up window?

Lavik17 — Wed, 29 Jun 2022 20:48:25 GMT

Thank you! This is exactly what I was looking for!

Re: How to check if list of columns exist and report those that are missing using a pop-up window?

Lavik17 — Wed, 29 Jun 2022 20:49:03 GMT

Thank you! This is an interesting solution! I really should learn to work with Associative Arrays...

Re: How to check if list of columns exist and report those that are missing using a pop-up window?

hogi — Tue, 27 Jun 2023 19:52:36 GMT

The approach with the associative array is great!

But please note that the comparisons described here just find exact matches.

In general for Jmp it doesn't matter if there are capital letters in the column name - or spaces.

So, depending on your application case, maybe the check if list of columns exist shouldn't care either.

Very robust is @txnelson 's approach :

r=try(column(dt,tn)<<get name,"");

With all the pitfalls of column existence checks - in my opinion Jmp should provide a robust way to ask a data table if a column exists.
Here is the post in the wish list: