How do I perform row operations in looping?

PG — Mon, 26 Mar 2018 11:35:23 GMT

Hello,

I have a table like below.

A B C ..n columns

1 2 3

7 6 4

3 7 9

m rows

I want to write a script such that for every column " Value of nth row= Value of nth row -Value of 1st row" and in the end reset the first row to 0. So in the end my table should look like

A B C

0 0 0..

6 4 1

2 5 6

Could someone help me with a script for such an operation? Thanks

Re: How do I perform row operations in looping?

txnelson — Mon, 26 Mar 2018 12:38:44 GMT

Here are a couple of ways to do the looping........more ways exist, but I will let others show them

Names Default To Here( 1 );

// Open the data table
dt1 = Open( "$SAMPLE_DATA\Blood Pressure.jmp" );

// Create a second copy
dt2 = dt1 << subset( selected columns( 0 ), selected rows( 0 ) );

// Get all numeric, continuous column names 
colList = dt1 << get column names( string, numeric, continuous );

// Loop across all numeric, continuous columns and use a 
// matrix operation to handle the math
For( i = 1, i <= N Items( colList ), i++,
	mat = Column( dt1, colList[i] ) << get values;
	mat = mat - mat[1];
	Column( dt1, colList[i] ) << set values( mat );
);


// Now do the same thing looping with the data in place
// Loop across all numeric, continuous columns
For( i = 1, i <= N Items( colList ), i++, 

	// Go through each row, from the bottom to the top to subtract
	// the value of the first row from each rows value
	For( k = N Rows( dt2 ), k >= 1, k--,
		Column( dt2, colList[i] )[k] = Column( dt2, colList[i] )[k] - Column( dt2, colList[i] )[1]
	)
);

Re: How do I perform row operations in looping?

PG — Tue, 27 Mar 2018 07:27:51 GMT

Thanks txnelson. It works perfectly.

topic Re: How do I perform row operations in looping? in Discussions

How do I perform row operations in looping?

Re: How do I perform row operations in looping?

Re: How do I perform row operations in looping?