topic Re: how to set the control limit for a column using other columns? in Discussions

how to set the control limit for a column using other columns?

Mikasa — Fri, 09 Jun 2023 23:39:23 GMT

Hi every one.

I know this question might be repeated. I have read all answers for example

I have a column (:X) and I have three columns for :X control limits, (UCL,LCL, Ave). and I like to set the control limits to :X, but I am confused.

I tried ;

:X<<Set Property("Control Limits", {XBar(Ave(:Center Line[1]),LCL( :Lower Limit[1] ), UCL( Upper Limit[1] )), Show Control Limits( 1)});

But it does not work.

Also, sometimes in UCL,LCL, and AVE columns, I have different values for different rows in :X

I know it is not possible to have different set of Spec limits for a Colum but I was wondering if there is a way to do that for Control limit.

Thanks

Re: how to set the control limit for a column using other columns?

statman — Wed, 30 Sep 2020 19:07:04 GMT

Sorry, I'm a bit confused by your inquiry. Why don't you let JMP calculate the control limits (or create control charts) on your x column? You realize control limits are a function of the data, how it was collected and how you are subgrouping it?

Re: how to set the control limit for a column using other columns?

Mikasa — Wed, 30 Sep 2020 20:05:10 GMT

Thanks @statman

I am creating a report and my data table include all data that I pull by JMP. I wrote an script for my report and making a HTML report at the end. This script has to be run every day, so I am not sure if I can do what you are suggesting.

Re: how to set the control limit for a column using other columns?

statman — Wed, 30 Sep 2020 20:17:35 GMT

Hopefully you aren't just changing control limits every day? And hopefully the control limits are appropriate for your data set.

Re: how to set the control limit for a column using other columns?

Mikasa — Wed, 30 Sep 2020 21:27:16 GMT

No the data table will be updated daily too. and all the data are pulled out from the same tool and appropriate.

Re: how to set the control limit for a column using other columns?

txnelson — Wed, 30 Sep 2020 21:34:10 GMT

The values within Lists will not be executed, therefore, you need to use the below methodology to create the JSL needed to upload the Control Limits

Eval(
	Substitute(
			Expr(
				:X << Set Property(
					"Control Limits",
					{XBar( Ave( __avg__ ), LCL( __LCL__ ), UCL( __UCL__ ) ),
					Show Control Limits( 1 )}
				)
			),
		Expr( __avg__ ), :Center Line[1],
		Expr( __LCL__ ), :Lower Limit[1],
		Expr( __UCL__ ), :Upper Limit[1]
	)
);

Re: how to set the control limit for a column using other columns?

Mikasa — Thu, 01 Oct 2020 03:23:10 GMT

Thanks Jim
this method works for the Spec limits but does not show the control limits. I am not sure what is wrong

Re: how to set the control limit for a column using other columns?

txnelson — Thu, 01 Oct 2020 03:38:54 GMT

I was going to comment on your "Show Limits()" element you added to the Control Limits specification. As far as I know, Spec Limits and Response are the only limits that will automatically display on charts and graphs.

Control limits can be set for different phases in the data table. The Control Chart Platforms can handle the phases and the displaying of control limits. Once you go outside of the Control Limits Platforms, the displaying of control limits has to be done by adding JSL to the charts to display the limits.

Re: how to set the control limit for a column using other columns?

Mikasa — Thu, 01 Oct 2020 15:18:39 GMT

sorry Jim, I think I am confused with your answer,

I added

Eval(
Substitute(
Expr(
:REM OX << Set Property(
"Control Limits",
{XBar( Ave( __avg__ ), LCL( __LCL__ ), UCL( __UCL__ ) ),
Show Control Limits( 1 )}
)
),
Expr( __avg__ ), :Center Line[1],
Expr( __LCL__ ), :Lower Limit[1],
Expr( __UCL__ ), :Upper Limit[1],
),
);

to my script to upload the limits.

It does not show any thing on the charts. It is working for Spec limits.

I could not understand your comment about Show Control limits()

Re: how to set the control limit for a column using other columns?

txnelson — Thu, 01 Oct 2020 20:00:33 GMT

As I stated in my last response:
As far as I know, Spec Limits and Response are the only limits that will automatically display on charts and graphs

Control Limits do not have the capability to automatically be displayed on charts, except for Control Charts!

Re: how to set the control limit for a column using other columns?

Byron_JMP — Mon, 05 Oct 2020 19:11:35 GMT

@txnelson I'm pretty sure you're right.

Do you think it would be possible to have an axis property reference a control limit property?

Re: how to set the control limit for a column using other columns?

Mark_Bailey — Mon, 05 Oct 2020 21:29:36 GMT

Some JMP platforms might use more than one column property, but they are not linked in any way, if that is what you are asking. Your script would have to use 'setter and getter' actions to coordinate anything beyond what JMP does automatically.

Re: how to set the control limit for a column using other columns?

txnelson — Tue, 06 Oct 2020 16:11:52 GMT

Here is a simple example that

Populates the Control Limits for a column
Runs a Distribution Platform
Adds the Control Limits from the displayed column on the graphical output

names default to here(1);

// Open a sample data table
dt=open("$SAMPLE_DATA/big class.jmp" );

// Add a column to be used as the subgroup
dt << new column( "group", formula(Mod(Row(), 4)));

// Add the Control Limits columns to the data table
dt << new column("Center Line", set values({62.55}));
dt << new column("Lower Limit", set values({58.08}));
dt << new column("Upper Limit", set values({67.02}));

// Set the name of the Height column to match the previously distributed
// code
dt:height << set name("X");


// Set the column Property for the Control Limits
Eval(
	Substitute(
			Expr(
				:X << Set Property(
					"Control Limits",
					{XBar( avg( __avg__ ), LCL( __LCL__ ), UCL( __UCL__ ) )}
				)
			),
		Expr( __avg__ ), :Center Line[1],
		Expr( __LCL__ ), :Lower Limit[1],
		Expr( __UCL__ ), :Upper Limit[1]
	)
);

// Run a platform that creates a graph
dist = Distribution( Continuous Distribution( Column( :X ) ) );

// Extract the Control Limits from the column
contLimits = :X << get property("Control Limits");

// Parse through the returned Limits to get the LCL, UCL and Avg
contLimits=char(contLimits);
found=contains(contLimits,"XBar");
contLimits=substr(contLimits,found+5);
found=contains(contLimits,"avg");
contLimits=substr(contLimits,found+4);
theAvg = num( word(1,contLimits,")"));
found=contains(contLimits,"LCL");
contLimits=substr(contLimits,found+4);
theLCL = num( word(1,contLimits,")"));
found=contains(contLimits,"UCL");
contLimits=substr(contLimits,found+4);
theUCL = num( word(1,contLimits,")"));

// Add reference lines to the graph with the Control Limit values
report(dist)[AxisBox(1)] << add ref line(theLCL,Solid,Black,"LCL");
report(dist)[AxisBox(1)] << add ref line(theUCL,Solid,Black,"UCL");
report(dist)[AxisBox(1)] << add ref line(theAvg,Solid,Black,"Ave");