topic Re: how to find the empty columns and delete them by scripting in Discussions

how to find the empty columns and delete them by scripting

robust1972 — Thu, 12 May 2016 19:53:00 GMT

how to find the empty columns and delete them by scripting. any helps and/or hints will be very appreciated.

ms — Thu, 12 May 2016 22:06:37 GMT

I can think of several ways to do this. Here's an example based on the built-in Missing Data Pattern command.

dt = Current Data Table();

names = dt << Get Column Names();

dt1 = dt << Missing Data Pattern(columns(Eval(names)), invisible);

n = N Row(dt1);

For(i = N Col(dt), i >= 1, i--,

If(Col Sum(Column(dt1, i + 3)) < n,

Remove From(names, i)

)

);

Try(dt << delete columns(names));

Close(dt1, nosave);

ian_jmp — Fri, 13 May 2016 10:30:04 GMT

As an alternative (and probably one of Marcus' 'several ways'):

dt = CurrentDataTable();

m = dt << getAllColumnsAsMatrix;

// Loop over the columns and record which are entirely missing

c2del = {};

for(c=1, c<=NCol(m), c++,

if(NRow(Loc(IsMissing(m[0,c]))) == NRow(m), InsertInto(c2del, c));

);

// Delete the columns

dt << deleteColumns(c2del);