topic Re: Plotting lower / upper limits and average in a control chart in Discussions

Plotting lower / upper limits and average in a control chart

vjalvim — Wed, 20 Sep 2017 10:25:20 GMT

Hi guys,

I would like to know if it is possible to plot the lower , upper and average values direct in the control chart (created by control chart builder) instead of Show Limit Summaries table.

Thanks.

Re: Plotting lower / upper limits and average in a control chart

ian_jmp — Wed, 20 Sep 2017 14:04:58 GMT

You could double-click on the vertical axis and add refernece lines, or add a custom graphics script to the graph box by right-clicking on this. For the second option, do 'Help > Scripting Index' and search for 'H Line'.

Re: Plotting lower / upper limits and average in a control chart

vjalvim — Wed, 20 Sep 2017 12:32:10 GMT

Hi, thanks for quick answer.

I think I'm not so clear in my explanation. I need to plot the values for lower, upper and average lines.

See below the example that I'm looking for. In the left, the software that I used in the past.

If I can plot the values from Show Summaries Limits table, I can remove the table to report (the best layout to put in a presentation).

Re: Plotting lower / upper limits and average in a control chart

ian_jmp — Wed, 20 Sep 2017 12:51:55 GMT

I'm the one who mis-understood. This topic has come up before.

Re: Plotting lower / upper limits and average in a control chart

txnelson — Wed, 20 Sep 2017 13:28:18 GMT

The values can be added to the chart. If there are not phases, the values are displayed as part of the chart

But if the data has phases, the values, as you are pointing out are in a table next to the chart, and you want them on the chart. If your old software allowed you to manually add the values, then you can do the same within JMP by just annotating the chart

If you need this programatically done, then a script could be used to simply read the values from the displayed table and placed onto the IR chart.

I noticed in your example from your old software, that only one set of limits were displayed, even though it appeared that there were different phases. Was that because the limits were the same for all phases?

Re: Plotting lower / upper limits and average in a control chart

vjalvim — Wed, 20 Sep 2017 17:13:09 GMT

Hi again,

So, the old software that I used in the past is Minitab.

Answering your question, the values are ploted automatically from the software and also by phase (see the picture below).

In the example that I shared before, there isn't phases.

I know I've assked too much but could you give me direction about how to include these actions (remove table and plot values in the charts) using script?

Thanks again.

Re: Plotting lower / upper limits and average in a control chart

txnelson — Thu, 21 Sep 2017 03:16:09 GMT

Here is a very rough script that will pull the values from the limits table, and place them on the chart. I suggest that you take the time to read the Scripting Guide using the code below to learn exactly how the code does what it does.

Help==>Books==>Scripting Guide

Names Default To Here( 1 );

// Open the sample data table
dt = Open( "$SAMPLE_DATA\Quality Control\Pickles.jmp" );

// There isn't an adequate column to be used as a Phase column in the sample
// data table, so create one
dt << New Column( "MyPhase", character, formula( Char( Floor( Row() / 13 + 1 ) ) ) );

// Run the control Chart
ct = dt << Control Chart(
	Phase( :MyPhase ),
	Group Size( 1 ),
	KSigma( 3 ),
	Chart Col( :Acid, Individual Measurement( Phase Level( "1" ), Phase Level( "2" ) ), Moving Range( Phase Level( "1" ), Phase Level( "2" ) ) )
);

// Create a list called byPhase of the each of the Phase values
Summarize( dt, byPhase = by( :MyPhase ) );

// Find the max row for each phase to determine the X position on the chart
// for the placement of the text values
PhaseMaxRowList = {};
For( i = 1, i <= N Items( byPhase ), i++,
	Insert Into( PhaseMaxRowList, Max( dt << get rows where( :MyPhase == byPhase[i] ) ) )
);

// Add the text to the chart
framebox = Report( ct )[frame box( 1 )];
framebox << Add Graphics Script(
	Text Color( "Black" );
		
	// Loop across the phases and add the 3 text values by pulling their values from the table
	// and reformating the values
	For( i = 1, i <= N Items( byPhase ), i++,
		LCL = (Report( ct )["Individual Measurement of Acid"][Number Col Box( i )] << get)[1];
		LCLtxt = "LCL=" || Format( LCL, "Fixed Dec", 5, 2 );
		Avg = (Report( ct )["Individual Measurement of Acid"][Number Col Box( i + N Items( byPhase ) )] << get)[1];
		Avgtxt = "Avg=" || Format( Avg, "Fixed Dec", 5, 2 );
		UCL = (Report( ct )["Individual Measurement of Acid"][Number Col Box( i + (N Items( byPhase ) * 2) )] << get)[1];
		UCLtxt = "UCL=" || Format( UCL, "Fixed Dec", 5, 2 );
	
		Text( Center Justified, {PhaseMaxRowList[i] - 2, LCL + .1}, LCLtxt );
		Text( Center Justified, {PhaseMaxRowList[i] - 2, Avg + .1}, Avgtxt );
		Text( Center Justified, {PhaseMaxRowList[i] - 2, UCL + .1}, UCLtxt );
	);
);

Re: Plotting lower / upper limits and average in a control chart

ian_jmp — Thu, 21 Sep 2017 08:49:01 GMT

Very nice Jim!

I took the liberty of adding to your code so that there is a separate graphics script for each annotation:

This makes it possible to move the annotations 'by hand' to avoid any collisions (Right-click on the graphics box, select 'Customize' and edit the x and y values in the scripts to taste).

Names Default To Here( 1 );

// Open the sample data table
dt = Open( "$SAMPLE_DATA\Quality Control\Pickles.jmp" );

// There isn't an adequate column to be used as a Phase column in the sample
// data table, so create one
dt << New Column( "MyPhase", character, formula( Char( Floor( Row() / 13 + 1 ) ) ) );

// Run the control Chart
ct = dt << Control Chart(
	Phase( :MyPhase ),
	Group Size( 1 ),
	KSigma( 3 ),
	Chart Col( :Acid, Individual Measurement( Phase Level( "1" ), Phase Level( "2" ) ), Moving Range( Phase Level( "1" ), Phase Level( "2" ) ) )
);

// Create a list called byPhase of the each of the Phase values
Summarize( dt, byPhase = by( :MyPhase ) );

// Find the max row for each phase to determine the X position on the chart
// for the placement of the text values
PhaseMaxRowList = {};
For( i = 1, i <= N Items( byPhase ), i++,
	Insert Into( PhaseMaxRowList, Max( dt << get rows where( :MyPhase == byPhase[i] ) ) )
);

// Add the text to the chart
framebox = Report( ct )[frame box( 1 )];
addTxt = Expr(
			framebox << Add Graphics Script(
						Description( scriptNameTBD ),
						Text Color( "Black" );	
						Text( Center Justified, {xTBD - 2, yTBD + .1}, txtTBD );
						);
			);
// Loop across the phases and add the 3 text values by pulling their values from the table
// and reformating the values
For( i = 1, i <= N Items( byPhase ), i++,
	LCL = (Report( ct )["Individual Measurement of Acid"][Number Col Box( i )] << get)[1];
	LCLtxt = "LCL=" || Format( LCL, "Fixed Dec", 5, 2 );
	Avg = (Report( ct )["Individual Measurement of Acid"][Number Col Box( i + N Items( byPhase ) )] << get)[1];
	Avgtxt = "Avg=" || Format( Avg, "Fixed Dec", 5, 2 );
	UCL = (Report( ct )["Individual Measurement of Acid"][Number Col Box( i + (N Items( byPhase ) * 2) )] << get)[1];
	UCLtxt = "UCL=" || Format( UCL, "Fixed Dec", 5, 2 );
	// Use a separate graphics script for each annotation so that they are more easily moved 'by hand'
	Eval(Substitute(NameExpr(addTxt), Expr(scriptNameTBD), "LCL Text "||Char(i), Expr(xTBD), PhaseMaxRowList[i], Expr(yTBD), LCL, Expr(txtTBD), LCLtxt));
	Eval(Substitute(NameExpr(addTxt), Expr(scriptNameTBD), "Avg Text "||Char(i), Expr(xTBD), PhaseMaxRowList[i], Expr(yTBD), Avg, Expr(txtTBD), Avgtxt));
	Eval(Substitute(NameExpr(addTxt), Expr(scriptNameTBD), "UCL Text "||Char(i), Expr(xTBD), PhaseMaxRowList[i], Expr(yTBD), UCL, Expr(txtTBD), UCLtxt));
);

Re: Plotting lower / upper limits and average in a control chart

txnelson — Thu, 21 Sep 2017 12:24:43 GMT

@ian_jmp

Very nice addition!

Re: Plotting lower / upper limits and average in a control chart

GoodMan — Sun, 24 Sep 2017 04:27:39 GMT

I tried the JSL on my Mac JMP 11. However it seems still the texts have been successfully added into the chart. In log window, i get the following error information and said that can not caluate out subscript. Can you give me an explantion?

For( i = 1, i <= N Items( byPhase ), i++,

LCL = (Report( ct )[/*###*/"Individual Measurement of Acid"][Number Col Box( i )

] << get)[1];

Re: Plotting lower / upper limits and average in a control chart

txnelson — Sun, 24 Sep 2017 12:49:35 GMT

I have neither the access to JMP 11 or to a Mac, so I will need your help. The message is pointing to a piece of code that is attemping to read the LCL from the displayed output table. Can you please provide the image of the table that was generated by the control chart that has the limits in it?

Re: Plotting lower / upper limits and average in a control chart

GoodMan — Mon, 25 Sep 2017 01:12:12 GMT

The JSL is the same as you posted before. You can find the table image here. As you see that the text for LCL, UCL and Average have not been added.

Thanks.

Re: Plotting lower / upper limits and average in a control chart

txnelson — Mon, 25 Sep 2017 02:00:33 GMT

The script is looking for a specific Outline Box with the title, in English, of "Individual Measurement of Acid". Your output is obviously not in English. The below script changes the reference to Outline Box(2). This is an absolute reference to the outline box, while "Individual Measurement of Acid" is a relative reference. You could also try replacing "Individual Measurement of Acid" with

Names Default To Here( 1 );

// Open the sample data table
dt = Open( "$SAMPLE_DATA\Quality Control\Pickles.jmp" );

// There isn't an adequate column to be used as a Phase column in the sample
// data table, so create one
dt << New Column( "MyPhase", character, formula( Char( Floor( Row() / 13 + 1 ) ) ) );

// Run the control Chart
ct = dt << Control Chart(
	Phase( :MyPhase ),
	Group Size( 1 ),
	KSigma( 3 ),
	Chart Col( :Acid, Individual Measurement( Phase Level( "1" ), Phase Level( "2" ) ), Moving Range( Phase Level( "1" ), Phase Level( "2" ) ) )
);

// Create a list called byPhase of the each of the Phase values
Summarize( dt, byPhase = by( :MyPhase ) );

// Find the max row for each phase to determine the X position on the chart
// for the placement of the text values
PhaseMaxRowList = {};
For( i = 1, i <= N Items( byPhase ), i++,
	Insert Into( PhaseMaxRowList, Max( dt << get rows where( :MyPhase == byPhase[i] ) ) )
);

// Add the text to the chart
framebox = Report( ct )[frame box( 1 )];
addTxt = Expr(
			framebox << Add Graphics Script(
						Description( scriptNameTBD ),
						Text Color( "Black" );	
						Text( Center Justified, {xTBD - 2, yTBD + .1}, txtTBD );
						);
			);
// Loop across the phases and add the 3 text values by pulling their values from the table
// and reformating the values
For( i = 1, i <= N Items( byPhase ), i++,
	LCL = (Report( ct )[Outline Box(2)][Number Col Box( i )] << get)[1];
	LCLtxt = "LCL=" || Format( LCL, "Fixed Dec", 5, 2 );
	Avg = (Report( ct )[Outline Box(2)][Number Col Box( i + N Items( byPhase ) )] << get)[1];
	Avgtxt = "Avg=" || Format( Avg, "Fixed Dec", 5, 2 );
	UCL = (Report( ct )[Outline Box(2)][Number Col Box( i + (N Items( byPhase ) * 2) )] << get)[1];
	UCLtxt = "UCL=" || Format( UCL, "Fixed Dec", 5, 2 );
	// Use a separate graphics script for each annotation so that they are more easily moved 'by hand'
	Eval(Substitute(NameExpr(addTxt), Expr(scriptNameTBD), "LCL Text "||Char(i), Expr(xTBD), PhaseMaxRowList[i], Expr(yTBD), LCL, Expr(txtTBD), LCLtxt));
	Eval(Substitute(NameExpr(addTxt), Expr(scriptNameTBD), "Avg Text "||Char(i), Expr(xTBD), PhaseMaxRowList[i], Expr(yTBD), Avg, Expr(txtTBD), Avgtxt));
	Eval(Substitute(NameExpr(addTxt), Expr(scriptNameTBD), "UCL Text "||Char(i), Expr(xTBD), PhaseMaxRowList[i], Expr(yTBD), UCL, Expr(txtTBD), UCLtxt));
);

Re: Plotting lower / upper limits and average in a control chart

GoodMan — Tue, 26 Sep 2017 03:15:50 GMT

Thank you. I checked in English pickle sample data still no success. I step to step to run the scrip and get the following report after i run Summarize( dt/*###*/, byPhase = by( :MyPhase ) ). I translate the log into English for you. Do you believe there is some wrong there?

必须是赋值运算符正在访问或计算“dt”, dt/*###*/
Must use assignment operator in visiting "dt"
在以下脚本中，使用 /*###*/ 标记错误
in the following script, use /*###*/ to mark error

Re: Plotting lower / upper limits and average in a control chart

txnelson — Tue, 26 Sep 2017 11:21:28 GMT

The syntax of the "Summarize()" function has changed in the recent versions of JMP. It seems that might be the issue. Change the statement

Summarize( dt, byPhase = by( :MyPhase ) );

Summarize( byPhase = by( :MyPhase ) );

Re: Plotting lower / upper limits and average in a control chart

GoodMan — Tue, 26 Sep 2017 12:38:21 GMT

Thank you,Jim. It works now!