topic script to add two column in Discussions

script to add two column

tangxu — Fri, 09 Jun 2023 22:04:43 GMT

i am trying to add two columns.

two of the column has name abcd and efgh

following line works:

dt_tab << New Column( newcolumn, formula( :name( "abcd" ) + :name( "efgh" ) ) );

but following code is throwing an error

name1 = "abcd";
name2 ="efgh";

dt_tab << New Column( name1 || "3", formula(:name(name1) + :name(name2)));

why is the 2nd method not working?

Re: script to add two column

txnelson — Mon, 01 Feb 2021 03:09:19 GMT

The reason this is not working, is that neither the :Name() function nor the Formula() element does not parse the contents of the function before execution. You need to create the exact JSL before execution

name1 = "abcd";
name2 = "efgh";

Eval(
	Substitute(
			Expr(
				dt_tab << New Column( name1 || "3",
					formula( Column( __name1__ ) ) + Column( __name2__ )
				)
			),
		Expr( __name1__ ), name1,
		Expr( __name2__ ), name2
	)
);

Re: script to add two column

tangxu — Mon, 01 Feb 2021 04:56:18 GMT

Thank you Jim. I tried this but still not working.

Re: script to add two column

txnelson — Mon, 01 Feb 2021 05:13:25 GMT

My error......I had placed an ")" wrong, and should have used the As Column() function, not the Column() function

Names Default To Here( 1 );
dt_tab = New Table( "Example",
	Add Rows( 4 ),
	New Column( "abcd", 

		Numeric,
		"Continuous",
		Format( "Best", 12 ),
		Set Values( [1, 2, 3, 4] )
	),
	New Column( "efgh",
		Numeric,
		"Continuous",
		Format( "Best", 12 ),
		Set Values( [5, 6, 7, 8] )
	)
);

name1 = "abcd";
name2 = "efgh";

Eval(
	Substitute(
			Expr(
				dt_tab <<
				New Column( name1 || "3",
					formula(
						As Column( __name1__ )
						+As Column( __name2__ )
					)
				)
			),
		Expr( __name1__ ), name1,
		Expr( __name2__ ), name2
	)
);