topic Re: Eval Expr not working in Discussions

Eval Expr not working

SpannerHead — Thu, 12 Mar 2026 16:17:53 GMT

Always confused by this one. I created this formula based on one that worked previously.

// Get the current data table
dt = Current Data Table();

colNames = dt << get column names( continuous, string );

// Loop through all columns
For each( {col}, colNames,
Eval(
	Eval Expr(	
		New Column(
			Expr( col ) || "_Gouge",
			Numeric,
			"Continuous",
			Format( "Best", 10 ),
			Formula( (Mean( As Column( Eval(col) ) [Index(1, 100)]) + Mean(As Column(Eval(col)) [Index(N Rows() - 99, N Rows())])) / 2 - Col Minimum(As Column(Eval(col)) ) )
			);
		)
	);
);

Formula appears to remain unevaluated.

Re: Eval Expr not working

mmarchandFSLR — Thu, 12 Mar 2026 19:15:48 GMT

As Column( Eval( col ) ) should be As Column( Expr( col ) );

Re: Eval Expr not working

SpannerHead — Thu, 12 Mar 2026 20:25:30 GMT

Finished thing looks like this.

// Get the current data table
dt = Current Data Table();

colNames = dt << get column names( continuous, string );

// Loop through all columns
For each( {col}, colNames,
Eval(
	Eval Expr(	
		New Column(
			Expr( col ) || "_Gouge",
			Numeric,
			"Continuous",
			Format( "Best", 10 ),
			Formula( (Mean( As Column( Expr( col ) ) [Index(1, 100)]) + Mean(As Column( Expr( col ) ) [Index(N Rows() - 99, N Rows())])) / 2 - Col Minimum(As Column( Expr( col )) ) )
			);
		)
	);
);

Re: Eval Expr not working

hogi — Thu, 12 Mar 2026 21:45:06 GMT

You could also use the below code. It will create column references which look as if the column was added in Formula Editor.
One of the benefits: when the input column is renamed, the formula still works.

dt = Current Data Table();

colNames = dt << get column names( continuous, string );

// Loop through all columns
For each( {col}, colNames,
Eval(
	Eval Expr(	
		New Column(
			col || "_Gouge",
			Numeric,
			"Continuous",
			Format( "Best", 10 ),
			Formula( (Mean( Expr(Name Expr(As Column(  col ) )) [Index(1, 100)]) + Mean(Expr(Name Expr(As Column(  col ) )) [Index(N Rows() - 99, N Rows())])) / 2 - Col Minimum(Expr(Name Expr(As Column(  col )) )) )
			);
		)
	);
);