topic Re: How to write a script for selecting several columns (>1000) in a data table as input for an Analysis (e.g. inverse correlations) in Discussions

How to write a script for selecting several columns (>1000) in a data table as input for an Analysis (e.g. inverse correlations)

Anders_M — Sat, 10 Jun 2023 23:36:18 GMT

Hi I am new to JSL and would like to make a script for selecting multiple columns (>1000) and to use them an input for analysis. For example using the Mulitvariate analysis tool and calculating the inverse correlation.
I have made a script for selecting two columns for Bivariate analysis but how to extend it for multiple columns as used in e.g Mulitvariate analysis.

I have tried to find clues at this forum but I do something wrong and I am stuck. I would be very greatful if someone could help me with this.

Best Regards /Anders

Names Default To Here( 1 );
dt = Open( "$SAMPLE_DATA/Big Class.jmp" );
xvar = .;
yvar = .;
win = New Window( "Example of Returning Values",
	<<Modal,
	Text Box( " Select numeric columns. " ),
	H List Box(
		Text Box( " X, Factor " ),
		x = Col List Box(
			dt, // data table reference
			all, // display all columns from the data table
 
// get the name of the selected column before the window closes

			xvar = (x << Get Selected)[1];
			Show( xvar );
			
		),
		Text Box( "Y, Response" ),
		y = Col List Box(
			dt,
			all,
			yvar = (y << Get Selected)[1];
			Show( yvar );
		)
	)
);
If (win["Button"] == 1, // if the user clicks OK...
xcol = Column( dt, xvar ); //  get the columns
ycol = Column( dt, yvar );


dt << Bivariate( Y( ycol ), X( xcol ) ); // create a Bivariate plot
//dt << Multivariate( Y(ycol), Inverse Correlations(1)); // create a Inverse Correlation Matris
// How to select several columns as input for Multivariate ( Y(???), Inverse Correlations(1));
);

Re: How to write a script for selecting several columns (>1000) in a data table as input for an Analysis (e.g. inverse correlations)

txnelson — Sun, 29 Aug 2021 12:39:17 GMT

You were headed in the right direction. Your original script limited the Yvar to only 1 variable, and so by removing that restriction it lets one choose multiple variables, which then are transferred as a list to the Multivariate input.

Names Default To Here( 1 );
dt = Open( "$SAMPLE_DATA/semiconductor capability.jmp" );
xvar = .;
yvar = .;
win = New Window( "Example of Returning Values",
	<<Modal,
	Text Box( " Select numeric columns. " ),
	H List Box(
		
		Text Box( "Y, Response" ),
		y = Col List Box(
			dt,
			all,
			yvarList = (y << Get Selected);
			Show( yvarList );
		)
	)
);
If( win["Button"] == 1, // if the user clicks OK...
	Multivariate(
		Y( Eval( yvarList ) ),
		Estimation Method( "Row-wise" ),
		Scatterplot Matrix( 1 ),
		Inverse Correlations( 1 )
	)
);

Re: How to write a script for selecting several columns (>1000) in a data table as input for an Analysis (e.g. inverse correlations)

jthi — Sun, 29 Aug 2021 12:47:18 GMT

You could also take a look at Column Dialog instead of building modal new window. Depending on the level of customization you need, it might be simpler to use.

Names Default To Here(1);
dt = Open("$SAMPLE_DATA/Solubility.jmp");
colDiag = Column Dialog(y = ColList("Y", Data Type("Numeric")));
dt << Multivariate(Y(colDiag["y"]));

Re: How to write a script for selecting several columns (>1000) in a data table as input for an Analysis (e.g. inverse correlations)

txnelson — Sun, 29 Aug 2021 13:18:56 GMT

I like this a lot!

Re: How to write a script for selecting several columns (>1000) in a data table as input for an Analysis (e.g. inverse correlations)

Anders_M — Fri, 03 Sep 2021 06:08:05 GMT

Thanks Jarmo.

A good suggestion for lower level of customization and simpler use. /Anders

Re: How to write a script for selecting several columns (>1000) in a data table as input for an Analysis (e.g. inverse correlations)

Anders_M — Thu, 09 Sep 2021 19:06:42 GMT

Thanks, that's a very simple way!