topic remove almost empty categorical columns in Discussions

remove almost empty categorical columns

FR60 — Thu, 16 Mar 2017 17:18:05 GMT

Some one can help me?

From a database i need to remove categorical columns with a certain percentage of missing character and at the same time I would like to remove the numeric columns with a percentage of stagnant values (not necessary 100%).

Thanks. Felice

Re: remove almost empty categorical columns

txnelson — Thu, 16 Mar 2017 17:34:47 GMT

Here is a quick and dirty script that gets rid of columns with less than a specified percent of data

Names Default To Here( 1 );
dt = Current Data Table();
percent = 90;
colList = dt << get column names( character, string );
NumRows = N Rows( dt );
For( i = N Items( colList ), i >= 1, i--,
	If( Col Number( Column( dt, i ) ) / NumRows * 100 < percent,
		dt << delete columns( colList[i] )
	)
);

Re: remove almost empty categorical columns

msharp — Thu, 16 Mar 2017 19:08:25 GMT

Another method, I believe slightly more robust.

Names Default To Here( 1 );
dt = Current Data Table();
percent = 90;
delcols = {};
numRows = nrows(dt);
for(i=1; maxi=NCols(dt), i<=maxi, i++,
	col = column(dt, i);
	nmissing = col N missing(col);
	if(nmissing > numRows * percent/100,
		insert into(delcols, i);
	);
);
if(nitems(delcols) > 0, dt << delete columns(delcols));

Re: remove almost empty categorical columns

msharp — Thu, 16 Mar 2017 19:12:44 GMT

I think you are also looking for something like this:

Which will delete a numeric column if all data is only one value.

Names Default To Here( 1 );
dt = Current Data Table();
delcols = {};
numRows = nrows(dt);
for(i=1; maxi=NCols(dt), i<=maxi, i++,
	col = column(dt, i);
	try(summarize(dt, max = max(col), min = min(col));
		if((max == min)  | (ismissing(max)),
			insertinto(delcols, i);
		)
	);
);
if(nitems(delcols) > 0, dt << delete columns(delcols));

Re: remove almost empty categorical columns

mpl34 — Fri, 17 Mar 2017 01:06:34 GMT

you might be able to use the method you posted before but with the mode of the column for something less than 100%

Names Default To Here( 1 );
dt = Current Data Table();
percent = 90;
delcols = {};
numRows = nrows(dt);
for(i=1; maxi=NCols(dt), i<=maxi, i++,
	if(nrows(loc(aslist(column(dt,i)<<getasmatrix),mode(column(dt,i)<<getasmatrix))) > numRows * percent/100,
		insert into(delcols, i);
	);
);
if(nitems(delcols) > 0, dt << delete columns(delcols));

Re: remove almost empty categorical columns

FR60 — Fri, 17 Mar 2017 14:52:37 GMT

I tried yor script on the second table below and the result is here.

As you can see it was able to remove almost all desired columns but second one (col2) not. How I can do to remove it too?

Thanks Felice

Re: remove almost empty categorical columns

msharp — Fri, 17 Mar 2017 15:20:45 GMT

Just combine the strategies. Something like:

Names Default To Here( 1 );
dt = Current Data Table();
percent = 90;
delcols = {};
numRows = nrows(dt);
for(i=1; maxi=NCols(dt), i<=maxi, i++,
	if(nrows(loc(aslist(column(dt,i)<<getasmatrix),mode(column(dt,i)<<getasmatrix))) > numRows * percent/100,
		insert into(delcols, i);
	,
		if(Col N Missing(column(dt,i)) > numRows * percent/100,
			insert into(delcols, i);
		);
	);
);
if(nitems(delcols) > 0, dt << delete columns(delcols));

Re: remove almost empty categorical columns

FR60 — Fri, 17 Mar 2017 16:02:07 GMT

Hi msharp thanks for your reply. Let'm ask another question. The percent variable work for both on categorical and numerical columns? If yes can I have two different value for missing and stagnant cases?

Sorry for maybe stupid question but I'm not expert in jsl language.

Felice

Re: remove almost empty categorical columns

msharp — Fri, 17 Mar 2017 16:41:59 GMT

Yeah it all depends on how you set it up. The first check is finding the most common value in each column and determines if it is above or below the threshold percentage. Unfortunately, a missing value isn't a value, so it can't be the most common. That's why it doesn't work on the numeric columns. It does work on the Character columns b/c "" is both missing and an empty string value.

Hope that helps explain things.

If you want more granularity, just run multiple loops with different percentages using different strategies.

Re: remove almost empty categorical columns

FR60 — Fri, 17 Mar 2017 16:53:13 GMT

Perfect thanks.

Felice