Adding Tabulate Table into journal

OneNorthJMP — Sat, 10 Jun 2023 23:21:09 GMT

I try to add a tabulate table into my journal for reporting. But i been stuck in JSL with error and the tabulate table is not able to add into journal. Please advise what am i missing?

Names Default To Here( 1 );
Clear Symbols();
Clear Log();
Close All( Data Tables, NoSave );
Close All( Journals, NoSave );

//Journal
nw = New Window( "Reports",
	<<Journal,
	hlb = H List Box(
		lub = Lineup Box( N Col( 1 ) )
	)
);

lub << Append ( sb = Spacer Box( size (10, 500), color ("White") ) );
lub << Append( tb = Text Box( "VENUS SMIC CYCLING REPORT " || Short Date( Today() ) ));
tb << Set Font Size( 20 ) << Set Font Style( "Bold" ) << Justify Text( "Center" );
tb << set width(1500) << set wrap((1500));
lub << Append( Page Break Box() );


//*************************************
dt_source = Open( "TEST.jmp" );

dt_source:hardbin << Data Type( Character );

dt_source << New Column( "FFT", "Character", "Norminal", 
	Formula(
		If( :hardbin == 1,
			"Pass;1",
			Char( :Name( "failtest_name,0,0" ) || ";" || Char( :Name( "failtest_number,0,0" ) ) )
		)
	)	
);


obj_table = dt_source << Tabulate(
	Show Control Panel( 0 ),
	Add Table(
		Column Table( Grouping Columns( :Wafer ) ),
		Row Table(
			Grouping Columns( :hardbin, :BinName, :FFT ),
			Statistics( Name( "% of Total" ) )
		)
	)
);

lub << Append( obj_table ); // where i got the error

Re: Adding Tabulate Table into journal

txnelson — Fri, 23 Oct 2020 03:14:57 GMT

You need to reference the report object from the Tabulate

lub << Append( Report( obj_table ) );

Re: Adding Tabulate Table into journal

OneNorthJMP — Fri, 23 Oct 2020 03:24:26 GMT

Thanks Nelson. It work

topic Adding Tabulate Table into journal in Discussions

Adding Tabulate Table into journal

Re: Adding Tabulate Table into journal

Re: Adding Tabulate Table into journal