topic Re: I am generating new column based on a user input and need to move in Discussions

I am generating new column based on a user input and need to move

ConfidenceOwl94 — Tue, 02 Dec 2025 21:45:47 GMT

I am generating new column based on a user input and need to move using script. Can anyone help to fix my script

dt << New Column("Suspected "|| selectedCol,
	Formula(
		If(Contains(myValueList, char(as column(selectedCol))), 
			"Yes", 
			"No" 
		)
	)
);
Data Table( dt ) << Move Selected Columns( as column("Suspected "|| selectedCol), after( as column(selectedCol) ) );

Re: I am generating new column based on a user input and need to move

mmarchandFSLR — Tue, 02 Dec 2025 22:22:52 GMT

I'm able to get it to work by enclosing As Column() in a Name Expr() and putting it in a list.

dt << Move Selected Columns(
	{Name Expr( As Column( "Suspected " || selectedCol ) )},
	After( As Column( selectedCol ) )
);

Re: I am generating new column based on a user input and need to move

mmarchandFSLR — Tue, 02 Dec 2025 22:27:05 GMT

This way works, too, with only the string in a list, but the After() has to have As Column().

dt << Move Selected Columns(
	{"Suspected " || selectedCol},
	After( As Column( selectedCol ) )
);

Re: I am generating new column based on a user input and need to move

txnelson — Tue, 02 Dec 2025 22:44:22 GMT

Here is how I got it to work

dt << New Column( "Suspected " || selectedCol,
	Character,
	Formula(
		If( Contains( myValueList, Char( As Column( selectedCol ) ) ),
			"Yes",
			"No"
		)
	)
);
Eval(
	Parse(
		"dt << Move Selected Columns(:Suspected " || selectedCol || ", after( :" ||
		selectedCol || ") );"
	)
);

Re: I am generating new column based on a user input and need to move

jthi — Wed, 03 Dec 2025 05:47:05 GMT

I would strongly suggest adding expression evaluation to your column to avoid possible issues (compare how my formula vs your formula looks like). You can also get reference to the created column and use that with <<Move Selected Column

Names Default To Here(1); 

dt = Open("$SAMPLE_DATA/Big Class.jmp");

selectedCol = "age";
myValueList = {"12", "15"};

newcol = Eval(EvalExpr(
	dt << New Column("Suspected "|| selectedCol, Character, Nominal, Formula(
		If(Contains(Expr(myValueList), Char(Expr(NameExpr(As column(dt, selectedCol))))),
			"Yes", 
			"No"
		)
	));
));

dt << Move Selected Columns(
	newcol, After(Eval(selectedCol))
);