topic Re: Col Score in reverse order options? in Discussions

Col Score in reverse order options?

shampton82 — Tue, 22 Sep 2026 22:40:55 GMT

Hey everyone,

Is there an easy way to reverse the order using the Col Score() function? The default is that it scores it by descending order, so if something has the highest value it is given the highest score and the smallest value is given the score of 1. I'd like the highest value to be a score of 1 and the lowest value to be the lowest score.

Thanks for any input!

Re: Col Score in reverse order options?

txnelson — Wed, 23 Sep 2026 01:33:32 GMT

Here is how I would do it

Names Default To Here( 1 );
Open( "$SAMPLE_DATA/Big Class.jmp" );
New Column( "Score Height",
	formula( col score(:Height))
);
New Column( "Height reverse",
	Formula( col max(:height)-:height + col min(:height))
);
current data table()<<rerun formulas;
New Column( "score Height reverse",
	set each value( col score(:height reverse))
);

current data table() << delete columns(:height reverse);

Re: Col Score in reverse order options?

jthi — Wed, 23 Sep 2026 04:49:11 GMT

You can combine it with Col Number for example

Names Default To Here(1);

dt = Open("$SAMPLE_DATA/Big Class.jmp");

dt << New Column("Score Height", Formula(Col Score(:height)));
dt << New Column("Score Height Reverse", Formula(Col Number(:height) - Col Score(:height) + 1));

dt << New Column("Score Height by age", Formula(Col Score(:height, :age)));
dt << New Column("Score Height by age Reverse", Formula(Col Number(:height, :age) - Col Score(:height, :age) + 1));

Write();

Re: Col Score in reverse order options?

shampton82 — Thu, 24 Sep 2026 17:47:49 GMT

Thanks for the help @jthi and @txnelson . Using your guidance, I came up with this that is working well

For use with a single column

Col Score( :height ) * -1 + 1 + Col Maximum( Col Score( :height ) )

For use with by columns:

Col Score( :height, :sex ) * -1 + 1 + Col Maximum( Col Score( :height, :sex ), :sex )

Appreciate the quick responses!

Steve