topic Re: Script multiple columns grouped in distribution plot in Discussions

Script multiple columns grouped in distribution plot

RonSwanson — Sat, 23 Feb 2019 17:25:10 GMT

I'm trying to script a way to plot multiple parameter columns that are grouped together in a distribution (as shown in figure). My problem is the code needs a separate "Continuous Distribution" row for each parameter column. My data pulls have different column names and number of columns to plot depending on what I'm doing. I can't figure out how to take that column name list and have it plotted in a group as show below, rather than looping through and creating individual plots for each parameter.

Distribution(
	Continuous Distribution( Column( :Parameter1 ) ),
	Continuous Distribution( Column( :Parameter2 ) ),
	Continuous Distribution( Column( :Parameter3 ) )
);

Re: Script multiple columns grouped in distribution plot

txnelson — Sat, 23 Feb 2019 19:31:06 GMT

Here is one way to generate the code required to produce what you want

Names Default To Here( 1 );
dt = Open( "$SAMPLE_DATA/big class.jmp" );

// Get the all of the numeric, continuous column names
colNames = dt << get column names( string, continuous );

// Build a character string that represents the commands that need to be run
theExpr = "dis = dt << Distribution(
	Continuous Distribution( column( column(dt, colNames[1])))";

// Loop across the remaining columns in the colNames list and generate the continuous distribution
// commands
For( i = 2, i <= N Items( colNames ), i++,
	theExpr = theExpr || ", Continuous Distribution( column( column(dt, colNames[" || Char( i ) || "])))"
);

// place the closing ")" to complete the command string
theExpr = theExpr || ");";

// Execute the code generated and placed into the character string variable
Eval( Parse( theExpr ) );

Re: Script multiple columns grouped in distribution plot

RonSwanson — Sun, 24 Feb 2019 16:11:25 GMT

exactly what I needed... thanks tx!!

Re: Script multiple columns grouped in distribution plot

gzmorgan0 — Mon, 25 Feb 2019 05:30:16 GMT

@RonSwanson ,

Jim @txnelson's script provides you much more control and a solution. This as an alternate option, since I have often been asked how to easily script an unknown number of distributions. This script also includes commands to "wrap" distributions and how to send messages to all distributions by sending a message to the object (Capability Analysis message) and to send a message to the reveal icon.

Names default to Here(1);

dt = Open("$Sample_Data/Semiconductor Capability.jmp");

cnames = dt << get column names("Continuous", "string");

//Here I will just use 10

cnames = cnames[1::10];
 dist = dt << Distribution(Columns(evalList(cnames)));
 //if you want to limit the number per row
 dist << arrange in rows(3);  //change 3 to 5 or whatever you want

 dist << Capability Analysis(0);  //turn off the distribution
 
report(dist)[OutlineBox(2)] << Open all like this(1);    //reveal all distributions
 
 report(dist)[OutlineBox(2)] << Close all like this(1);  //do not reveal

Re: Script multiple columns grouped in distribution plot

ducksb0y — Thu, 01 Aug 2019 08:27:45 GMT

@txnelson i have used this script and it worked. What i am trying to do is automating my report but my data table is composed of 300+ columns, number of columns vary per week. I have column names that starts with ex. "Fail1", "Fail2",,, "Total1","Total2",,, "Yield1", "Yield2",,, "Loss1", "Loss2",,. How to filter to show continuous distributions for example "Loss1", "Loss2",, only?

Re: Script multiple columns grouped in distribution plot

txnelson — Thu, 01 Aug 2019 12:33:52 GMT

All you need to do is to modify the list of column names, to meet the requirements. There are many ways to do this, below is one example

Names Default To Here( 1 );
dt = Open( "$SAMPLE_DATA/semiconductor capability.jmp" );

// Get the all of the numeric, continuous column names
colNames = dt << get column names( string, continuous );

// Work backwards through the list of columns eliminating those that
// do not meet the pattern one is interested in
For( i = N Items( colNames ), i >= 1, i--,
	If( left( colNames[i], 3 ) != "NPN" , colNames = remove( colNames, i, 1 ) );
);

// Build a character string that represents the commands that need to be run
theExpr = "dis = dt << Distribution(
	Continuous Distribution( column( column(dt, colNames[1])))";

// Loop across the remaining columns in the colNames list and generate the continuous distribution
// commands
For( i = 2, i <= N Items( colNames ), i++,
	theExpr = theExpr || ", Continuous Distribution( column( column(dt, colNames[" || Char( i ) || "])))"
);

// place the closing ")" to complete the command string
theExpr = theExpr || ");";

// Execute the code generated and placed into the character string variable
Eval( Parse( theExpr ) );

Re: Script multiple columns grouped in distribution plot

spudton — Tue, 07 Jul 2020 15:21:55 GMT

If I wanted to put that into an application, with a local data filter, could I put the Allocate statement inside the Eval(Parse) ?

So..

theExpr = "dis = Allocate(
				Border1 = Border Box();
				DataFilterContext1 = Data Filter Context Box();
				List1 = H List Box();
				DataFilter1 = Dt << Data Filter( Local );
				Report1 = Platform(
					Dt,
					Distribution(
	Continuous Distribution( column( column(Dt, colNames[1])))";

	For( i = 2, i <= N Items( colNames ), i++,
	theExpr = theExpr || ", Continuous Distribution( column( column(Dt, colNames[" || Char( i ) || "])))"
);

theExpr = theExpr || "	)
	);
	)";
	
	show(theexpr);
Eval( Parse( theExpr ) );

Re: Script multiple columns grouped in distribution plot

txnelson — Tue, 07 Jul 2020 16:33:47 GMT

The short answer is No. At a minimum you need to create a character string that includes all of the JMP App code.

Re: Script multiple columns grouped in distribution plot

spudton — Wed, 08 Jul 2020 07:10:13 GMT

OK Thanks.

what would be your strategy for doing this? Would you avoid using application builder with allocate etc, and just use a script to position everything?

thanks again

Wayne.

Re: Script multiple columns grouped in distribution plot

txnelson — Wed, 08 Jul 2020 08:16:53 GMT

I would just avoid the overhead of placing it into an application.

Re: Script multiple columns grouped in distribution plot

spudton — Wed, 08 Jul 2020 09:07:03 GMT

Noted, I think that my assumption that everything starts with an application has caused me much pain.

One more question, hopefully, If I want to set the properties of all the distributions in a report, as I've done with this single variable here, "T05066DD ET_DELTA Ratio" is there a simple command to do it, or do i need to build a for loop and run the "sendtoreport" for each variable in my list?

ET_DELTA_List = {};
dist = dt << Distribution(Columns(evalList(ET_DELTA_List)));

 dist << arrange in rows(5);  
 dist << Quantiles(0);  
 dist << Summary Statistics(0);  
 
report(dist)[OutlineBox(2)] << Open all like this(1);    
 //show properties(dist)
 
 dist <<	SendToReport(
		Dispatch(
			{"T05066DD ET_DELTA Ratio"},//this is one of many distributions. i would like to set the following properties to all the distributions in the report
			"1",
			ScaleBox,
			{Min( -5 ), Max( 5 ), Inc( 5000 ), Minor Ticks( 1 ),
			Add Ref Line( 2, "Solid", "Black", "", 1 ),
			Add Ref Line( -2, "Solid", "Black", "", 1 )}
		)
	)

Re: Script multiple columns grouped in distribution plot

txnelson — Wed, 08 Jul 2020 10:16:28 GMT

Here is how I would handle the issue

names default to here(1);
dt=open("$SAMPLE_DATA/semiconductor capability.jmp");

colList = dt << get column names(continuous,string);
// For this illustration I want to use just the NPNn columns
for(i=nitems(colList), i>=1,i--,
	If(substr(colList[i],1,3)!="NPN", remove from(colList,i,1))
);

// build the JSL string
theExpr = 
"Dis = Distribution(
		Continuous Distribution( Column( :" || colList[1] || " ), 
		Process Capability( Use Column Property Specs ) )";
For( i = 2, i <= N Items( colList ), i++,
	theExpr = theExpr || "," || "Continuous Distribution( Column( :" || colList[i] ||
	" ), Process Capability( Use Column Property Specs ) )"
);
theExpr=theExpr||");";

// run the built JSL string
eval(parse(theexpr));

// Standardize the settings
disr = Dis << report;

disr[colList[1]]["Quantiles"]<<close all like this;
disr[colList[1]]["Summary Statistics"]<<close all like this;
disr[colList[1]]["Process Capability"]<<close all like this;

For(i=1,i<=nitems(colList),i++,
	disr[colList[i]][AxisBox(1)] << min(87) << max(127) << inc(5)
	<< Add Ref Line( 121, "Solid","Black","",1)
	<< Add Ref Line( 100, "Solid", "Black", "", 1 )
	<< Add Ref Line( 90, "Solid", "Black", "", 1 )
);