topic Re: Shading in an area on a time-series chart in Discussions

Shading in an area on a time-series chart

scottahindle — Mon, 28 Aug 2017 14:39:38 GMT

Dear all,

If I plot a simple time-series of my data I will often gain insight from control limits and also spec limits on the graph. (Simple visualisations of the Voice of the Process and the Voice of the Customer).

With control charts we can "Shade Zones" which can help - I like this feature.

Is there a simple way to do something similar using Graph Builder?

In the attached file it is easy enough to add a pair of horizontal lines which you find at -3 and +3. Is there a simple way using scripting to shade in between two such horizontal lines? How would I shade in the area between -3 and +3 on such a graph to show this is a region to focus on when making sense of the data?

Would be great if somebody could pass on some advice.

Scott.

Re: Shading in an area on a time-series chart

David_Burnham — Mon, 28 Aug 2017 18:13:35 GMT

Through JSL you can add a graphics script to customise the graph, so that it shows a shaded polygon:

gb = Graph Builder(
	Size( 1659, 932 ),
	Show Control Panel( 0 ),
	Variables( X( :Series ), Y( :Data ) ),
	Elements( Points( X, Y, Legend( 5 ) ) ),
	SendToReport(
		Dispatch(
			{},
			"Series",
			ScaleBox,
			{Min( 0 ), Max( 102 ), Inc( 10 ), Minor Ticks( 1 )}
		),
		Dispatch(
			{},
			"Data",
			ScaleBox,
			{Min( -4 ), Max( 4 ), Inc( 1 ), Minor Ticks( 1 ),
			Add Ref Line( 3, "Solid", "Black", "", 1 ),
			Add Ref Line( -3, "Solid", "Black", "", 1 )}
		)
	)
);

// create a shaded region
rep = gb << Report;
x = {};
x[1] = rep[AxisBox(1)] << Get Min;
x[2] = rep[AxisBox(1)] << Get Max;
x[3] = x[2];
x[4] = x[1];
y = {-3,-3,3,3};
fb = rep[FrameBox(1)];
fb << Add Graphics Script(
	Transparency(0.1);
	Fill Color("Green"); 
	Polygon( Matrix(x), matrix(y) )
);

Re: Shading in an area on a time-series chart

scottahindle — Mon, 28 Aug 2017 21:21:33 GMT

David - Thanks!

Re: Shading in an area on a time-series chart

jerry_cooper — Mon, 28 Aug 2017 22:58:00 GMT

As a non-scripting alternative for those with JMP version 12 or higher, there is an option for allowing ranges for reference lines in the Y-axis Settings dialog (double-click the y-axis). Checking the "Allow Ranges" box will provide number boxes for inputting the min and max of the range and will allow you to choose a color for that range.

Re: Shading in an area on a time-series chart

David_Burnham — Tue, 29 Aug 2017 07:57:16 GMT

Nice one Jerry, not seen that check box before.

The code example that I provide I usually use for confidence intervals, but for a rectangular range, like you said can be done interactively, or can be done like this:

rep = gb << Report;
rep[AxisBox(2)] << Add Ref Line( {-3, 3}, "Solid", "Medium Light Green", "", 1, 0.25 );

Re: Shading in an area on a time-series chart

scottahindle — Wed, 30 Aug 2017 20:38:15 GMT

Thanks, Jerry. This is a great option which I didn't know about. I've already used it a few times!