topic Re: Select specific columns with JSL name contains code in Discussions

Select specific columns with JSL name contains code

Thomas1 — Wed, 22 Aug 2018 13:34:19 GMT

The Name contains script:

Names Default To Here( 1 );
dt = Open( "$SAMPLE_DATA/Big Class.jmp" );
New Window( "Filter Col Selector Example",
    fontobj = lb = Filter Col Selector( width( 250 ) )
);
lb << Name contains( "a" );

delviers all colums, which contains a. What code must be added in order to mark one of these columns by clicking or double clikking the column from the list box?

Re: Select specific columns with JSL name contains code

gzmorgan0 — Wed, 22 Aug 2018 23:32:56 GMT

Try this

Names Default To Here( 1 );
dt = Open( "$SAMPLE_DATA/Big Class.jmp" );
New Window( "Filter Col Selector Example",
    fontobj = lb = Filter Col Selector( width( 250 ) )
);
lb << Name contains( "a" );

//select name

_xx = lb << get items;
_idx = Contains(_xx, "name");
lb << set selected( _idx, 1);  //or 0 to unselect

To see the available messages for an object select Main Menu > Scripting Index > Display Box > FilterColSelector

Re: Select specific columns with JSL name contains code

Thomas1 — Thu, 23 Aug 2018 06:40:43 GMT

Thanks for your reply. Unfortunately, I did not get the results with the JSL update. Right now, I do not know why.

What I actually want is to get a similar behavior like for Cols / Columns Viewer ... / Name Contains … in JMP.

In general, this is possible with the mentioned JSL code from the Scripting Index:

Names Default To Here( 1 );

dt = Open( "$SAMPLE_DATA/Big Class.jmp" );

New Window( "Filter Col Selector Example",

       fontobj = lb = Filter Col Selector( width( 250 ) )

);

lb << Name contains( );

However after the search string has been run, I I’d like to mark the desired / selected column in the data table, by double click. This part is still missing or not working within the JSL code from the Scripting Index.

Re: Select specific columns with JSL name contains code

ian_jmp — Thu, 23 Aug 2018 08:17:15 GMT

Not sure I have understood correctly, but is this what you are after?

Names Default To Here( 1 );

dt = Open( "$SAMPLE_DATA/Big Class.jmp" );

// Make a FilterBoxSelector
New Window( "Filter Col Selector Example", lb = Filter Col Selector( width( 250 ) ));

// Define and set an 'action' script
actionScript =
Expr(
	selected = lb << getSelected;
	dt << clearColumnSelection;
	dt << selectColumns(selected);
);
lb << setScript(actionScript);

// Try it out
lb << Name contains("sex");
Wait(3);
lb << Name contains("eight");

Re: Select specific columns with JSL name contains code

gzmorgan0 — Thu, 23 Aug 2018 09:47:23 GMT

Ian,

This is somewhat of a related question. Since the blogger response had lb<< Name Contains(), I assumed, the request is for the user to enter a filter field and all columns would be selected.

So I tried to expose the Filter field (Show Filter). I failed at multiple attempts to enable this second menu item via JSL.

Is there a method to enable the filter field and configure the filter? I can get the PopupBox Menu Count, and Menu Text, but not the selection.

Re: Select specific columns with JSL name contains code

Thomas1 — Thu, 23 Aug 2018 09:57:05 GMT

Thanks for your support Ian. It is not yet working as I want.

I' m looking for JSL code with which I can general search for specific columns by name ( part1) and then select the desired column in the list box from part1 by double clicking and mark the column in the data table.

The general search part1 is done with JSL code:

Names Default To Here( 1 );
dt = Current Data Table();
New Window( "Column Search",
	fontobj = lb = Filter Col Selector( width( 250 ) )
);
lb << Name contains(  );

The marking part2 could be done for the example like the code from the scripting index

Names Default To Here( 1 );
dt = Open( "$SAMPLE_DATA/Blood Pressure.jmp" );
dt << Go to( :BP 12F );

How must they combined in order to find, mark and go to the columns in a data table?

Re: Select specific columns with JSL name contains code

gzmorgan0 — Thu, 23 Aug 2018 10:02:08 GMT

Figured it out:

Names Default To Here( 1 );
dt = Open( "$SAMPLE_DATA/Big Class.jmp" );

New Window( "Filter Col Selector Example",
    fcb = Filter Col Selector( width( 250 ) )
);
ib = (fcb<<Parent) << Xpath("//IfBox");
ib << set(1);

Re: Select specific columns with JSL name contains code

Thomas1 — Thu, 23 Aug 2018 12:50:11 GMT

Am I missing something. I can't get to selected column in the data table.

Re: Select specific columns with JSL name contains code

gzmorgan0 — Thu, 23 Aug 2018 18:22:33 GMT

Try this

Names Default To Here( 1 );
dt = Open( "$SAMPLE_DATA/Big Class.jmp" );


New Window( "Filter Col Selector Example",
    fcb = Filter Col Selector( width( 250 ))
);
ib = (fcb<<Parent) << Xpath("//IfBox");
ib << set(1);
lbb = (fcb<<Parent) << Xpath("(//ListBoxBox)[1]");
lbb << set Function(Function({this},
   selCol = this<<get selected;
   dt<<clear Column Selection;
   dt <<select Columns(selCol) ));

Re: Select specific columns with JSL name contains code

Thomas1 — Fri, 24 Aug 2018 06:22:08 GMT

Thanks for your endurance. I really appreciate it. However the JSL is still not working as intended (see image).

The goal is to get the same function as one gets by using Cols / Columns Viewer / Name Contains. The results, which are being shown in the search box, can be clicked and as result, the specific column is selected in the origin data table.

In case the proper JSL code is available, the whole column search / select process can be carried out much faster.

Re: Select specific columns with JSL name contains code

gzmorgan0 — Fri, 24 Aug 2018 07:25:42 GMT

What version of JMP are you using.

When I run the script I sent, here is what happens:

the dialog appears with the filter box
type in a, then select age, age is highlighted; select name then name is selected; hold the control key and select age and both are selected.
delete a and type in ei then weight and height are selected, similar behavior as above.

Sorry it is not working for you. The script I sent works on JMP 14.1 on the PC. It does not work in JMP 13.2.1, before I look for an alternative, which version of JMP are you using?

Anytime you ask a question you should always specify the version of JMP you are using.

Re: Select specific columns with JSL name contains code

gzmorgan0 — Fri, 24 Aug 2018 07:26:43 GMT

This script works in JMP 12 and JMP 13. The reason the previous script does not work in earlier versions of JMP is that the data table messages clear column selections and select columns(list) are not available. In earlier versions, columns need to be selected and unselected one at a time, hence, the required changes below. I do not have access to any version earlier than JMP 12.

Names Default To Here( 1 );
dt = Open( "$SAMPLE_DATA/Big Class.jmp" );


New Window( "Filter Col Selector Example",
    fcb = Filter Col Selector( width( 250 ))
);

ib = (fcb<<Parent) << Xpath("//IfBox");
ib << set(1);
lbb = (fcb<<Parent) << Xpath("(//ListBoxBox)[1]");

lbb << set Function(Function({this},{_xx, i},
   selCol = this<<get selected;
   _xx = dt << get selected columns;
   For(i=1, i<=nitems(_xx), i++, _xx[i] << set selected(0));
   For(i=1, i<=nitems(selCol), i++, column(dt,selCol[i] ) << set selected(1));
  )	
);

Re: Select specific columns with JSL name contains code

Thomas1 — Fri, 24 Aug 2018 08:35:27 GMT

Sorry for that. I do have JMP 13.1

Re: Select specific columns with JSL name contains code

Thomas1 — Fri, 24 Aug 2018 08:43:38 GMT

Great. Now the JSL is working with JMP 13.1 . I appreciate really your and Ian's endurance in geting the question solved.

Thanks a lot

Re: Select specific columns with JSL name contains code

Thomas1 — Fri, 24 Aug 2018 09:38:40 GMT

The JSL is now working with the satrting JSL:

Names Default To Here( 1 );
dt = Open( "$SAMPLE_DATA/Big Class.jmp" );

If the JSL is generalized (to use it in an Icon Toolbar) in JMP 13.1.0 like:

Names Default To Here( 1 );
dt = Current Data Table();

I run into to the old problem => No colums selection. Do you know whether this specific for JMP 13.10.0?

If yes, don't try to fix it. I hope that I will have JMP 14 soon.

Re: Select specific columns with JSL name contains code

gzmorgan0 — Fri, 24 Aug 2018 10:17:40 GMT

The last script I sent (modified for Current Data Table ) works for both JMP 12 and JMP 13. Here is a screen shot from JMP 12. As the screen shot depicts this is the JMP sample data table.

However, the script will not work if the current data table changes because << Get Selected Columns, returns a list of column references, not the table name. So :Chloroform will return an error if the current data table does not have that column. So to make the script more robust, I changed line 18 below to the JSL below. The script is attached. It should even if the original table is no longer the current data table. However, if the script (Here) changes the value of dt while the dialog is still open, then a a name collision will occur and cause a problem. Or if the original table is closed when the dialog is still open, problems will occur.

   For(i=1, i<=nitems(_xx), i++, column(dt, char(_xx[i])) << set selected(0));

Re: Select specific columns with JSL name contains code

Thomas1 — Fri, 24 Aug 2018 15:36:07 GMT

Again thanks for your support and patience.

The script is better, but as already mentioned, it is still possible to get no function. For example after the dialog has been closed (via Icon in the tool bar) and rum again for a second search and select run on the same data table. Maybe things will improve with JMP 14.

Re: Select specific columns with JSL name contains code

gzmorgan0 — Fri, 24 Aug 2018 21:09:14 GMT

I do not know what you mean by "after the dialog has been closed (via Icon in the tool bar) ".

Which icon? Is thid a custom script?

When you have a script that runs, but does not run in different conditions, most of the time it is a scoping problem. For example the first script I gave you for JMP13 and 12 worked, however, if the current data table changed while the dialog was still open, the syntax :colname will not work. It was a weakness in my program. However, when I converted the :colname to a string "colname" using the char() function and referencing the source table it is robust.

So whatever you are doing via the icon or following script is creating a scoping problem and a JMP version will not fix the problem. So since you have not shared what you are doing, I can only point to some things to look for:

The script must use names default to here, if you have other scripts that reference dt.
Make sure the original target table is the current table before you click on the script button again. (Menu bar displays the table list).

I think you might have a scoping problem, or a table locking problem. Good luck finding it.

Here is a screenshot, I added the script as an addin. I used this many times while doing other stuff, using it on different tables then using again and it works the same in both JMP 13 and JMP 12. It is not a version issue.

Re: Select specific columns with JSL name contains code

Thomas1 — Sat, 25 Aug 2018 17:48:03 GMT

You are right. Your code is working. My mistake was the naming of the icon. I did not use a blank.

After the icon name has been changed to "Column Search" it is working perfectly.

A last question to this topic would be what code must be added to script in order not only to select the found column, but also to go to the found column?

This would improve the whole process further in case the column is not in the visible part of the window.

Re: Select specific columns with JSL name contains code

gzmorgan0 — Mon, 27 Aug 2018 04:04:40 GMT

JMP 13.2.1 has dt << Go To (col ref) ; I don't have 13.1. So, here is a test case. If this works teh modified script is attached. it added JSL to Bring Window to Front(), and Go To()

Names Default to Here(1);
 dt = open("$Sample_Data/Semiconductor Capability.jmp");
 //select a column towards the end of the table
:PM_L1 << set selected(1);
wait(2);
dt << go to(:PM_L1);