topic Re: How to delete outlinebox that not required from graphs in Discussions

How to delete outlinebox that not required from graphs

joshua — Sun, 05 Apr 2020 06:25:05 GMT

I want to delete outlinebox that are not required (or I don't want have).

Following this post https://community.jmp.com/t5/Discussions/How-to-show-fit-line-graphs-in-a-single-report-without-the/td-p/46302

We can delete the all of the boxes. But I want to keep only 'Linear Fit Site == 1' and the equation

So I tried

Names Default To Here( 1 );
dt = Open( "$SAMPLE_DATA/Semiconductor Capability.jmp" );
biv = Bivariate(
	Y( :NPN1 ),
	X( :PNP1 ),
	Fit Where( :SITE == 1, Fit Line( {Line Color( {213, 72, 87} )} ) ));
	
biv[Outline Box(3)] << Delete;	
biv[Outline Box(4)] << Delete;
biv[Outline Box(5)] << Delete;

But still those boxes are there. The expected output that I need

Re: How to delete outlinebox that not required from graphs

txnelson — Sun, 05 Apr 2020 09:38:23 GMT

See my annotated JSL below

Names Default To Here( 1 );
dt = Open( "$SAMPLE_DATA/Semiconductor Capability.jmp" );
biv = Bivariate(
	Y( :NPN1 ),
	X( :PNP1 ),
	Fit Where( :SITE == 1, Fit Line( {Line Color( {213, 72, 87} )} ) ));
	
// When you are modifying the output from a Platform
// one needs to access the report
// Additionally, you need to delete the outline boxes either in
// reverse order as below, since the Butline Box nomenclature
// will change after the deletion of a box.  That is, if you delete
// Outline Box(3) first, once it is deleted, what was Outline Box(4)
// will now be the 3rd Outline Box etc.	
Report(biv)[Outline Box(5)] << Delete;
Report(biv)[Outline Box(4)] << Delete;
Report(biv)[Outline Box(3)] << Delete;

/*
// To illustrate this, you can actually eliminate the 3 Outline Boxes
// with the code below
Report(biv)[Outline Box(3)] << Delete;
Report(biv)[Outline Box(3)] << Delete;
Report(biv)[Outline Box(3)] << Delete;

// and an alternative method would be to use direct references
Report(biv)["Summary of Fit"] << Delete;
Report(biv)["Analysis of Variance"] << Delete;
Report(biv)["Parameter Estimates"] << Delete;
*/

Re: How to delete outlinebox that not required from graphs

Craige_Hales — Sun, 05 Apr 2020 11:29:33 GMT

Also consider using <<Visibility rather than <<Delete.

Report(biv)[Outline Box(3)] << Visibility("collapse");

"Collapse" will hide the box and remove the space it uses in the report, without deleting the box. Two advantages: (1) the displaybox numbering does not shift around and (2) some platforms might be confused by deleting certain display boxes they depend on.

I like Jim's final example combined with Visibility:

dt = Open( "$SAMPLE_DATA/Semiconductor Capability.jmp" );
biv = Bivariate(
	Y( :NPN1 ),
	X( :PNP1 ),
	Fit Where( :SITE == 1, Fit Line( {Line Color( {213, 72, 87} )} ) ));
	
Report(biv)["Summary of Fit"] << Visibility("collapse");
Report(biv)["Analysis of Variance"] << Visibility("collapse");
Report(biv)["Parameter Estimates"] << Visibility("collapse");

which explains itself to anyone that needs to understand or maintain it later.