topic Re: How do add text to a cell that has an image loaded? in Discussions

How do add text to a cell that has an image loaded?

lwx228 — Fri, 09 Jun 2023 17:01:49 GMT

Is it possible to add text to a cell that has already loaded images?

Thanks!

Re: How do add text to a cell that has an image loaded?

jthi — Mon, 20 Jun 2022 14:16:56 GMT

You could use set each value to re-create the image with text

Names Default To Here(1);
dt = Open("$SAMPLE_DATA/Big Class Families.jmp");


Column(dt, "picture") << Set Each Value(
	H List Box(align("center"),
		Text box(:name),
		:picture
	) << Get Picture
);

Re: How do add text to a cell that has an image loaded?

lwx228 — Mon, 20 Jun 2022 14:38:13 GMT

If I want to add more than one cell of text, I try to add it left and right.

Can I add text below?It looks like this down here.

Column(dt, "picture") << Set Each Value(
	H List Box(align("center"),
		Text box(:name),
		:picture
	) << Get Picture
);
Column(dt, "picture") << Set Each Value(
	H List Box(align("center"),
		Text box(:sports),
		:picture
	) << Get Picture
);

Thanks Experts!

Re: How do add text to a cell that has an image loaded?

jthi — Mon, 20 Jun 2022 14:55:50 GMT

Using proper display functions (h list box, v list box, lineup box...) and display boxes should help you to organize the elements

Re: How do add text to a cell that has an image loaded?

lwx228 — Thu, 23 Jun 2022 14:25:59 GMT

JSL can add text to a screenshot and then place it on the image.

Thanks!

dt = Open( "$SAMPLE_DATA/Big Class Families.jmp" );
rp = New Window( "", dt << Get As Report );
rp << Set Cell Height( 250 );
pic = rp << Get Picture;

Re: How do add text to a cell that has an image loaded?

Craige_Hales — Thu, 23 Jun 2022 23:48:28 GMT

Use a graphics frame box to add text and lines on top of a picture.

Re: How do add text to a cell that has an image loaded?

lwx228 — Fri, 24 Jun 2022 13:09:38 GMT

Thank Craige!

I copied the following JSL, just to achieve the simplest function.
But I still don't know the code.Text is not added where it should be.
Consult experts to help modify, with the simplest code implementation.

Thanks Experts!

dt = Open( "$SAMPLE_DATA/Big Class Families.jmp" );
dt << delete columns( 3 :: N Col( dt ) );
dt << delete rows( 6 :: N Row( dt ) );
dt << Set Cell Height( 100 );
rp = New Window( "", dt << Get As Report );
original = rp << Get Picture;
{xSize, ySize} = original << size;

gb = Graph Box(
	<<backgroundcolor( "orange" ),
	FrameSize( xSize + 1, ySize + 1 ),
	X Scale( 0, xSize + 1 ),
	Y Scale( 0, ySize + 1 ),
	<<Add Image( image( original ), bounds( top( 0 ), Left( 1 ), bottom( ySize ), Right( xSize + 1 ) ) ),
	Text( Center Justified, { 50, 10}, "KATIE" )
);
updated = gb[framebox( 1 )] << getpicture;
updated << crop( Left( 1 ), top( 1 ), Right( xSize + 1 ), bottom( ySize + 1 ) );
originalMatrix = original << getpixels;
newMatrix = updated << getpixels;
diff = (originalMatrix - newMatrix != 0);
New Window( "bitmaps", V List Box( gb ) );

Re: How do add text to a cell that has an image loaded?

lwx228 — Fri, 24 Jun 2022 13:11:32 GMT

Text( Center Justified, { 50, 10}, "KATIE" )

How can this code be modified to fit inside the original image?

Re: How do add text to a cell that has an image loaded?

Craige_Hales — Fri, 24 Jun 2022 13:20:59 GMT

text size function; 5 points is a little too small for my eyes.

Re: How do add text to a cell that has an image loaded?

Craige_Hales — Fri, 24 Jun 2022 13:29:55 GMT

Wait. You are using a picture of the whole data table, but I'm pretty sure you want to work on one picture at a time.

Just grab the image from dt:picture[iRow] rather than loading it from a file, then replace it when done. Approximately like this:

original = dt:picture[iRow];
...existing jsl...
dt:picture[iRow] = updated;

Re: How do add text to a cell that has an image loaded?

Craige_Hales — Fri, 24 Jun 2022 13:35:48 GMT

dt = Open( "$SAMPLE_DATA/Big Class Families.jmp" );
For( iRow = 1, iRow <= N Rows( dt ), irow += 1, 
// open the original
	original = dt:picture[iRow];
	{xSize, ySize} = original << size;
// use a frame to do the drawing, make the original fit the frame exactly
	gb = Graph Box(
		<<backgroundcolor( "orange" ), // to see errors better
		FrameSize( xSize + 1, ySize + 1 ), // the +1 is required, 4 times
		X Scale( 0, xSize + 1 ),
		Y Scale( 0, ySize + 1 ), 
	// apparently x and y are different. this is correct in 17EA.
		<<Add Image( image( original ), bounds( top( 0 ), Left( 1 ), bottom( ySize ), Right( xSize + 1 ) ) ), 
	// draw something on top of the image
		Text( Center Justified, {xSize / 2, 10}, dt:name[irow] );
	);
// capture an updated image
	updated = gb[framebox( 1 )] << getpicture;
// crop added border. "updated" is the final image.
	updated << crop( Left( 1 ), top( 1 ), Right( xSize + 1 ), bottom( ySize + 1 ) );
	dt:picture[irow]=updated;
);

Mug shots

Re: How do add text to a cell that has an image loaded?

lwx228 — Fri, 24 Jun 2022 13:46:51 GMT

Thanks!

I see!

Re: How do add text to a cell that has an image loaded?

Craige_Hales — Fri, 24 Jun 2022 13:49:01 GMT

...and the orange background is because those images have transparent pixels. Your images probably don't have transparent pixels, so you probably won't see that. Preserving the transparency while adding text is a lot harder.