topic Re: Is there a preference setting to hide legacy Control Chart warning? in Discussions

Is there a preference setting to hide legacy Control Chart warning?

SDF1 — Tue, 05 Aug 2025 13:03:13 GMT

Hello All,

JMP v18 users

I'm curious if anyone has found a JMP preferences setting to hide or remove the legacy CC warning that appears in JMP 18.

We have some JMP users that are running JSL code to build certain kinds of reports for customers, and they want to hide this warning, but don't want to have to hide it manually. I did find a scripting solution that hides the warnings here, which was posted in Sep 2024. I was just wondering if anyone has found a solution since that post was first created through the JMP > Preferences menu instead (the users are not that experienced with scripting).

Thanks!,

Re: Is there a preference setting to hide legacy Control Chart warning?

statman — Tue, 05 Aug 2025 13:36:52 GMT

Don't get me started. I'm not aware of any preference and I still don't understand why they are removing the traditional control chart platform.

Re: Is there a preference setting to hide legacy Control Chart warning?

scott_allen — Wed, 06 Aug 2025 15:44:05 GMT

@SDF1

EDIT: Oops, didn't read that the part about not wanting a scripting solution!

EDIT2: In EA19 there is a way to toggle off the alerts. The script below will still run and there is a toggle for the alert:

I don't think there is a way to hide the alerts in Preferences, but the warnings are just text boxes in the control chart report.

Here is one way to remove them:

names default to here(1);
dt = open( "$SAMPLE_DATA\Tablet Measurements.jmp");
cc = dt << Control Chart(
	Group Size( 1 ),
	KSigma( 3 ),
	Chart Col( :Weight, Individual Measurement, Moving Range ),
);

// find the text boxes
textboxes = report( cc ) << xpath( "//TextBox" );

// delete the text box if it contains "Legacy"
for each( {box}, textboxes,
	if( contains( box << get text, "Legacy" ), box << delete )
)

Re: Is there a preference setting to hide legacy Control Chart warning?

jthi — Wed, 06 Aug 2025 19:36:26 GMT

This might be one case where Global Window Handler could be used with with an add-in / toolbar item to create the handler (or use startup script).

Set Global Window Handler(
	Function({window},
		Local({tebs},
			tebs = window << XPath("//TextBox[text()='Legacy Control Charts are being removed in JMP 19. Please use Control Chart Builder from the Quality and Process menu instead.']");
			If(N Items(tebs) > 0,
				tebs << Visibility("Collapse");
				Write("\!N", N Items(tebs), " legacy text boxes hidden from ", window << Get Window Title);
				wait(0);
			);		
		);
	);
);

Run that script and then create legacy control chart to see how it works

Names Default To Here(1);

dt = Open("$SAMPLE_DATA\Tablet Measurements.jmp");
cc = dt << Control Chart(
	Group Size(1),
	KSigma(3),
	Chart Col(:Weight, Individual Measurement, Moving Range)
);

Write();

You could also just take the function from the window handler and use it as a function which users could use.

Names Default To Here(1);

hide_legacy_cc_text = Function({window}, {Default Local},
	tebs = window << XPath("//TextBox[text()='Legacy Control Charts are being removed in JMP 19. Please use Control Chart Builder from the Quality and Process menu instead.']");
	If(N Items(tebs) > 0,
		tebs << Visibility("Collapse");
		Write("\!N", N Items(tebs), " legacy text boxes hidden from ", window << Get Window Title);
		wait(0);
	);		
);


dt = Open("$SAMPLE_DATA\Tablet Measurements.jmp");
cc = dt << Control Chart(
	Group Size(1),
	KSigma(3),
	Chart Col(:Weight, Individual Measurement, Moving Range)
);

hide_legacy_cc_text(cc);

Re: Is there a preference setting to hide legacy Control Chart warning?

statman — Wed, 06 Aug 2025 22:46:35 GMT

Works great Jarmo! Now if we can get JMP 19 to add the platform back in...