topic Re: Name quote a strange column name in Discussions

Name quote a strange column name

pauldeen — Fri, 09 Jun 2023 19:56:01 GMT

I'm trying to insert a column name into a fit model expression. For that I need to escape strange characters in column names to do that we use the :"name"n convention. So how do I go from a string column name to this format?

colListY = {"Plating Thickness (m\!"\!")"};
//This doesn't work
newcolumnref = eval insert("\[:"^colListY[1]^"n]\");

//Looking for this end result
:"Plating Thickness (m\!"\!")"n

Which I can then insert anywhere, for example:

insert into(expr(Y()), newcolumnref);

Anybody know of a robust way to do this?

Re: Name quote a strange column name

txnelson — Sat, 04 Sep 2021 16:23:57 GMT

You can use the Column, or As Column functions to provide protection to the complex column name

colListY = {"Plating Thickness (m\!"\!")"};

newcolumnref = eval insert("column(\!"^colListY[1]^\!")");

Re: Name quote a strange column name

Craige_Hales — Sat, 04 Sep 2021 17:02:41 GMT

If you can avoid getting the name of the column as a string, and get the column object instead, it might be easier. Below, cols is a list of column objects, not their names.

colListY = {"Plating Thickness (m\!"\!")"};
dt = Open( "$sample_data/big class.jmp" );
dt:age << setname( colListY[1] );
cols = dt << getcolumnnames;// don't use the string keyword
/* {name, "Plating Thickness (m\!"\!")"n, sex, height, weight} */

script = Expr(
	Fit Model(
		Y( :weight ),
		Effects( F1 ),
		Personality( "Standard Least Squares" ),
		Run(
			:weight << {Plot Actual by Predicted( 1 ), Plot Residual by Predicted( 1 ),
			Plot Effect Leverage( 1 )}
		)
	)
);

Substitute Into( script, Expr( F1 ), cols[2] );
Write( Name Expr( script ) );
/*
Fit Model(
	Y( :weight ),
	Effects( "Plating Thickness (m\!"\!")"n ),
	Personality( "Standard Least Squares" ),
	Run(
		:weight << {Plot Actual by Predicted( 1 ), Plot Residual by Predicted( 1 ),
		Plot Effect Leverage( 1 )}
	)
);
*/

Re: Name quote a strange column name

pauldeen — Mon, 06 Sep 2021 10:15:27 GMT

@txnelson The problem is that when building the fit model script the column() format cannot be used:

Fit Model(
	//Y( :"Plating Thickness (m\!"\!")"n ), <- works
	Y(column("Plating Thickness (m\!"\!"")), //<- does not work
	Effects(
		:"Shift-temp"n, :Position, :Subgroup, :"Shift-temp"n * :Position,
		:"Shift-temp"n * :Subgroup, :Position * :Subgroup
	),
	Personality( "Standard Least Squares" )
);

@Craige_Hales the users selects the columns with a Col list box() and I pass a << get items message to it. That gives me the list of column names as a string. I could locate those column names in the table and find the column number but when assembling the effects expression this method will not allow me to build the interactions as shown above.

Is there a way to do expression concatenation to go from string to col reference with name escape?

Re: Name quote a strange column name

Craige_Hales — Mon, 06 Sep 2021 10:34:55 GMT

try this combination of the two answers:

colListY = {"Plating Thickness (m\!"\!")"};
dt = Open( "$sample_data/big class.jmp" );
dt:age << setname( colListY[1] );

script = Expr(
	Fit Model(
		Y( F1 ),
		Effects( :height ),
		Personality( "Standard Least Squares" ),
		Run( F1 << {Plot Actual by Predicted( 1 ), Plot Residual by Predicted( 1 ), Plot Effect Leverage( 1 )} )
	)
);

Substitute Into( script, Expr( F1 ), Column( dt, colListY[1] ) );
Write( Name Expr( script ) );
/*
Fit Model(
	Y( Column( "Plating Thickness (m\!"\!")" ) ),
	Effects( :height ),
	Personality( "Standard Least Squares" ),
	Run(
		Column( "Plating Thickness (m\!"\!")" ) << {Plot Actual by Predicted( 1 ),
		Plot Residual by Predicted( 1 ), Plot Effect Leverage( 1 )}
	)
)
*/

Eval( script );

run with column substituted

Re: Name quote a strange column name

Craige_Hales — Mon, 06 Sep 2021 11:34:35 GMT

More notes:

I explicitly referenced the table in the column function. Might make a difference if multiple tables are open.

If you are concatenating strings, this might do it; you can always use the :"height"n even if not required (height, for example.)

colreftxt = ":" || Regex( Log Capture( Print( colListY[1] ) ), "^\s*(.*)\s*$", "\1" ) || "n";
write(colreftxt);

:"Plating Thickness (m\!"\!")"n

which might be escaped right. Expression manipulation will probably be easier than parsing text assembled like this.

Re: Name quote a strange column name

pauldeen — Mon, 06 Sep 2021 12:33:31 GMT

Thanks Craige, It seems like this is more complicated than it should be but it works :)

For anybody trying to do this, I put Craige's solution in a function:

WrapColumns = Function({ColName},{default local},
	ReturnList = {};
	If(is list(ColName),	
		For(i=1, i<=n items(ColName), i++,
			insert into(ReturnList, parse(":" || Regex( Log Capture( Print( ColName[1] ) ), "^\s*(.*)\s*$", "\1" ) || "n");)
		);
	,
		insert into(ReturnList, parse(":" || Regex( Log Capture( Print( ColName ) ), "^\s*(.*)\s*$", "\1" ) || "n");)
	);
	Return(ReturnList);
);

Re: Name quote a strange column name

Craige_Hales — Mon, 06 Sep 2021 13:59:52 GMT

It is too complicated. You can probably replace the regex() with trim() because that is all it is doing. Originally I thought it was going to remove the outer quotation marks that print() leaves behind. (edit: and there is no need to trim at all for the input to parse!)

You might have [1] where you need [i] in your example.

Re: Name quote a strange column name

pauldeen — Mon, 06 Sep 2021 14:22:07 GMT

Updated with Craige's feedback, thanks for the 1/i!

WrapColumns = Function({ColName},{default local},
	ReturnList = {};
	If(is list(ColName),	
		For(i=1, i<=n items(ColName), i++,
			insert into(ReturnList, parse(":" || Log Capture( Print( ColName[i] ) ) || "n"))
		);
	,
		insert into(ReturnList, parse(":" || Log Capture( Print( ColName ) ) || "n"))
	);
	Return(ReturnList);
);

Re: Name quote a strange column name

Craige_Hales — Mon, 06 Sep 2021 14:48:49 GMT

To explain for any one watching: the print function does two things: it escapes the internal quotation marks (and other special cases) and it adds external quotation marks. That produces a valid string, and Paul's code then adds a : in front and an n afterward and parses the result into a JSL column name constant. There might, or might not, be an actual column that the column name constant can attach to when used in a script. The column does not need to exist when Paul's code runs. Without the print() function, I'm not sure what function I'd use to get the escaping done (the rules are too complicated to write my own.) Because the original name contained embedded quotation marks, it needs the escaping before being turned into a column name constant.

If the data table is open, you can use the column() function in much the same way to get a column object that (I'm pretty sure) can be used in all the same places that the column name constant can appear. That column object refers to a real column, at least until the table is closed. Launching a platform with an expired column object or a column name constant that doesn't match a table column will produce an expected error message.

@XanGregg

Re: Name quote a strange column name

XanGregg — Wed, 08 Sep 2021 13:43:38 GMT

Can you elaborate on the "does not work" part? I tried versions back to JMP 15 and the following seems to work. Maybe I'm missing part of the issue.

Data Table( "Big Class" ):weight << Set Name( "weight\!"\!"" );

Fit Model(
	Y( Column( "weight\!"\!"" ) ),
	Effects( :age, :sex, :height ),
	Personality( "Standard Least Squares" ),
	Run()
);

Re: Name quote a strange column name

txnelson — Wed, 08 Sep 2021 13:49:09 GMT

Just for giggles, I took the code back to JMP 11.2.1 and it works great.

Re: Name quote a strange column name

pauldeen — Tue, 14 Sep 2021 08:46:03 GMT

@XanGregg Now that I'm testing it with your code it works here as well. Let me investigate and see if I can share the failing example more completely...

Re: Name quote a strange column name

jmp_demo — Tue, 14 Sep 2021 20:28:05 GMT

This is a great question!

Re: Name quote a strange column name

jmp_demo — Wed, 15 Sep 2021 19:50:17 GMT

This is a great question!

Re: Name quote a strange column name

pauldeen — Mon, 20 Sep 2021 12:51:05 GMT

After carefull testing and going back through a few of my scripts I have not been able to make it fail again. Thanks for checking!

Re: Name quote a strange column name

pauldeen — Tue, 05 Oct 2021 13:41:04 GMT

@XanGregg Column formulas don't work this way and the special quoting methods does work:

colListY = {"Plating Thickness (m\!"\!")"};
dt = Open( "$sample_data/big class.jmp" );
dt:age << setname( colListY[1] );
eval(eval expr(dt << New Column( "test",
		Numeric,
		"Continuous",
		Format( "Fixed Dec", 12, 2 ),
		Formula( expr(column(colListY[1])) - :height ),
		Set Display Width( 78 )
	)));

It produces a function column in which the formula is:

Column( "Plating Thickness (m\!"\!")" ) -  /*###*/:height/*###*/

which does not evaluate.

This does:

WrapColumns = Function({ColName},{default local},
	ReturnList = {};
	If(is list(ColName),	
		For(i=1, i<=n items(ColName), i++,
			insert into(ReturnList, parse(":" || Log Capture( Print( ColName[i] ) ) || "n"))
		);
	,
		insert into(ReturnList, parse(":" || Log Capture( Print( ColName ) ) || "n"))
	);
	Return(ReturnList);
);

eval(eval expr(dt << New Column( "test2",
		Numeric,
		"Continuous",
		Format( "Fixed Dec", 12, 2 ),
		Formula( expr(WrapColumns(colListY)[1]) - :height ),
		Set Display Width( 78 )
	)));

Do you know a way to fix this with the column() system?

Re: Name quote a strange column name

Craige_Hales — Tue, 05 Oct 2021 13:54:40 GMT

(without trying it, so might be wrong)

Formula( column(expr(colListY[1])) - :height ),

I think you want the expr inside the column. That way the column function is evaluated later, using the string captured earlier.

Re: Name quote a strange column name

pauldeen — Tue, 05 Oct 2021 14:56:06 GMT

That results in a column formula error for me

Re: Name quote a strange column name

Craige_Hales — Tue, 05 Oct 2021 15:39:33 GMT

colListY = {"Plating Thickness (m\!"\!")"};
dt = Open( "$sample_data/big class.jmp" );
dt:age << setname( colListY[1] );
Eval(
	Eval Expr(
		dt << New Column( "test",
			Numeric,
			"Continuous",
			Format( "Fixed Dec", 12, 2 ),
			Formula( Column( Expr( colListY[1] ) )[]  ),
			Set Display Width( 78 )
		)
	)
);

The empty [ ] tells JMP to evaluate the column for the current row.

Building column formulas like this probably hides the underlying column dependencies from JMP's formula evaluator; see discussion. If you have formula columns depending on other formula columns, JMP may not be able to peer into this indirection to figure out what to evaluate first.