JSL create lines on graphs

itzikd — Fri, 09 Jun 2023 19:47:41 GMT

Hello,

so I'm trying to create red lines that will be like in this script

Names Default To Here( 1 );

dt = Current Data Table();

listX = {"1"};
listY = {"test1", "test2", "test3"};
lowLine = 3;
highLine = 5;
		
bivExpr = Expr(
	Bivariate(
		Y( Eval List( listY ) ),
		X( Eval List( listx ) ),
		Fit Spline( 1, Standardized, {Line Color( "Blue" )} ),
		SendToReport(
			Dispatch(
				{},
				"Bivar Plot",
				FrameBox,
				{Add Graphics Script(
					2,
					Description( "Script" ),
					Pen Color( "Red" );
					Line Style( "dashed" );
					X Function( lowLine, x );
					X Function( highLine, x );
				), Grid Line Order( 1 ), Reference Line Order( 3 )}
			)
		)
	)
);

bivExpr;

and my table DT is like this:

Group	test1	test2	test3	1	1
BL	1	1	1	1	1
BL	2	2	2	2	65
BL	23	3	6	1	1
POR	2	2	2	2	2
Value1	1	1	1	3	4
POR	5	7	2	2	2
Value1	7	5	1	7	3
Value2	2	2	2	2	2
Value0	8	1	1	1	6

result:

my question is how can I create different lines for each graph (for the first one 3-5 for the 2nd one 2-7 and so on dynamically)

thanks!

Re: JSL create lines on graphs

txnelson — Sun, 23 May 2021 17:41:25 GMT

Using Reference Lines is how I would handle this

Names Default To Here( 1 );

dt = Current Data Table();

listX = {"1"};
listY = {"test1", "test2", "test3"};

lowList = {3, 2, 1};
highList = {5, 7, 9};

lowLine = 3;
highLine = 5;
		
bivExpr = Expr(
	biv = Bivariate(
		Y( Eval List( listY ) ),
		X( Eval List( listx ) ),
		Fit Spline( 1, Standardized, {Line Color( "Blue" )} )
	);
	For( i = 1, i <= N Items( listY ), i++,
		Report( biv[i] )[AxisBox( 2 )] << add Ref Line( lowList[i], "Dashed", "Red" );
		Report( biv[i] )[AxisBox( 2 )] << add Ref Line( highList[i], "Dashed", "Red" );
	);
);

bivExpr;

topic JSL create lines on graphs in Discussions

JSL create lines on graphs

Re: JSL create lines on graphs