topic Re: How to run program with whitespaces in path in Discussions

How to run program with whitespaces in path

Georg — Sun, 11 Jan 2026 09:20:52 GMT

Dear community,

I want to zip files in current directory on win10 with JMP,

so I use run program() and cmd or powershell.

But with onedrive there are whitspaces in my path, how can I get it working?

Have found: https://community.jmp.com/t5/Discussions/Open-file-in-excel-with-whitespace-in-filename/m-p/911999?search-action-id=96030372702&search-result-uid=911999 in usergroup, but didn't help me.

Thanks!

Names Default To Here( 1 );

base_path = Get Default Directory(); // doesn't work
base_path = "C:\Users\"; // works

Show( base_path );
// e.g. base_path = "/C:/Users/user/OneDrive - Documents/";
// how to mask space in path??

command = Eval Insert( "dir ^base_path^" );
// command = eval insert("\[dir "^base_path^"]\"); // doesn't work
Show( command );

RP = Run Program(
	Executable( "cmd.exe" ),
	Options( Insert( {"/a", "/q", "/c"}, command ) ), 
//	ReadFunction( Function( {this}, Write( this << read ) ) )
	readfunction( "Text" )
);

Re: How to run program with whitespaces in path

jthi — Mon, 12 Jan 2026 08:18:58 GMT

Adding quotes around the path should work

Names Default To Here(1);

base_path = "C:\Program Files\"; // works

Show(base_path);

command = Eval Insert("dir \!"^base_path^\!"");
Show(command);

RP = Run Program(
	Executable("cmd.exe"),
	Options(Insert({"/a", "/q", "/c"}, command)), 
//	ReadFunction( Function( {this}, Write( this << read ) ) )
	readfunction("Text")
);

Re: How to run program with whitespaces in path

Georg — Mon, 26 Jan 2026 10:46:49 GMT

Hi Jarmo, thanks, your're right, I had a problem with the starting backslash as well.

Names Default To Here( 1 );

base_path = "C:\Program Files\"; // works
base_path = Get Default Directory();
// starting backslash makes problems, needs to be removed
// "/C:/Users/<user>/OneDrive - Documents/"
base_path = Substr( base_path, 2, Length( base_path ) );

command = Eval Insert( "dir \!"^base_path^\!"" );
Show( command );

RP = Run Program(
	Executable( "cmd.exe" ),
	Options( Insert( {"/a", "/q", "/c"}, command ) ), 
//	ReadFunction( Function( {this}, Write( this << read ) ) )
	readfunction( "Text" )
);

Re: How to run program with whitespaces in path

jthi — Mon, 12 Jan 2026 15:50:36 GMT

I would use Convert File Path() with "windows" argument to remove the first backslash

Names Default To Here(1);

base_path = Get Default Directory();

base_path_w = Convert File Path(base_path, "windows"); // "C:\Users\<USERNAME>\Documents\"