topic Re: Is it possible to extract the script behind a JMP Table? in Discussions

Is it possible to extract the script behind a JMP Table?

powerpuff — Tue, 20 Feb 2018 15:55:13 GMT

For example, we can manually right click on the top-left red icon in a report and hit save script --> To script window.

Is there a way to do this as a JSL script? This is because I want to manipulate the script to make combined data table further. Thanks for the help.

Re: Is it possible to extract the script behind a JMP Table?

uday_guntupalli — Tue, 20 Feb 2018 15:58:23 GMT

@powerpuff,
Look for a button which say "Source" and right click that in the table

If you hit - "edit", you will be able to see the script that JMP generated for the table.

Re: Is it possible to extract the script behind a JMP Table?

powerpuff — Tue, 20 Feb 2018 16:08:33 GMT

I was actually talking about the little red button after you open up one of the reports below 'source' option.

Re: Is it possible to extract the script behind a JMP Table?

uday_guntupalli — Tue, 20 Feb 2018 16:13:24 GMT

@powerpuff,
You should be able to save that as well to a Script Window as shown below.

Re: Is it possible to extract the script behind a JMP Table?

powerpuff — Tue, 20 Feb 2018 16:17:37 GMT

Yes, I know I can do that manually, my question was: Can this be done in a jsl script?

Re: Is it possible to extract the script behind a JMP Table?

Justin_Chilton — Tue, 20 Feb 2018 16:26:22 GMT

Not sure if this is what you're trying to do, but if you want to dynamically get a JSL script for a Platform into a JSL expresison variable, you can send the Get Script message to the platform. In the below example, the script variable will have the same script that would appear in the Script Window if you save to it from the Red Triangle Menu.

Names Default To Here( 1 );
dt = Open( "$SAMPLE_DATA\Big Class.jmp" );
dist = dt << Distribution(
	Continuous Distribution( Column( :weight ) ),
	Nominal Distribution( Column( :age ) )
);

script = dist << Get Script();

Script variable:

Distribution(
	Continuous Distribution( Column( :weight ) ),
	Nominal Distribution( Column( :age ) )
)

Re: Is it possible to extract the script behind a JMP Table?

powerpuff — Tue, 20 Feb 2018 17:33:51 GMT

Hi Justin,

Thank you for your response. Can you tell me how do you choose the script variables? I am trying to extract a script from Stepwise regression. Thanks.

Re: Is it possible to extract the script behind a JMP Table?

Mark_Bailey — Tue, 20 Feb 2018 22:14:21 GMT

Generally, JMP objects understand this message, including data tables:

Data Table( "Big Class" ) << Get Script;

Re: Is it possible to extract the script behind a JMP Table?

txnelson — Tue, 20 Feb 2018 17:52:27 GMT

I don't think you want to parse through the script, when you can easily get the model variables by retrieving them directly from the ouput of the run Model. See the simple script below

Names Default To Here( 1 );
dt = Open( "$SAMPLE_DATA/Fitness.jmp" );

// Run the Stepwise and the resulting model
obj = Fit Model(
	Y( :Oxy ),
	Effects(
		:Runtime,
		:Weight,
		:RunPulse,
		:RstPulse,
		:MaxPulse
	),
	Personality( Stepwise ),
	Run
);
// run the stepwise
obj << Go;
// run the model
mod = obj << Run Model;

// Capture from the Effect Tests output, the list of 
// variables that were run in the model
Variables = report(mod)["EffectTests"][StringColBox(1)]<<get;
show(Variables);

Re: Is it possible to extract the script behind a JMP Table?

powerpuff — Tue, 20 Feb 2018 18:05:18 GMT

I want to extract the script to a script window and add some more code to it to make multiple combined data tables and then make a resulting table from columns I extract using the make combined data table function.

Re: Is it possible to extract the script behind a JMP Table?

txnelson — Tue, 20 Feb 2018 18:42:22 GMT

Going down the path of parsing a script is sometimes the only way to get what you need. However, it has been my experience that unless you are looking for things a user may have changed and you need to pick those changes up, reconstructing the code from scratch is typically a simpler approach.

BTW, don't forget to examine the user preferences. The scripts extracted will not provide you with settings that a user may have set by setting preferences.

Re: Is it possible to extract the script behind a JMP Table?

Justin_Chilton — Tue, 20 Feb 2018 20:35:14 GMT

If you really want the script to appear in a Script Window, you can use the Save Script to Script Window message. But I am not sure what you would do with that.

Names Default To Here( 1 );
dt = Open( "$SAMPLE_DATA\Big Class.jmp" );
dist = dt << Distribution(
	Continuous Distribution( Column( :weight ) ),
	Nominal Distribution( Column( :age ) )
);

dist << Save script to script window();

Or you could always put the script into a new script editor window from the Get Script result. You could add to this script yourself, but I still don't think I am following what you are looking to do.

Names Default To Here( 1 );
dt = Open( "$SAMPLE_DATA\Big Class.jmp" );
dist = dt << Distribution(
	Continuous Distribution( Column( :weight ) ),
	Nominal Distribution( Column( :age ) )
);

script = Char( dist << Get Script() );

nw = New Window( "Not the Script Window",
	<<Script,
	Names Default To Here( 1 );
	"\[dt = Open( "$SAMPLE_DATA\Big Class.jmp" ); obj = dt<<]\" || script
);
nw[ScriptBox(1)] << Reformat();

Re: Is it possible to extract the script behind a JMP Table?

David_Burnham — Wed, 21 Feb 2018 18:20:40 GMT

This is a long discussion thread so not sure if you have got your answer - if not, let me know, it can be done - and I have some code I can dig out if it will help

Re: Is it possible to extract the script behind a JMP Table?

powerpuff — Wed, 21 Feb 2018 19:00:42 GMT

I want to write a script that would go to the JMP report and do the save script to --> script window and then make additions to the script so that I can acquire only certain columns from the report table. I have many tables that I need data from, hence I want to be able to extract the script and manipulate it accordingly.

Thanks

Re: Is it possible to extract the script behind a JMP Table?

powerpuff — Wed, 21 Feb 2018 20:08:44 GMT

Thank you so much. I would really appreciate it if you could provide me with some code I can look up to. Thanks

Re: Is it possible to extract the script behind a JMP Table?

David_Burnham — Wed, 21 Feb 2018 20:15:39 GMT

This code will find table scripts for fit model and pop them into a script window

dt = open("$SAMPLE_DATA/Big Class.jmp");

// check whether the current data table contains any scripts
// for least squares regression
lstModelNames = {};    // name of scripts
lstModelScripts = {};  // script contents
If (NTable()>0,
	lstTableScripts = Current Data Table() << Get Table Script Names;
	For (i=1,i<=NItems(lstTableScripts),i++,
		s = Current Data Table() << Get Property(lstTableScripts[i]);
		str = Char(NameExpr(s));
		If (Left(str,7)!="JMP App" & Contains(str,"Standard Least Squares") & !Contains(str,"Generalized Regression"),
			InsertInto(lstModelNames,lstTableScripts[i]);
			InsertInto(lstModelScripts,NameExpr(s));
		)
	)
);

// launch script windows
For (i=1,i<=NItems(lstModelScripts),i++,
	New Window(lstModelNames[i], <<Script,
		Char(lstModelScripts[i])
	);
);

But if they are in a script window then you have to manually make the edits. Alternatively just treat the scripts as either expressions or as strings and manipulate them in code. For example:

// run the model invisiblely and create a handle 'fm'
// that references the model object
s = lstModelScripts[1];
str = Char(NameExpr(s));		
str = "fm =" || str;
SubstituteInto(str,"Fit Model(","Fit Model(Invisible,");
Eval(Parse(str));
// ensure summary of fit is available
fm << Summary Of Fit(1);
// grab the R-sq from the report window
rep = fm << Report;
ob = rep[OutlineBox("Summary of Fit")];
values = ob[NumberColBox(1)] << Get;
Rsquare = values[1];
// close the model object
rep << Close Window;
show(RSquare);

Re: Is it possible to extract the script behind a JMP Table?

powerpuff — Wed, 21 Feb 2018 21:00:39 GMT

This is somewhat closer to what I was looking for. Thanks a lot.

Re: Is it possible to extract the script behind a JMP Table?

powerpuff — Thu, 22 Feb 2018 14:51:49 GMT

Also, the script that I acquire is spread horizontally across the script window. Is it possible to acquire the script vertically in the script window?

Re: Is it possible to extract the script behind a JMP Table?

Justin_Chilton — Thu, 22 Feb 2018 15:26:02 GMT

You can reformat the script in the ScriptBox to make it appear nicely in the Script Window.

Window( "Script Window" )[Script Box(1)] << Reformat();

Re: Is it possible to extract the script behind a JMP Table?

powerpuff — Thu, 22 Feb 2018 15:51:18 GMT

This somehow doesnt seem to work. The output I acquire looks like this.

Whereas I am looking for something like this: