topic Re: Find All Display Tree Elements in Discussions

Find All Display Tree Elements

robot — Mon, 05 Oct 2015 04:04:36 GMT

Hi,

I would like to use JSL to get a list of all the objects within a display tree for scripting purposes. Specifically, I would like to get a list of all the FrameBoxes within a window, and then add a graphics script to each. Or better still, I would like to return a list of available FrameBoxes to the user, and then have the user select which graphics script to add.

How can I get a list of all the FrameBoxes in a window? I would like to get a list that is in a form suitable for scripting, and not just view the Display Tree. Is this possible?

Thanks!

Re: Find All Display Tree Elements

ian_jmp — Mon, 05 Oct 2015 08:53:38 GMT

That's perfectly possible. The code below uses pre-order traversal to walk the display tree (and was originally written by Joseph Morgan in the JMP Division, I believe). You should be able to get what you need with a few tweaks (depending on the rest of your code).

NamesDefaultToHere(1);

ClearLog();

// This function recursively traverses a display tree producing

// a pre-order listing of the names of display boxes that constitute

// the tree. It also looks for each FrameBox (whether displayed or not),

// and gets the name of the parent OutlineBox

preorder = Function({node},

Local({chnode},

// Inspect the current node

nodeType = Char(node << className);

Print("Node: "||nodeType);

If(nodeType =="FrameBox",

// Find the title of the parent outline node of this FrameBox

parent = node << parent;

parentType = Char(parent << className);

While(parentType != "OutlineBox",

parent = parent << parent;

parentType = Char(parent << className);

);

InsertInto(fbTitles, parent << getTitle)

);

// Do the recusrsion

chnode = node << child;

While(IsScriptable(chnode),

Recurse(chnode);

chnode = chnode << sib;

);

// Try out 'preorder' . . .

dt = Open("$SAMPLE_DATA/Big Class.jmp");

obj = dt << Fit Model(

Y( :height ),

Effects( :sex ),

Personality( "Standard Least Squares" ),

Emphasis( "Effect Leverage" ),

Run(

:height << {Lack of Fit( 0 ), Plot Actual by Predicted( 1 ),

Plot Regression( 0 ), Plot Residual by Predicted( 1 ),

Plot Effect Leverage( 1 )}

)

);

report=report(obj);

fbTitles = {};

preorder(report);

Print("\!n", fbTitles);

Re: Find All Display Tree Elements

robot — Mon, 05 Oct 2015 23:25:26 GMT

Thanks Ian.

Re: Find All Display Tree Elements

robot — Wed, 16 Dec 2015 04:23:52 GMT

Hi Ian@JMP,

Thanks again for the preorder function. Is there a way for the function to return only FrameBoxes that are actually displayed? Or is there a way for JMP to tell which FrameBoxes are displayed or not?

I find that when my script tries to send a command to a FrameBox that is not displayed, it will cause an error.

Re: Find All Display Tree Elements

ian_jmp — Wed, 16 Dec 2015 15:23:40 GMT

Not really answering your question directly, but you may be able to make the failure you mention benign by using the 'Try()' function.

Re: Find All Display Tree Elements

robot — Wed, 16 Dec 2015 15:57:16 GMT

Okay. Thanks Ian. An unfortunate side-effect of the returned hidden FrameBoxes is that the FrameBox title may not match up with the FrameBox number as shown below. I may be able to get my script to work using some other variations on the Try() function.

Names Default To Here( 1 );

Clear Log();

// This function recursively traverses a display tree producing

// a pre-order listing of the names of display boxes that constitute

// the tree. It also looks for each FrameBox (whether displayed or not),

// and gets the name of the parent OutlineBox

preorder = Function( {node},

Local( {chnode},

// Inspect the current node

nodeType = Char( node << className );

Print( "Node: " || nodeType );

If( nodeType == "FrameBox",

// Find the title of the parent outline node of this FrameBox

parent = node << parent;

parentType = Char( parent << className );

While( parentType != "OutlineBox",

parent = parent << parent;

parentType = Char( parent << className );

);

Insert Into( fbTitles, parent << getTitle );

);

// Do the recusrsion

chnode = node << child;

While( Is Scriptable( chnode ),

Recurse( chnode );

chnode = chnode << sib;

);

)

);

// Try out 'preorder' . . .

dt = Open( "$SAMPLE_DATA/Big Class.jmp" );

obj = dt << Fit Model(

Y( :height ),

Effects( :sex ),

Personality( "Standard Least Squares" ),

Emphasis( "Effect Leverage" ),

Run(

:height << {Lack of Fit( 0 ), Plot Actual by Predicted( 1 ), Plot Regression( 0 ), Plot Residual by Predicted( 1 ), Plot Effect Leverage( 1 )

}

)

);

report = Report( obj );

fbTitles = {};

preorder( report );

Print( "\!n", fbTitles );

// Select windows.

Wait( 1 );

obj << Bring Window to Front;

For( i = 1, i <= N Items( fbTitles ), i++,

Try(

report[FrameBox( i )] << Select;

win = New Window( "FrameBox Title", <<Modal, Text Box( Eval( fbTitles[i] ) ) );

report[FrameBox( i )] << Deselect;

)

);

Re: Find All Display Tree Elements

ms — Wed, 16 Dec 2015 21:15:30 GMT

Interesting discussion. Below is an example, borrowing heavily from the examples above, where I use an associative array to link the present numbers of displayed frame boxes with their titles.

dt = Open("$SAMPLE_DATA/Big Class.jmp");

obj = dt << Fit Model(

Y(:height),

Effects(:sex),

Personality("Standard Least Squares"),

Emphasis("Effect Leverage"),

Run(

:height << {Lack of Fit(0), Plot Actual by Predicted(1), Box Cox Y Transformation(1), Plot Residual by Predicted(1),

Plot Effect Leverage(1)}

)

);

report = Report(obj);

// Associative array linking displayed framebox numbers with titles

fbTitles = [=> ];

i = 1;

While(Is Scriptable(Try(parent = Report[Framebox(i)] << parent)),

While(parentType = Char(parent << className) != "OutlineBox", parent = parent << parent);

fbTitles << insert item(i, parent << getTitle);

i++;

);

Show(fbTitles);

// Select windows.

obj << Bring Window to Front;

For(i = 1, i <= N Items(fbTitles), i++,

report[FrameBox(i)] << Select;

win = New Window("FrameBox Title", <<Modal, Text Box(Eval(fbTitles[i])));

report[FrameBox(i)] << Deselect;

);

Re: Find All Display Tree Elements

vince_faller — Wed, 16 Dec 2015 22:05:30 GMT

This worked for me if you don't need all the other stuff Ian built in. Don't know why it's returning lists of lists but I just select the first one.

dt = open("$SAMPLE_DATA/Big Class.jmp");

biv = (dt << Bivariate(Y(:height, :weight), X(:age)));

frame_list = biv << xpath("//FrameBox");

wait(2);

frame_list[1][1]<<Select;

wait(2);

frame_list[2][1]<<Select;

Re: Find All Display Tree Elements

robot — Wed, 16 Dec 2015 22:06:55 GMT

Thanks MS.

If you post your reply at the separate discussion for this follow-up question, Find Hidden or Displayed FrameBoxes, I will mark it correct.

Very impressive.

Re: Find All Display Tree Elements

robot — Sat, 26 Dec 2015 00:58:44 GMT

Hi MS,

Thanks again for your script; it works beautifully for JMP12. I am now trying to make the script compatible down to JMP10, and I have having trouble debugging the script for GraphBuilder. Do you know how to make your script work for GraphBuilder in JMP10?

dt = Open( "$SAMPLE_DATA/Big Class.jmp" );

// Script will work for graph1.

graph1 = dt << Fit Model(

Y( :height ),

Effects( :sex ),

Personality( "Standard Least Squares" ),

Emphasis( "Effect Leverage" ),

Run(

:height << {Lack of Fit( 0 ), Plot Actual by Predicted( 1 ),

Box Cox Y Transformation( 1 ), Plot Residual by Predicted( 1 ),

Plot Effect Leverage( 1 )}

)

);

// Script will crash for graph2.

graph2 = dt << Graph Builder(

Show Control Panel( 0 ),

Variables( X( :height ), Y( :weight ), Wrap( :age ) ),

Elements( Points( X, Y, Legend( 1 ) ) )

);

Wait( 1 );

win = Current Window();

// Associative array linking displayed FrameBox numbers with titles

fbTitles = [=> ];

i = 1;

While( Is Scriptable( Try( parent = win[Framebox( i )] << parent ) ),

While( parentType = Char( parent << className ) != "OutlineBox",

parent = parent << parent

);

fbTitles << insert item( i, parent << getTitle );

i++;

);

Show( fbTitles );

// Select windows.

win << Bring Window to Front;

For( i = 1, i <= N Items( fbTitles ), i++,

win[FrameBox( i )] << Select;

New Window( "FrameBox Title", <<Modal, Text Box( Eval( fbTitles[i] ) ) );

win[FrameBox( i )] << Deselect;

);

Re: Find All Display Tree Elements

ms — Mon, 28 Dec 2015 09:46:19 GMT

I may not be able to help since I don't have a JMP 10 license. What goes wrong? Any messages in the log?

Graph Builder has evolved a lot for every new version of JMP. I think that Graph Builder's scripting support has improved too. Maybe there's a special display-box type in the v.10 Graph Builder report that is not (yet) "scriptable", causing the while-loop to stop before the search is completed.

You could also try to use Insert() instead of Insert Item().

Re: Find All Display Tree Elements

robot — Wed, 30 Dec 2015 17:16:35 GMT

Hi MS,

The problem appears to be that "parent << getTitle" does not yield a result for Graph Builder in JMP10.

My team will make due without this for JMP10. Thanks for your help!

Re: Find All Display Tree Elements

tova — Tue, 16 Apr 2019 07:31:45 GMT

I am trying to run this script, but I am getting the error message :

Send Expects Scriptable Object{1} in access or evaluation of 'Send' , node << /*###*/className/*###*/

ANy idea why or what I should do?

thanks

Re: Find All Display Tree Elements

tova — Tue, 16 Apr 2019 07:32:53 GMT

I am trying to run this script, but I am getting the error message:

Send Expects Scriptable Object{1} in access or evaluation of 'Send' , node << /*###*/className/*###*/

ANy idea why or what I should do?

THanks,

Tova

Re: Find All Display Tree Elements

txnelson — Tue, 16 Apr 2019 12:48:48 GMT

What version of JMP are you using?

Are you running on a Windows box or on a Mac?

Could you please clear the log, rerun the script, and then include the entire log output in your next response?