topic Re: N Col using textbox value in Discussions

N Col using textbox value

UserID16644 — Sun, 11 Jun 2023 11:22:03 GMT

Hi all,

I am trying to create a user input box that will determine the N Col for my line up box. I tried this script

User_Input = New Window( "N Col", << modal(),
	hlistbox(
		Text Box( "Enter Column No:  " ),
		Col_Num_teb = Text Edit Box( "", <<set width( 200 ) ),
	),
	Button Box( "OK", 
		col_num = col_num_teb << get();
	),
);

lb = LineUpBox( N Col(col_num) );

I tried entering 4 but ends up having 2 columns. How can I correctly get the N Col for my line up box?

Re: N Col using textbox value

jthi — Tue, 22 Feb 2022 06:15:24 GMT

You could either use Number Edit Box and then << Get or with Text Edit Box use << Get Text and then convert that to number with Num()

Names Default To Here(1);

//Text Edit Box
User_Input = New Window("N Col",
	<<modal(),
	H List Box(Text Box("Enter Column No:  "), Col_Num_teb = Text Edit Box("", <<set width(200)), ),
	Button Box("OK", col_num = col_num_teb << get text),
);
show(Num(col_num));

//number edit box
User_Input = New Window("N Col",
	<<modal(),
	H List Box(Text Box("Enter Column No:  "), neb = Number Edit Box(., <<set width(50)), ),
	Button Box("OK", col_num = neb << get),
);
show(col_num);

Re: N Col using textbox value

Thierry_S — Tue, 22 Feb 2022 06:22:15 GMT

Hi,

Unless you convert your text/string into a number, the LineUpBox call will not work. Try replacing the Text Edit Box () with a Number Edit Box

User_Input = New Window( "N Col", << modal(),
	hlistbox(
		Text Box( "Enter Column No:  " ),
		Col_Num_neb = Number Edit Box ( 1 ), // You can replace "1" by any other initial value
	),
	Button Box( "OK", 
		col_num = col_num_neb << get; // You don't need the parentheses here
	),
);

lb = LineUpBox( N Col(col_num) );