topic Re: JSL - Adding a Table to a Journal in Discussions

JSL - Adding a Table to a Journal

drblove — Wed, 16 Nov 2016 17:24:11 GMT

Another JSL question, I'm trying to put a table in Journal using JSL. Here is what I am trying to do:

current_data_table << New Data View;

// Creating the Journal

nw = New Window("Journal Right Here", <<Journal,
	ob = Outline Box("Section 1",
        Text Box("Some description that we need here.", << Markup),
        Current Journal()[TableBox(current_data_table)]
    )
);

Everything seems to be working but the TableBox code... I am sure it is something easy but it is stumping me.

Thank you in advance.

Re: JSL - Adding a Table to a Journal

txnelson — Wed, 16 Nov 2016 17:50:21 GMT

Here is a very simple script that does what you want:

Names Default To Here( 1 );
dt = Open( "$SAMPLE_DATA/big class.jmp" );

nw = New Window( "sample journal",
	<<journal, 

	ob = Outline Box( "Selection 1",
		Text Box( "this is some description", Markup( 1 ) ),
		dt << New Data Box()
	)
);

Re: JSL - Adding a Table to a Journal

drblove — Wed, 16 Nov 2016 18:04:51 GMT

Hi Jim,

Thank you for your response. It works great. Quick question through, when I go to the Journal is shows the table with rows and columns that are completely empty (like an Excel spreadhseet) versus just the rows and column with headers. Any solutions?

Thank you in advance,

Brad

Re: JSL - Adding a Table to a Journal

txnelson — Wed, 16 Nov 2016 18:21:05 GMT

The reason it displays empty cells, is because it is a view into an existing data table. Here is another script that just adds a visual copy. The script has to be a little tricky in it's method to place the data table view under the outline box.

Names Default To Here( 1 );
dt = Open( "$SAMPLE_DATA/big class.jmp" );

nw = New Window( "sample journal",
	<<journal, 

	ob = Outline Box( "Selection 1", 
		Text Box( "this is some description", Markup( 1 ) ), 
		hlb = H List Box() 
	)
);
xx = New Window( "xxx", <<journal );
dt << journal;
hlb << append( xx );
xx << close window;

Re: JSL - Adding a Table to a Journal

drblove — Wed, 16 Nov 2016 18:43:52 GMT

Awesome! Thank you so much for taking the time to reply, completely works.

Brad

Re: JSL - Adding a Table to a Journal

mann — Mon, 24 Sep 2018 13:54:59 GMT

Thanks for those last 4 lines.

Re: JSL - Adding a Table to a Journal

ram — Tue, 25 Sep 2018 20:12:04 GMT

Is it possible to append matrix to a display box without any for loop etc?

Re: JSL - Adding a Table to a Journal

txnelson — Tue, 25 Sep 2018 20:41:48 GMT

Append a matrix???

A mathematical matrix....... a = [1,2,3 4,5,6] ?

A matrix of text boxes?

Re: JSL - Adding a Table to a Journal

ram — Tue, 25 Sep 2018 20:56:00 GMT

Yes, A 2D matrix of numbers. I was thinking if it can be converted as a table, can it be directly append to a display box?
Thanks

Re: JSL - Adding a Table to a Journal

txnelson — Wed, 26 Sep 2018 00:09:34 GMT

This might work for you

names default to here(1);
myMatrix = [1 2 3, 4 5 6, 7 8 9];
nw=new window("test", vlb=vlistbox());
vlb<<append((as table(myMatrix))<< get as report);
close(current data table(), nosave);
(nw<<xpath("//NumberColBox"))<<set heading("");

Re: JSL - Adding a Table to a Journal

Mark_Bailey — Wed, 26 Sep 2018 14:22:54 GMT

Actually, there is the matrix display box, too.

Names Default To Here( 1 );
myMatrix = [1 2 3, 4 5 6, 7 8 9];
nw = New Window( "test", vlb = V List Box() );
vlb << Append( Matrix Box( myMatrix ) );

Re: JSL - Adding a Table to a Journal

ram — Wed, 26 Sep 2018 15:05:05 GMT

Thank you

Re: JSL - Adding a Table to a Journal

ram — Wed, 26 Sep 2018 21:24:00 GMT

Thank you

Re: JSL - Adding a Table to a Journal

Herrera5238 — Thu, 27 Jun 2019 13:28:32 GMT

Is it possible to change font size for the table?

Here are my attempts but I can't seem to be able to have it actually make a change.

Names Default to Here(1);

dt = Open("$sample_data/Big Class.jmp");

nw = New Window("Tables", <<Journal);


// Attempt 1
/*tableVBox = V List Box(<< Append (Data Table Box (dt) ));
tableVBox << font("Times New Roman", 50);

nw << Append ( Outline Box( "Big Class Table", tableBox ));*/


// Attempt 2
tableDTB = Data Table Box (dt);
tableDTB << Optimize Display;

nw << Append ( Outline Box( "Big Class Table", V List Box(<< Append (tableDTB )) ));

Re: JSL - Adding a Table to a Journal

txnelson — Thu, 27 Jun 2019 14:10:01 GMT

The data table, when moved into a journal, is convered into a TableBox(). The only way that I know of to change the text size in a table box, is in the JMP Preferences. However, that will change the text size for all areas within JMP, not just the table box.