topic Re: Crop a JPG Image in Discussions

Crop a JPG Image

thickey — Fri, 09 Jun 2023 18:06:36 GMT

Trying to crop the light grey border from around the outside of the below wafermap image using the following script. I guess I'm not understanding how the crop message works as there is no difference in the before and after images.

Any idea of what I'm doing wrong?

Cheers, Troy

img = open("D:\wafer.jpg", jpg);
win1 = newWindow("Original", img);

img << crop(left(5),right(5),top(5),bottom(5));
win2 = newWindow("Cropped", img);

img << savePicture("D:\waferCropped.jpg", jpg);

Re: Crop a JPG Image

Thierry_S — Fri, 03 Dec 2021 06:05:55 GMT

Hi,

I think that you forgot to assign the cropped image to a variable:

img2 = img << crop(left(5),right(5),top(5),bottom(5));
win2 = newWindow("Cropped", img2);

Best,

Re: Crop a JPG Image

thickey — Fri, 03 Dec 2021 08:17:23 GMT

Thanks for the reply Thierry.

I had tried exactly that as well but with no luck.

Re: Crop a JPG Image

thickey — Fri, 03 Dec 2021 08:35:00 GMT

OK, so it looks like I just didn't understand how the crop function works. Fundamentally you need to know the height and width of the image you are cropping and work with those values when you crop, relative to the LHS and TOP Edges

Left = Number of pixels to remove from left side

Right = 'Width' (in pixels) of remaining image to keep

Top = Number of pixels to remove from top of image

Bottom = 'Height' (in pixels) of remaining image to keep

img = open("D:\WaferMaps\8PTPCVEB\wafer.jpg", jpg);
imgX = (img << GetSize)[1];
imgY = (img << GetSize)[2];
win1 = newWindow("Original", img);

myTrimBy = 5;
img << crop(left(myTrimBy),right(imgX - myTrimBy), top(myTrimBy), bottom(imgY - myTrimBy));
win2 = newWindow("Cropped", img);

img << savePicture("D:\WaferMaps\8PTPCVEB\waferCropped.jpg", jpg);

Re: Crop a JPG Image

gzmorgan0 — Fri, 03 Dec 2021 09:20:12 GMT

Nice job. The Right and Bottom definitions you provided are not exactly as you specified. Your script is spot on!

See the script below.

Names Default To Here( 1 );
img = Open( "$SAMPLE_IMAGES/tile.jpg", jpg );

s = {w,h} = img << get size();
show( s ); //{451, 451}
obj = New Window( "tile(40,40)", img );
Wait( 1 );
img << Crop( Left( 50 ), Right( 100 ), Top( 60 ), Bottom( 150 ) );
s = {w,h} = img << get size();
show( s ); //{50, 90}

//img is a matrix of pixels the initail size is 1 to 451 columns aka "w" width
//and "h" is height 1 to 451 rows

//Crop Left(x) is the starting column and Right(y) is the ending column 
//Top() and Bottom() works the same, so after the crop the width is 100-50=50
//and the height is  150-60=90

Re: Crop a JPG Image

Georg — Fri, 03 Dec 2021 09:43:26 GMT

Dear @Thierry_S ,

I would have thought the same way, this behaviour is strange, as the documentation say: "creates new image ...".

But in fact crop is changing the current image, so into my eyes the documentation is not correct, it is misleading.

@tonya_mauldin , do you think the documentation has to be changed according to this?

Names Default To Here( 1 );
img = Open( "$SAMPLE_IMAGES/tile.jpg", jpg );
Print( "Size before crop:", img << get size );

img << Crop(
	Left( 50 ),
	Right( 400 ),
	Top( 50 ),
	Bottom( 400 )
);

Print( "Size before crop:", img << get size );
print("So crop changes the image and does not create a new one as written in the documentation");

Images (jmp.com)

Re: Crop a JPG Image

Craige_Hales — Fri, 03 Dec 2021 15:24:53 GMT

Yes, it is a non-obvious interface and wants better doc. @Anonymous

pixels = [
-11 -11 -11 -11 -11 -11 -11 -11 -11,
-11 -11 -91 -99 -99 -99 -99 -92 -11,
-11 -11 -99 -99 -99 -99 -99 -99 -11,
-11 -11 -99 -99 -99 -99 -99 -99 -11,
-11 -11 -99 -99 -99 -99 -99 -99 -11,
-11 -11 -93 -99 -99 -99 -99 -94 -11];

img = New Image( pixels );
{hSize, ySize} = img << size;
Show( img << getsize, img << getpixels );

// crop the -11 out of the image
img << crop( Left( 2 ), Right( 8 ), top( 1 ), bottom( 6 ) );
Show( img << getsize, img << getpixels );

////    img << getsize = {6, 5};
////    img << getpixels = 
////    [	-91 -99 -99 -99 -99 -92, 
////        -99 -99 -99 -99 -99 -99, 
////        -99 -99 -99 -99 -99 -99, 
////        -99 -99 -99 -99 -99 -99, 
////        -93 -99 -99 -99 -99 -94];

The zero-based pixel indexes are on the hairlines between the pixels.

Re: Crop a JPG Image

Qiana_Eaglin — Fri, 03 Dec 2021 19:28:49 GMT

Thank you for bringing this to my attention. What document is being referenced in previous comments?

Thanks,

Qiana

Re: Crop a JPG Image

Craige_Hales — Fri, 03 Dec 2021 23:57:45 GMT

@Georg pointed to https://www.jmp.com/support/help/en/16.1/?os=win&source=application&utm_source=helpmenu&utm_medium=application#page/jmp/images.shtml

Which appears identical to the ~~scripting guide~~. syntax reference.

I'd point to the scripting index:

Both say "creates a new image" but only the existing image is modified, which was part of the confusion, and neither does a good job explaining the parameters. There is another crop, for a segment, that is distinct from this one.

Thanks for looking at it!

Re: Crop a JPG Image

hogi — Fri, 18 Apr 2025 10:38:35 GMT

Thanks @Craige_Hales :)
very (!) helpful