Add additional values to list using col list box

UserID16644 — Sat, 10 Jun 2023 20:49:51 GMT

Is it possible that an existing list would have an additional data from col list box?

For example: Fruits = {"apple", "mango", "strawberry"}

Then, when user picked banana, orange from the col list box, it will be added to the fruits list.

I tried using Fruits = get items but only the initial list values are initialized. Pls help

Re: Add additional values to list using col list box

txnelson — Mon, 21 Mar 2022 07:32:02 GMT

Here are 2 examples. The first one is using a Col List Box. It requires the additional fruit choices to be column names, so that they will show up in the Col List Box as choices to be added to the Fruits list.

Names Default To Here( 1 );
dt=new table("New Fruits",
	new column("Bananas"),
	new column("Oranges")
);
Fruits = {"apple", "mango", "strawberry"};
New Window( "Example",
	lb = col List Box(dt,all,
		width( 200 ),
		max selected( 1 ),
		nlines( 6 ),
		selList = lb << get selected;
		locList = lb << get selected indices;
		If( Contains( Fruits, selList[1] ) == 0,
			Insert Into( Fruits, selList[1] )
		);
		lb << set selected(locList[1],0);
		show(Fruits);
	)
);

This seems to be an inefficient way to code this, unless the choices you want to make are actually column names. If they are not column names that need to be selected, then by using just a List Box() will work just fine

Names Default To Here( 1 );
Fruits = {"apple", "mango", "strawberry"};
New Window( "Example",
	lb = List Box(
		{"Banana", "Orange"},
		width( 200 ),
		max selected( 1 ),
		nlines( 6 ),
		selList = lb << get selected;
		locList = lb << get selected indices;
		If( Contains( Fruits, selList[1] ) == 0,
			Insert Into( Fruits, selList[1] )
		);
		lb << set selected(locList[1],0);
		show(Fruits);
	)
);

topic Add additional values to list using col list box in Discussions

Add additional values to list using col list box

Re: Add additional values to list using col list box