topic Re: How to know if a table is a linked subset? in Discussions

How to know if a table is a linked subset?

anne_sa — Mon, 03 Jul 2017 08:56:20 GMT

Hello everybody,

I would like to determine (using JSL) if the current data table is linked to a main table or not.

I tried "<< Get Table Variable Names" but it didn't work.

Do you have any idea of how we can get this information?

Thanks in advance for your help!

Re: How to know if a table is a linked subset?

ian_jmp — Mon, 03 Jul 2017 09:50:26 GMT

FWIW, assuming your code makes the tables, you can make linked or unlinked subsets as you require:

Names Default To Here( 1 );

dt = Open( "$SAMPLE_DATA/Big Class.jmp" );
// Unlinked subset
dt << selectRandomly(0.1);
dt2 = dt << Subset(LinkToOriginalDataTable( 0 ) );
dt2 << setName("Unlinked");
// Linked subset
dt << selectRandomly(0.1);
dt3 = dt << Subset(LinkToOriginalDataTable( 1 ) );
dt3 << setName("Linked");

Re: How to know if a table is a linked subset?

anne_sa — Mon, 03 Jul 2017 09:55:26 GMT

Thank you for your answer Ian.

However my objective is not to create a linked subset but to determine if an existing table is linked to another or not.
Sorry if I was not clear enough!

Re: How to know if a table is a linked subset?

ian_jmp — Mon, 03 Jul 2017 10:05:23 GMT

No, I understood, but was implying that you could avoid the 'problem'. But if you want to tell retrospectively, you could do something like:

Names Default To Here( 1 );

dt = Open( "$SAMPLE_DATA/Big Class.jmp" );
// Unlinked subset
dt << selectRandomly(0.1);
dt2 = dt << Subset(LinkToOriginalDataTable( 0 ) );
dt2 << setName("Unlinked");
// Linked subset
dt << selectRandomly(0.1);
dt3 = dt << Subset(LinkToOriginalDataTable( 1 ) );
dt3 << setName("Linked");


// Function to determine if two tables are linked
rLinked = Function({dt1, dt2}, {Default Local},
	dt1 << selectAllRows;
	if(NRow(dt2 << getSelectedRows) > 0,
		linked = 1,
		linked = 0
		);
	dt1 << clearSelect;
	linked;
);

Print(rLinked(dt, dt2), rLinked(dt, dt3));

Re: How to know if a table is a linked subset?

anne_sa — Mon, 03 Jul 2017 11:50:28 GMT

Thanks Ian, that is indeed a quite convenient way to solve the problem!

I just need to go one step further. How can we do that if we do not know what is the potential main table (dt in your code)?

Do we have to test all opening tables or is there a faster solution?

Re: How to know if a table is a linked subset?

Craige_Hales — Mon, 03 Jul 2017 12:27:15 GMT

you might be able to use the table variable; it will need some testing because I'm not sure if it is always set (update: tried several ways to make a subset and it seems the table variable is always created):

dt<<gettablevariable("Linked Subset")
"This subset is linked to Big Class"

// but not linked parent table:
Data Table( "Big Class" )
dt<<gettablevariable("Linked Subset")
""

This linked subset has a table variable

Re: How to know if a table is a linked subset?

anne_sa — Mon, 03 Jul 2017 12:45:28 GMT

Thanks for the suggestion Craige!

I tried "Get Table Variable Names" but not "Get Table Variable"!

I did some tests and it seems to work pretty well!

So far, there is just one particular case where it doesn't work. If I create a summary table linked to the original table, there is no table variable created.

Any idea for this last point?

Re: How to know if a table is a linked subset?

ian_jmp — Mon, 03 Jul 2017 13:07:32 GMT

Yes, the 'summary table' scenario is the one I tried - Hence my replies above. But I'm still left musing over how your JMP session can get into a state where you don't know what's linked to what. But that's OK.

You could easily beuild a 'linking matrix' using 'NTable()' and what I've given above.

Re: How to know if a table is a linked subset?

Craige_Hales — Mon, 03 Jul 2017 13:22:10 GMT

I'm going with Ian's answer then.

Why do you need the linked table information? Maybe there is another approach.

Re: How to know if a table is a linked subset?

anne_sa — Mon, 03 Jul 2017 13:43:34 GMT

Actually I am using a script which runs several analyses. In particular, it saves the residuals and other columns from the Fit Model platform, in the current data table. If this table is linked to another one, columns are saved in the original table and not in the current one and it makes fail my script.

So when a user launches the script, I would like to check first if the current table is not linked to another one. And since I am not aware of what the user did before, that is the reason why I am not able to know what could be linked to what.

Let me know if you need more explanations or if something is not clear!

Besides to answer Ian's last post, I see how we could build this linking matrix but if we have a summary table, I am not sure that the previous script will work. If I am not wrong when you select rows in the original table, nothing is selected in the summary table.

So unfortunately this case is still problematic.

Re: How to know if a table is a linked subset?

ian_jmp — Mon, 03 Jul 2017 14:07:28 GMT

Regarding "In particular, it saves the residuals and other columns from the Fit Model platform, in the current data table" then perhaps I have mis-understood. But you should always be able to get the 'Fit Model' predictions to go to the correct table:

NamesDefaultToHere(1);

// Open a table
dt1 = Open("$SAMPLE_DATA/Big Class.jmp");
// Open another table
dt2 = Open("$SAMPLE_DATA/Bands Data.jmp");
// Direct the analysis to the first table
fml = dt1 << Fit Model(
				Y( :height ),
				Effects( :weight )
				);
fm = fml << Run;
// Prediction formula goes to the first, not the current table
Print(CurrentDataTable());
fm << predictionFormula;

Re: How to know if a table is a linked subset?

anne_sa — Mon, 03 Jul 2017 15:57:14 GMT

In fact, if I work with a subset linked to a table and if I save the Fit Model residuals, they are stored in the first main table. However, I have just remarked that prediction formula are saved in both tables! That is quite strange...

NamesDefaultToHere(1);

// Open a table
dt1 = Open("$SAMPLE_DATA/Big Class.jmp");

// Create a subset
dt2=dt1 << Subset(
	Selected Rows( 0 ),
	Rows( [1, 2, 3, 4, 5, 6, 7, 8, 9, 10] ),
	Selected columns only( 0 ),
	link to original data table(1)
);


// Direct the analysis to the subset table
fml = dt2 << Fit Model(
				Y( :height ),
				Effects( :weight )
				);
fm = fml << Run;
// Prediction formula are saved in both dt1 and dt2 and residulas are saved only in dt1
fm << prediction formula;
fm << residuals;

In this example I would like to have residuals and prediction formula only in dt2.

Re: How to know if a table is a linked subset?

ian_jmp — Wed, 05 Jul 2017 08:49:50 GMT

I suppose that the 'correct' behaviour in this case is open to interpretation, but if you see something that you regard as undesirable, please do send an email to support@jmp.com.

In this case though, if you are are intending to use the linked subset tables to 'isolate' certain rows for analysis, a more conventional approach might be to use the data filter, or the local version thereof. If you are saving formulas that were generated using just part of the data, you may need some additional code to curate these.

Re: How to know if a table is a linked subset?

anne_sa — Wed, 05 Jul 2017 09:47:24 GMT

Thank you for the additional information Ian.

Your are completely right, a "correct" behavior depends on the situation. I was not saying that one is better than another but just trying to explain why sometimes things go wrong with my script.

I also agree that creating a linked subset may not always be the best way to focus on some specific rows. However since my script can be used by other persons, I can't control what they have done before and what kind of table they are working with. So the idea is just to find a way to detect if a table is a linked one (ie not compatible with my script). In that case I could display a warning and stop the script.

Well if it is not feasible maybe I can find another way to deal with this particular case.

Re: How to know if a table is a linked subset?

ian_jmp — Wed, 05 Jul 2017 10:12:48 GMT

You could test this (along the lines I mentioned earlier):

NamesDefaultToHere(1);

// Function to determine if two tables are linked
rLinked = Function({dt1, dt2}, {Default Local},
	dt1 << selectAllRows;
	if(NRow(dt2 << getSelectedRows) > 0, linked = 1, linked = 0);
	dt1 << clearSelect;
	dt2 << clearSelect;
	linked;
);

// Look at the open tables in the session and see which pairs are linked
linkedTables = Function({}, {Default Local},
	nt = NTable();
	linkMat = J(nt, nt, .);
	tblNames = {};
	for(t1=1, t1<=nt, t1++,
		InsertInto(tblNames, DataTable(t1) << getName);
		for(t2=t1+1, t2<=nt, t2++,
			if(rLinked(DataTable(t1), DataTable(t2)), linkMat[t1, t2] = 1, linkMat[t1, t2] = 0);
			);
		);
	EvalList({linkMat, tblNames});
);

// Make some active tables
dt = Open( "$SAMPLE_DATA/Big Class.jmp" );
// Unlinked subset
dt << selectRandomly(0.1);
dt2 = dt << Subset(LinkToOriginalDataTable( 0 ) );
dt2 << setName("Unlinked");
// Linked subset
dt << selectRandomly(0.1);
dt3 = dt << Subset(LinkToOriginalDataTable( 1 ) );
dt3 << setName("Linked");

// Get the 'link matrix'
linkedOrNot = linkedTables();
dt4 = AsTable(linkedOrNot[1], << setName("Linked Tables"), << columnNames(linkedOrNot[2]));
dt4 << NewColumn("Column", Character, Values(linkedOrNot[2]));
dt4 << moveSelectedColumns({"Column"}, ToFirst);

Re: How to know if a table is a linked subset?

anne_sa — Thu, 06 Jul 2017 11:43:33 GMT

Hello Ian,

Thank you for the code! I think I can use something like that to solve my problem. I just need to add an additional control for summary table. Maybe something like that could work: trying to get the "Source" script of a table and check if it contains the word "summary".

I need to do some tests...

Thanks again for your help.

Re: How to know if a table is a linked subset?

ian_jmp — Thu, 06 Jul 2017 13:32:57 GMT

Untested (as usual . . . :(

NamesDefaultToHere(1);
ClearLog();

// See if a table is a summary of another table
isSummary = 
Function({dt}, {Default Local},
	ts = dt << Get Table Script Names;
	if (Contains(ts, "Source"),
		ss = dt << getProperty("Source");
		if (Head(Arg(ss, 2)) == Expr(Summary), 1, 0),
		0
		);
	);

// Make a summary table
dt1 = Open( "$SAMPLE_DATA/Big Class.jmp" );
dt2 = dt1 << Summary(Mean( :height ));
Print(isSummary(dt1));
Print(isSummary(dt2));

Re: How to know if a table is a linked subset?

anne_sa — Fri, 07 Jul 2017 12:03:27 GMT

Thank you one more time for your very fast answer Ian!

I am gonna combine the two parts and do some tests but I trust it should do the job! :)

Re: How to know if a table is a linked subset?

hogi — Sat, 31 Aug 2024 09:53:58 GMT

It's strange that a user has to set up a decision tree to find out if a table is linked or not.

I would assume that Jmp knows which tables are linked.

So, why is such an information not accessible via JSL?

Is it?

edit: thanks for providing the feature with JMP18 : )
(see below)

Re: How to know if a table is a linked subset?

Audrey_Shull — Mon, 03 Apr 2023 12:35:06 GMT

A JSL query to query a table about whether it is a linked subset did not previously exist. However, this conversation has caught the attention of JMP Development, and now a JSL message has been added in the next major release of JMP (JMP 18).

dt << Is Linked Subset; //will return 1 or 0