topic Re: Extract factor range from bivariate graph in Discussions

Extract factor range from bivariate graph

pauldeen — Fri, 09 Jun 2023 19:58:44 GMT

How do I efficiently extract the crossing points of this curve and its 95% CI with an arbitrary Y value.

dt = Open( "$sample_data/Growth.jmp" );
biv = Bivariate(
	Y( :age ),
	X( :ratio ),
	Fit Line( {Line Color( {204, 121, 41} )}, save studentized residuals ),
	SendToReport(
		Dispatch(
			{},
			"Bivar Plot",
			FrameBox,
			{Grid Line Order( 3 ), Reference Line Order( 4 )}
		)
	)
);
biv << (Curve[1] << Save Studentized Residuals);

biv2 = Bivariate(
	Y( :Studentized Residuals age ),
	X( :ratio ),
	Fit Polynomial( 2, {Confid Shaded Fit( 1 ), Line Color( {212, 73, 88} )} ),
	SendToReport(
		Dispatch(
			{},
			"ratio",
			ScaleBox,
			{Min( 0.2796875 ), Max( 1.2666259765625 ), Inc( 0.2 ), Minor Ticks( 1 )}
		),
		Dispatch(
			{},
			"Studentized Residuals age",
			ScaleBox,
			{Add Ref Line( 1.96, "Solid", "Black", "", 1 ),
			Add Ref Line( -1.96, "Solid", "Black", "", 1 )}
		)
	)
);

So I would like to get the Ratio values where the curve and its 95%CI crosses +/- 1.96 (so 6 values in total). Are there any better solutions than the brute force I can think of: dumping the predicteds and the mean confidence limit formula into a table and adding rows with values to the table to see when it crosses the limits?

Re: Extract range from graph

ih — Wed, 06 Oct 2021 11:54:30 GMT

I don't know of a direct method but here are a few ideas. Some would be a bit of work to script and probably I suspect none would be much faster for small problems.

Save a formula for each of those lines to the data table by pulling the parameters and standard errors from the table in the bivariate report and then creating a column with the appropriate formula. Then use the optimizer built into the profiler to solve for each.
Save relatively few points using the brute force method and then fit a new curve to them using fit model, and then save the prediction formula and solve with the optimizer.
Fit using fit model instead where you should be able to extract the prediction formula directly, but maybe not the CI.
Use the brute force method and interpolate between the closest few points, either linear between the last two, or for this problem quadratic between the closest three.

Re: Extract factor range from bivariate graph

Mark_Bailey — Thu, 07 Oct 2021 13:25:24 GMT

You might be able to use the Minimize() function and the expression for the confidence boundary. See the Help for optimization methods.

Re: Extract factor range from bivariate graph

pauldeen — Fri, 08 Oct 2021 06:42:10 GMT

@Mark_Bailey thanks, I tried giving that a shot but the syntax is unclear to me.

This is as far as I got, but now I need to figure out how to feed it it the right optimization constraints:

Names Default To Here( 1 );

dt = Open( "$sample_data/Growth.jmp" );
biv = Bivariate(
	Y( :age ),
	X( :ratio ),
	Fit Line( {Line Color( {204, 121, 41} )}, save studentized residuals ),
	SendToReport(
		Dispatch(
			{},
			"Bivar Plot",
			FrameBox,
			{Grid Line Order( 3 ), Reference Line Order( 4 )}
		)
	)
);
biv << (Curve[1] << Save Studentized Residuals);
biv << close window();

biv2 = Bivariate(
	Y( :Studentized Residuals age ),
	X( :ratio ),
	Fit Polynomial( 2, {Confid Shaded Fit( 1 ), Line Color( {212, 73, 88} )} ),
	SendToReport(
		Dispatch(
			{},
			"ratio",
			ScaleBox,
			{Min( 0.2796875 ), Max( 1.2666259765625 ), Inc( 0.2 ), Minor Ticks( 1 )}
		),
		Dispatch(
			{},
			"Studentized Residuals age",
			ScaleBox,
			{Add Ref Line( 1.96, "Solid", "Black", "", 1 ),
			Add Ref Line( -1.96, "Solid", "Black", "", 1 )}
		)
	)
);
biv << (Curve[1] << Mean Confidence Limit Formula);
f =column(dt, n cols(dt)) << Get Formula;
fs = substitute(name expr(f), expr(:ratio), expr(x1));
/*A = [1 5];
b = [-1.96, 1.96];
minFun = Constrained Maximize(
	f,
	{x1( 0, 5 )},
	<<lessthanEQ( {A, b} )/*and/or <<GreaterThanEQ({A,b}) and/or <<EqualTo({A,b}),
	<<StartingValues( [1, .5] )
);
Eval List( {x1, minFun} );*/

minimize(name expr(f), {})

The last part doesn't work. Thanks for your help!

Re: Extract factor range from bivariate graph

Mark_Bailey — Thu, 07 Oct 2021 17:25:31 GMT

I wonder about another approach. What if you use the Prediction Profiler and a Match Target desirability function with your target response? Then you can just pick off the predicted mean and the 95% confidence interval estimate of the mean.

I might have strayed from your original goal...

Re: Extract factor range from bivariate graph

Mark_Bailey — Thu, 07 Oct 2021 17:45:34 GMT

Your code was a bit messy. I cleaned it up and finished the example, though I might still be going after the wrong goal.

Names Default To Here( 1 );

// example data set
dt = Open( "$sample_data/Growth.jmp" );

// fit first-order polynomial model to response
biv = Bivariate(
	Y( :age ),
	X( :ratio ),
	Fit Line
);

// save residuals for next step
biv << (Curve[1] << Save Studentized Residuals);
biv << Close Window();

// fit second-order polynomial model to residuals
biv = Bivariate(
	Y( :Studentized Residuals age ),
	X( :ratio ),
	Fit Polynomial( 2, {Confid Shaded Fit( 1 ), Line Color( {212, 73, 88} )} )
);

// save formulas for lower / upper 95% confidence bound
biv << (Curve[1] << Mean Confidence Limit Formula);

// get upper formula
f = Column( dt, N Cols( dt ) ) << Get Formula;

// replace predictor name with x
fs = Substitute( Name Expr( f ), Expr( :ratio ), Expr( x ) );

// initialize x, could get x that predicts mean residual = 0
x = 0.5;

// minimize expression that is Abs( residual ), or mean = 0
fa = Insert( Expr( Abs() ), Name Expr( fs ) );

Minimize( fa, { x } );
Show( x );

Re: Extract factor range from bivariate graph

pauldeen — Fri, 08 Oct 2021 06:47:10 GMT

Yeah the problem with that one is that there are usually multiple crossings with the target value (one on the left and one on the right) and with the desirability maximizer you randomly get one of the two.

I tried Inverse predictions under fit model but that does not support quadratic terms.

Re: Extract factor range from bivariate graph

pauldeen — Fri, 08 Oct 2021 06:53:42 GMT

Yeah, exactly this works for finding the local minimum but it still is hard to get to the next crossing with 1.96 from there. You would still need to walk up the curve untill values exceed 1.96.

To temperoraly solve this, I built function for it that just takes little steps and goes out in both directions untill the value exceeds the limits (or the max number of steps) but I had expected there to be a solver function in JMP that would implement a better algorithm (like what is built into the non-linear platform). I guess for now I have what I need but I'm always open for nicer ways to do it.

Re: Extract factor range from bivariate graph

ih — Fri, 08 Oct 2021 11:53:59 GMT

You can do this using the optimizer built into the profiler. Set response limits to match target and then to find the upper and lower values just use reset factor grid to define the range of values to search, either above or below the minimum.

Profiler(
	Y( :Lower 95% Mean Studentized Residuals age ),
	Profiler(
		1,
		Desirability Functions( 1 ),
		Lower 95% Mean Studentized Residuals age <<
		Response Limits(
			{Lower( -0.04, 0.0183 ), Middle( 1.96, 1 ), Upper( 3.96, 0.0183 ),
			Goal( "Match Target" ), Importance( 1 )}
		),
		Term Value( ratio( 0.8, Min( 0 ), Max( 0.8 ), Lock( 0 ), Show( 1 ) ) )
	),
	SendToReport(
		Dispatch(
			{"Prediction Profiler"},
			"1",
			ScaleBox,
			{Min( 0 ), Max( 0.8 ), Inc( 0.2 ), Minor Ticks( 0 )}
		)
	)
) << Maximize Desirability;

Profiler(
	Y( :Lower 95% Mean Studentized Residuals age ),
	Profiler(
		1,
		Desirability Functions( 1 ),
		Lower 95% Mean Studentized Residuals age <<
		Response Limits(
			{Lower( -0.04, 0.0183 ), Middle( 1.96, 1 ), Upper( 3.96, 0.0183 ),
			Goal( "Match Target" ), Importance( 1 )}
		),
		Term Value( ratio( 1.52, Min( 0.8 ), Max( 2 ), Lock( 0 ), Show( 1 ) ) )
	),
	SendToReport(
		Dispatch(
			{"Prediction Profiler"},
			"1",
			ScaleBox,
			{Min( 0.8 ), Max( 2 ), Inc( 0.2 ), Minor Ticks( 0 )}
		)
	)
) << Maximize Desirability;

You should also be able to modify the expression you send to the minimize function by just subtracting 1.96 and minimizing the residual to get the same result. For some reason I get slightly different values though even after adjusting tolorances (1.07 in profiler v 1.03 with minimize).

fa = Insert( Expr( Abs() ), parse( "abs( " || char( Name Expr( fs ) ) || " - 1.96 )" ) );

// find lower value
x = 0.2;
Minimize( fa, { x(0.2,0.8) } );
Show( x );

// find upper value
x = 1;
Minimize( fa, { x(0.8,1.5) } );
Show( x );

Re: Extract factor range from bivariate graph

Craige_Hales — Fri, 08 Oct 2021 14:28:15 GMT

minor variation

offset = 1.96;

// (I do not know how to pick these without a visual examination of the result.)
startingPoint = 1.1; // or 0.5 (trial and error. pick something close and check.)

// example data set
dt = Open( "$sample_data/Growth.jmp" );

// fit first-order polynomial model to response
biv = Bivariate( Y( :age ), X( :ratio ), Fit Line );

// save residuals for next step
biv << (Curve[1] << Save Studentized Residuals);
biv << Close Window();

// fit second-order polynomial model to residuals
biv = Bivariate( Y( :Studentized Residuals age ), X( :ratio ), Fit Polynomial( 2, {Confid Shaded Fit( 1 ), Line Color( {212, 73, 88} )} ) );

// save formulas for lower / upper 95% confidence bound
biv << (Curve[1] << save predicteds);
biv << (Curve[1] << Mean Confidence Limit Formula);
// get formulas, using order columns were saved
fupper = Column( dt, N Cols( dt ) ) << Get Formula;
flower = Column( dt, N Cols( dt ) - 1 ) << Get Formula;
fpredicted = Column( dt, N Cols( dt ) - 2 ) << Get Formula;

// replace predictor name with x
fsupper = Substitute( Name Expr( fupper ), Expr( :ratio ), Expr( x ) );
fslower = Substitute( Name Expr( flower ), Expr( :ratio ), Expr( x ) );
fspredicted = Substitute( Name Expr( fpredicted ), Expr( :ratio ), Expr( x ) );

fsupper2 = Substitute( Expr( a - offset ), Expr( a ), Name Expr( fsupper ) ); // find zero at offset 
fslower2 = Substitute( Expr( a - offset ), Expr( a ), Name Expr( fslower ) ); // find zero at offset 
fspredicted2 = Substitute( Expr( a - offset ), Expr( a ), Name Expr( fspredicted ) ); // find zero at offset 

// initialize x, could get x that predicts mean residual = 0
x = startingPoint;
// minimize expression that is Abs( residual ), or mean = 0
faupper = Insert( Expr( Abs() ), Name Expr( fsupper2 ) );
Minimize( faupper, {x} );
xupper = x;
Show( xupper, Eval( faupper ) );

// initialize x, could get x that predicts mean residual = 0
x = startingPoint;
// minimize expression that is Abs( residual ), or mean = 0
falower = Insert( Expr( Abs() ), Name Expr( fslower2 ) );
Minimize( falower, {x} );
xlower = x;
Show( xlower, Eval( falower ) );


// initialize x, could get x that predicts mean residual = 0
x = startingPoint;
// minimize expression that is Abs( residual ), or mean = 0
fapredicted = Insert( Expr( Abs() ), Name Expr( fspredicted2 ) );
Minimize( fapredicted, {x} );
xpredicted = x;
Show( xpredicted, Eval( fapredicted ) );

// add lines on plot
Report( biv )[axisbox( 2 )] << {Add Ref Line( xpredicted, "Solid", "Black", "P", 1 ), Add Ref Line( xupper, "Solid", "Black", "U", 1 ),
Add Ref Line( xlower, "Solid", "Black", "L", 1 )};
Report( biv )[axisbox( 1 )] << {Add Ref Line( offset, "Solid", "Black", "", 1 )};
Report( biv )[framebox( 1 )] << Frame Size( 752, 513 );

Low sideHigh side

Re: Extract factor range from bivariate graph

ih — Tue, 09 Nov 2021 12:40:39 GMT

@Craige_Hales, to solve the initial value problem, if you minimize the whole function first you could use that ratio as a limit for the minimize search and be guaranteed to find the values on each side. For this problem that could be 0.8:

Minimize( fa, { x([very small number],[min ratio - found from minimizing the function]) } );

//For this example -10 is arbitrary (could use -1E6 or something), and 0.8 is
//roughly the overall function minimum
Minimize( fa, { x(-10,0.8) } );

Re: Extract factor range from bivariate graph

pauldeen — Tue, 12 Oct 2021 13:32:22 GMT

I tried desperatly to come up with a algorithm for the starting point, for example I used the quadratic formula to calculate the predicted curve crossing with 1.96 and even if you plug that number in for the starting condition you get fairly unpredictable behavior:

So thanks for showing how it can be used and I did learn a lot from this example, but it is not robust enough yet.

Re: Extract factor range from bivariate graph

Craige_Hales — Tue, 12 Oct 2021 14:12:01 GMT

I think the problem is with the absolute value function making a curve that doesn't have a nice derivative, making minimize likely to fail. I was hoping @ih idea would force minimize to stay in the right neighborhood, but maybe not.

I don't have time to puzzle through it right now; it seems likely there is a standard alternative to abs() for this problem...yielding a smoother function. (maybe squaring it? something like that.)

Edit: and your result agrees with mine, which is why I had the comment about visual inspection. The abs function makes a corner in the function to minimize, and the slope near that corner is used by the minimize function, and it expects a continuous (2nd?) derivative on each side of the answer. Since the slope instantly flips on each side of the true answer, it is amazing it gets close answers sometimes. I think the message in the log may be because of this.

Re: Extract factor range from bivariate graph

ih — Tue, 12 Oct 2021 18:30:35 GMT

You can adjust the factor grid (reset factor grid from the red triangle) to only get one limit or the other.

Re: Extract factor range from bivariate graph

ih — Wed, 20 Oct 2021 12:11:56 GMT

Expanding on @Craige_Hales and @Mark_Bailey 's code, you could do something like what is below to find the overall minimum and then use that as a bound for subsequent searches on each side, that way you are not as reliant on the initial value. Also, if you use a square instead of an absolute value gets rid of the corner. In practice though I've had good luck using the absolute value and other functions with step changes in the profiler's optimizer.

Names Default To Here( 1 );

// example data set
dt = Open( "$sample_data/Growth.jmp" );

// fit first-order polynomial model to response
biv = Bivariate(
	Y( :age ),
	X( :ratio ),
	Fit Line
);

// save residuals for next step
biv << (Curve[1] << Save Studentized Residuals);
biv << Close Window();

// fit second-order polynomial model to residuals
biv = Bivariate(
	Y( :Studentized Residuals age ),
	X( :ratio ),
	Fit Polynomial( 2, {Confid Shaded Fit( 1 ), Line Color( {212, 73, 88} )} )
);

// save formulas for lower / upper 95% confidence bound
biv << (Curve[1] << Mean Confidence Limit Formula);

// get formulas
fUpper = Column( dt, N Cols( dt ) ) << Get Formula;
fLower = Column( dt, N Cols( dt ) - 1 ) << Get Formula;

// replace predictor name with x
fsUpper = Substitute( Name Expr( fUpper ), Expr( :ratio ), Expr( x ) );
fsLower = Substitute( Name Expr( fLower ), Expr( :ratio ), Expr( x ) );

// initialize x, could get x that predicts mean residual = 0
x = 0.5;

// find the minimum of the whole expression, one solution will fall above and one below this value
fOverallMin = Name Expr( fsLower );
Minimize( fOverallMin, { x } );
xOverallMin = x;

// find where the value cross the x axis on each side of the overall min
x = xOverallMin - 1;
fMinCrossingTarget = Insert( Expr( Power() ), Insert( Expr( add(-1.96) ), Name Expr( fsLower ) ) );
Minimize( fMinCrossingTarget, { x(-1000, xOverallMin) } );
xMinLower = x;

x = xOverallMin + 1;
Minimize( fMinCrossingTarget, { x(xOverallMin, 1000) } );
xMinUpper = x;

x = xOverallMin - 1;
fMaxCrossingTarget = Insert( Expr( Power() ), Insert( Expr( add(-1.96) ), Name Expr( fsUpper ) ) );
Minimize( fMaxCrossingTarget, { x(-1000, xOverallMin) } );
xMaxLower = x;

x = xOverallMin + 1;
Minimize( fMaxCrossingTarget, { x(xOverallMin, 1000) } );
xMaxUpper = x;

show(xOverallMin, xMinLower, xMinUpper, xMaxLower, xMaxUpper);