topic Re: web reports - inactive filter for tab page in Discussions

web reports - inactive filter for tab page

LiPav — Sun, 11 Jun 2023 11:23:33 GMT

Hi,

I am building a web report as tab page boxes, where in each of the tab pages is a plot and a data filter built based on individual data table. It works, only the filter for 2nd and next tab pages are inactive... Any ideas?

Below is the example of the problem. The filter in the "alpha" tab is active, and the filter in the "beta" page inactive:

Names Default To Here( 1 );
dt = Open( "$SAMPLE_DATA/Big Class.jmp" );
dt_2 = Open( "$SAMPLE_DATA/Owl Diet.jmp" );

webreport1 = New Window( "Example",
Tab Box(
Tab Page Box( Title( "alpha" ),
H List Box(

dt << Bubble Plot( X( :weight ), Y( :height ), Sizes( :age ), Title Position( 0, 0 ),

local Data Filter(
Mode( Selected( 1 ), Show( 0 ), Include( 0 ) ) ,
Add Filter( columns( :sex ) )
)
)
)
),

Tab Page Box( Title( "beta" ),
H List Box(

dt_2 << Bubble Plot( X( :skull length ), Y( :skull length ), Sizes( :teeth row ), Title Position( 0, 0 ) ),
,
dt_2 << Data Filter(
Local,
Mode( Selected( 1 ), Show( 0 ), Include( 0 ) ) ,
Add Filter( columns( :species ) )
))
)

)
);

webreport = New Web Report();
webreport << Add Report( webreport1 );

file = webreport << Save( "$TEMP" );
If( !Is Empty( file ),
Web( file )
);

I am using JMP 16 on Windows.

Best regards,

Re: web reports - inactive filter for tab page

danschikore — Fri, 08 Apr 2022 12:53:00 GMT

Hi @LiPav - for the webreport, I believe the main issue is that only a single filter is supported per webpage. For export purposes, I would suggest creating two windows with one filter per window (see script below). These will be published with an index page, allowing you to use the browser forward/back buttons to navigate between the reports.

I also notice that in the desktop JMP window the second report is not interactive. This is due to the fact that the Data Filter is created separately from the Platform. When you have a filter for a single platform, I would recommend using the Local Data Filter() specification within the Bubble Plot() or other platform command. When you need to link a single filter to multiple reports in the same window, see the Scripting Index entry for Data Filter Context Box for an example that demonstrates how to link the filter to multiple platforms.

Hope that helps!

-Dan

dt = Open( "$SAMPLE_DATA/Big Class.jmp" );
dt_2 = Open( "$SAMPLE_DATA/Owl Diet.jmp" );

webreport1 = New Window( "alpha",
	H List Box(
		dt << Bubble Plot(
			X( :weight ),
			Y( :height ),
			Sizes( :age ),
			Title Position( 0, 0 ), 

			local Data Filter( Mode( Selected( 1 ), Show( 0 ), Include( 0 ) ), Add Filter( columns( :sex ) ) )
		)
	)
);

webreport2 = New Window( "beta",
	H List Box(
		dt_2 << Bubble Plot(
			X( :skull length ),
			Y( :skull length ),
			Sizes( :teeth row ),
			Title Position( 0, 0 ),
			Local Data Filter( Mode( Selected( 1 ), Show( 0 ), Include( 0 ) ), Add Filter( columns( :species ) ) )
		)
	)
);

webreport = New Web Report();
webreport << Title( "Reports" );
webreport << Description( "Multiple report example." );
webreport << Add Report( webreport1, Title( "alpha" ) );
webreport << Add Report( webreport2, Title( "beta" ) );

file = webreport << Save( "$TEMP" );
If( !Is Empty( file ),
	Web( file )
);

Re: web reports - inactive filter for tab page

LiPav — Sun, 10 Apr 2022 09:51:03 GMT

Thank you, Dan. I followed your example and made my project the way you suggested!

Best regards,