topic Re: Append tablebox under each charts in Discussions

Append tablebox under each charts

Jackie_ — Mon, 29 Dec 2025 14:24:07 GMT

How can I append a table box under each Control chart?

Trying to replicate like this...

dt = Open( "$SAMPLE_DATA/Semiconductor Capability.jmp" );
tabtypes = {"Tab1", "Tab2", "Tab3"};
cols = {:NPN1, ::PNP1, PNP2, :NPN2, :PNP3, :IVP1};
obj = (dt << Tabulate(

	Add Table(
		Column Table( Statistics( Mean, Std Dev, Median Absolute Deviation, Quantiles( 90 ), Mode ) ),
		Row Table( Analysis Columns( :NPN1, :PNP1, :PNP2, :NPN2, :PNP3, :IVP1 ) )
	)
)) << Make Into Data Table;
new = New Window( "Maverick Trends", <<movewindow( 200, 150 ), H List Box( Panel Box( , H List Box( tabttx = Tab Box() ) ) ) );
For Each( {gettabs, idd}, tabtypes, 

	
	tabttx << Add(
		Tab Page Box(
			Title( gettabs ),
			V List Box(
				For Each( {parameters, idx}, cols, 
				

                                                                                
                                                                                                
					vc1 = dt << Control Chart Builder(
						Size( 1294, 431 ),
						Connect Thru Missing( 1 ),
						Show Two Shewhart Charts( 0 ),
						Test Excluded Subgroups( 0 ),
						Include Missing Categories( 0 ),
						Show Excluded Region( 0 ),
						Show Limit Summaries( 0 ),
						Variables( Subgroup( :SITE ), Y( As Column( parameters ) ) ),
						Chart(
							Points( Statistic( "Individual" ), Show Connect Line( 1 ) ),
							Limits( Sigma( "Moving Range" ), Show Center Line( 0 ), Show Lower Limit( 0 ), Show Upper Limit( 0 ) )
						),
						Show Control Panel( 0 ),
						SendToReport(

							Dispatch( {}, "Control Chart Builder", OutlineBox, {Set Title( parameters )} ),
							Dispatch( {}, "graph display 1 title", TextEditBox, {Set Text( "" )} ),
							Dispatch( {}, "Date", ScaleBox, {Label Row( Label Orientation( "Angled" ) )} ),
							Dispatch( {}, "Subgroup display 1 title", TextEditBox, {Set Font Size( 10 ), Set Font Style( "Bold" )} ),
							Dispatch( {}, "Y display 1 title", TextEditBox, {Set Text( "" )} )
						)
                                                                                                
                                                                                                                
					);
                                                                                                                
						
                                                                                
                                
                                                
                                                                                                
				
                                                                                                                                
                                                                                                                                
                                                                                                                                
				);
                                                                
			)
                                                                                                
		)
	);
                
                
                
	For( i = 1, i <= N Rows( obj ), i++, 
		
                                
                                
                                
                                                                                
                                                
		
                                                                
			v_te = Try( obj:Analysis Columns[i], "N/A" );
			v_mean = Try( Char( Format( obj:Mean[i], "Best", 12, 2 ) ), "N/A" );
			v_std = Try( Char( Format( obj:Std Dev[i], "Best", 12, 2 ) ), "N/A" );
			v_med = Try( Char( Format( obj:Mediani, "Best", 12, 2 ) ), "N/A" );
				vc1 << append(
			Panel Box( "Stats Summary: ",
				Table Box(
    
					String Col Box( "Metric", v_te ),
					String Col Box( "Mean", v_mean ),
					String Col Box( "Std Dev", v_std ),
					String Col Box( "Median", v_med ), 
					
                                                                                                                                
                                                                                                                
				)
			)
                                                                                                                                
			;
		);

		
	)
                
                
	;
);

Re: Append tablebox under each charts

jthi — Mon, 29 Dec 2025 14:35:55 GMT

Names Default To Here(1);

dt = Open("$SAMPLE_DATA/Semiconductor Capability.jmp");
tabtypes = {"Tab1", "Tab2", "Tab3"};

cols = {:NPN1, :PNP1, :PNP2, :NPN2, :PNP3, :IVP1};

obj = (dt << Tabulate(
	Add Table(
		Column Table(Statistics(Mean, Std Dev, Median Absolute Deviation, Quantiles(90), Mode)),
		Row Table(Analysis Columns(:NPN1, :PNP1, :PNP2, :NPN2, :PNP3, :IVP1))
	)
)) << Make Into Data Table;

new = New Window("Maverick Trends",
	<<movewindow(200, 150),
	H List Box(Panel Box("", H List Box(tabttx = Tab Box())))
);

For Each({gettabs, idd}, tabtypes, 
	tabttx << Add(
		Tab Page Box(
			Title(gettabs),
			vlb = V List Box()
		)
	);
	
	For Each({parameters, idx}, cols, 
		vlb << Append(vc1 = dt << Control Chart Builder(
			Size(1294, 431),
			Connect Thru Missing(1),
			Show Two Shewhart Charts(0),
			Test Excluded Subgroups(0),
			Include Missing Categories(0),
			Show Excluded Region(0),
			Show Limit Summaries(0),
			Variables(Subgroup(:SITE), Y(As Column(parameters))),
			Chart(
				Points(Statistic("Individual"), Show Connect Line(1)),
				Limits(
					Sigma("Moving Range"),
					Show Center Line(0),
					Show Lower Limit(0),
					Show Upper Limit(0)
				)
			),
			Show Control Panel(0),
			SendToReport(Dispatch({}, "Control Chart Builder", OutlineBox, {Set Title(parameters)}),
				Dispatch({}, "graph display 1 title", TextEditBox, {Set Text("")}),
				Dispatch({}, "Date", ScaleBox, {Label Row(Label Orientation("Angled"))}),
				Dispatch({}, "Subgroup display 1 title", TextEditBox, {Set Font Size(10), Set Font Style("Bold")}),
				Dispatch({}, "Y display 1 title", TextEditBox, {Set Text("")})
			)
		);
		curcol = parameters << get name;
		r = obj << Get Rows Where(:Analysis Columns == curcol);
		
		If(N Items(r) > 0,
			vlb << append(
				Panel Box("Stats Summary: ",
					Table Box(
						String Col Box("Metric", obj[r, "Analysis Columns"]),
						Number Col Box("Mean", obj[r, "Mean"]),
						Number Col Box("Std Dev", obj[r, "Std Dev"]),
						Number Col Box("Median", obj[r, "Median"])
					)
				)
			);			
		);
	));
);

Re: Append tablebox under each charts

Jackie_ — Mon, 29 Dec 2025 15:04:59 GMT

~~Thanks Jarmo! This is being added above the chart, not below it.~~

It's working.. Thanks