topic Re: Make error message in Discussions

Make error message

LBrian — Fri, 09 Jun 2023 23:32:53 GMT

Hi, All.

I want to make an error message 'No item' window.

I made a script. but, it has not worked.

Please check my script where is wrong.

Names Default To Here( 1 );
dt = Open( "$Sample_Data/Blood pressure.jmp" );
dt<< show window( 0 );

win = New Window( "Select Item(s) for drawing the Histogram",
		<<Modal,
		Text Box( "Item List" ),
		H List Box(
			allcols = Col List Box( dt, all ),
			Lineup Box(
				2,
				V List Box(
					bbAdd = Button Box( "Add", xcols << append( allcols << get selected ) ),
					bbRemove = Button Box( "Remove", xcols << remove selected )

				),
				xcols = Col List Box( "Numeric", <<Modeling Type( {"Continuous"} ), min items( 1 ) ),

			),
			V List Box(
				bbOK = Button Box( "OK",
					xvar = (xcols << Get Items);
					str = "";
					
					show(xvar);
					
					if(xvar == "{}",
					Throw("No item")
					);					
					For( i = 1, i <= N Items( xvar ), i++,
						str = str || "Continuous Distribution(Column(:Name(\!"" || xvar[i] || "\!"))),"
					);
					Eval( Parse( "dt << Distribution(stack(1)," || str || ");" ) );
					win << Close Window;
					
	
				),
				bbCancel = Button Box( "Cancel", Throw() )
			)
		)
	);

Thanks.

Re: Make error message

tom_abramov — Wed, 22 Jul 2020 06:56:14 GMT

Hi,

add error window message in case of zero column added:

Names Default To Here( 1 );
dt = Open( "$Sample_Data/Blood pressure.jmp" );
dt<< show window( 0 );

win = New Window( "Select Item(s) for drawing the Histogram",
		//<<Modal,
		Text Box( "Item List" ),
		H List Box(
			allcols = Col List Box( dt, all ),
			Lineup Box(
				2,
				V List Box(
					bbAdd = Button Box( "Add", xcols << append( allcols << get selected ) ),
					bbRemove = Button Box( "Remove", xcols << remove selected )

				),
				xcols = Col List Box( "Numeric", <<Modeling Type( {"Continuous"} ), min items( 1 ) ),

			),
			V List Box(
				bbOK = Button Box( "OK",
					xvar = (xcols << Get Items);
					
					str = "";
					
					show(xvar);
					
					if(NItems(xvar) == 0,
					ErrWin = New Window("Error",<<modal, Text Box( "\!NPlease add columns\!N\!N" ))
					,//else					
					For( i = 1, i <= N Items( xvar ), i++,
						str = str || "Continuous Distribution(Column(:Name(\!"" || xvar[i] || "\!"))),"
					);
					Eval( Parse( "dt << Distribution(stack(1)," || str || ");" ) );
					win << Close Window;
					);//end of if
	
				),
				bbCancel = Button Box( "Cancel", Throw() )
			)
		)
	);

Re: Make error message

LBrian — Wed, 22 Jul 2020 07:29:38 GMT

Thank you very much!!!!