topic Re: How to make closewise continuous polygon with matrix in Discussions

How to make closewise continuous polygon with matrix

PhamBao — Wed, 16 Jul 2025 14:11:47 GMT

Hi all,
x_matrix = [59, 60, 62, 64, 68, 70, 80, 118, 130, 182, 461, 678, 696, 700, 701, 701, 701];
y_matrix = [44.07, -44.31, 105.11, -66.88, 132.65, -88.02, -91.87, -104.49, 116.54, -106.6, -108.17, -55.48, -95.9, -93, -87.98, -87.47, -69.45];

I have matrix above. Is there any way to convert or sort them into continuous closewise polygon

If my matrix x and y are not from convex polygon, is there any way to do so

Thanks

Re: How to make closewise continuous polygon with matrix

txnelson — Wed, 16 Jul 2025 14:39:26 GMT

I am not exactly sure what is the context of your need for a polygon, however, if you look in the Scripting Index

Help=>Scripting Index

and then search on Polygon, you will see the definition and example of using the Polygon function.

Re: How to make closewise continuous polygon with matrix

Craige_Hales — Wed, 16 Jul 2025 20:06:48 GMT

this is close:

x_matrix = [59, 60, 62, 64, 68, 70, 80, 118, 130, 182, 461, 678, 696, 700, 701, 701, 701];
y_matrix = [44.07, -44.31, 105.11, -66.88, 132.65, -88.02, -91.87, -104.49, 116.54, -106.6, -108.17, -55.48, -95.9, -93, -87.98, -87.47, -69.45];
t = Triangulation( x( x_matrix, y_matrix ) );
order = t << gethullpoints;
xs = x_matrix[order];
ys = y_matrix[order];
dt = As Table( xs || ys );
Graph Builder(
	Size( 669, 491 ),
	Show Control Panel( 0 ),
	Variables( X( :Col1 ), Y( :Col2 ) ),
	Elements( Line( X, Y, Legend( 7 ), Ordering( "Row Order" ) ), Points( X, Y, Legend( 8 ) ) )
);

Search the scripting index for "hull" and you'll find the alpha shape function as well. the Triangulation function can also tell you about points inside the hull and how they form a Delaunay triangulation. If you care about clockwise vs counter clockwise, https://stackoverflow.com/questions/1165647/how-to-determine-if-a-list-of-polygon-points-are-in-clockwise-order

I'm at the limit of my understanding, but I'd be fascinated to learn more about what you are doing.

@danschikore

Re: How to make closewise continuous polygon with matrix

danschikore — Thu, 17 Jul 2025 13:31:35 GMT

Thanks for the example @Craige_Hales - alpha shapes are definitely interesting for cases like this, since @PhamBao mentioned non-convex solutions. When the input is a polygon, the results might not be quite what you expect. The example below demonstrates the use of alpha shapes on a set of points. The alpha shape is a subset of the Delaunay triangulation, which could include points, edges, and triangles. In JMP, the alpha shape is showing you the only the triangles. For alpha=0, you get the Delaunay triangulation and convex hull:

As you increase alpha, you can get a hole in the middle:

Increase further, and you can get shapes like this:

But the output will not be a polygonal hull if the original samples do not include interior points. I think this would require some additional post-processing to find the outer boundary polygon.

Names Default To Here( 1 );
x_matrix = [0.309016994374947, 0.470228201833979, 0.809016994374948, 0.760845213036123, 1, 0.760845213036123,
0.809016994374948, 0.470228201833979, 0.309016994374948, 0, -0.309016994374947, -0.470228201833978,
-0.809016994374948, -0.760845213036123, -1, -0.760845213036123, -0.809016994374948, -0.470228201833979,
-0.309016994374948, 0];
y_matrix = [0.951056516295153, 0.647213595499958, 0.587785252292473, 0.247213595499958, 0, -0.247213595499958,
-0.587785252292473, -0.647213595499958, -0.951056516295153, -0.8, -0.951056516295154, -0.647213595499958,
-0.587785252292473, -0.247213595499958, 0, 0.247213595499958, 0.587785252292473, 0.647213595499958,
0.951056516295153, 0.8];
t = Triangulation( x( x_matrix, y_matrix ) );
a = Alpha Shape( t );
a << Set Alpha( alpha = 0 );
Eval(
	Eval Expr(
		New Window( "alpha shape",
			Outline Box( "Alpha Shape Explorer",
				HListBox(TextBox("Alpha: "), slider = Slider Box( 0, 4, alpha )),
				graph = Graph Box(
					Frame Size( 300, 300 ),
					X Scale( -1, 1 ),
					Y Scale( -1, 1 ),
					Path( Expr( a << get hull path ) )
				)
			)
		)
	)
);
slider << Set Function(
	Function( {this},
		a << Set Alpha( alpha );
		Eval( Eval Expr( graph << Set Graphics Script( Path( Expr( a << Get Hull Path ) ) ) ) );
	)
);

Re: How to make closewise continuous polygon with matrix

Craige_Hales — Thu, 17 Jul 2025 18:03:00 GMT

@danschikore Thanks! I found this picture and first three paragraphs useful for understanding alpha shape: https://doc.cgal.org/latest/Alpha_shapes_2/

Here it is with some random points.

n=200;
x_matrix = j(n,1,randomuniform(-1,1));
y_matrix = j(n,1,randomuniform(-1,1));
t = Triangulation( x( x_matrix, y_matrix ) );
a = Alpha Shape( t );
a << Set Alpha( alpha = 0 );
Eval(
	Eval Expr(
		New Window( "alpha shape",
			Outline Box( "Alpha Shape Explorer",
				HListBox(TextBox("Alpha: "), slider = Slider Box( 0, 10, alpha )),
				graph = Graph Box(
					Frame Size( 300, 300 ),
					X Scale( -1, 1 ),
					Y Scale( -1, 1 ),
					Path( Expr( a << get hull path ) );
					marker(x_matrix,y_matrix)
				)
			)
		)
	)
);
slider << Set Function(
	Function( {this},
		a << Set Alpha( alpha );
		Eval( Eval Expr( graph << Set Graphics Script( Path( Expr( a << Get Hull Path ) );marker(x_matrix,y_matrix) ) ) );
	)
);

(view in My Videos)

Re: How to make closewise continuous polygon with matrix

PhamBao — Thu, 17 Jul 2025 20:02:03 GMT

@danschikore and @Craige_Hales @txnelson : appreciate all for your response and suggestion. All suggestions works for me

Re: How to make closewise continuous polygon with matrix

PhamBao — Thu, 17 Jul 2025 20:28:56 GMT

Hi @Craige_Hales and @Craige_Hales and @txnelson

Right now, my script is working by your help. I would like to ask another question about scripting since I am really good at in scripting.

In my data table, I have two columns called "FORCEDROPTIME_3" and "ACTUAL_MAXCHASEHOLDFORCE_4"

I uses code below to draw convex hull around all data point

tri = Triangulation( X( :FORCEDROPTIME_3, :ACTUAL_MAXCHASEHOLDFORCE_4), Y( :ACTUALHEIGHTHOLDTIME_2 ) );// get contour around all data point
hulledge= tri << Get Hull Edges;
hullpoint =tri << Get Hull Points;
{xx, yy} = tri << Get Points();
tri2 = tri << Subset( tri << Get Hull Points ); // get data point of boundary
{tri2_xx, tri2_yy} = tri2 << Get Points();

Then I draw convex hull in the box and copy content frame to graph builder

New Window( "Contour Seg Example",

g = Graph Box(

X Scale( Min( xx ) - .1, Max( xx ) + .1 ),

Y Scale( Min( yy ) - .1, Max( yy ) + .1 ),

Contour Seg(

tri,

[0, 400, 1000, 2000, 9000],

zColor( 5 + [64 32 0 16 48] ),

Transparency( [1, 1, 1, 1, 1] )

Shape Seg( {Path( ashape << Get Hull Path() )}, <<Set Color( "Red" ) ),

Shape Seg( {Path( tri << Get Hull Path() )}, <<Set Color( "Black" ) )

)

);

frame = g[FrameBox( 1 )];

fontobj = seg = (frame << Find Seg( Contour Seg( 1 ) ));

frame << Copy Frame Contents;

//graphbuilder

chartdisplay = dt << Graph Builder(

Size( 1011, 666 ),

Show Control Panel( 0 ),

Variables( X( :FORCEDROPTIME_3 ), Y( :ACTUAL_MAXCHASEHOLDFORCE_4 ) ),

Elements( Points( X, Y, Legend( 3 ) ), Smoother( X, Y, Legend( 4 ) ) ),

SendToReport(

Dispatch(

{},

"FORCEDROPTIME_3",

ScaleBox,

{Min( Min( xx ) ), Max( Max( xx ) ), Inc( 100 ), Minor Ticks( 1 )}

Dispatch(

{},

"ACTUAL_MAXCHASEHOLDFORCE_4",

ScaleBox,

{Min( min(yy) ), Max( Max(yy) ), Inc( 2 ), Minor Ticks( 1 )}

)

);

rbiv1 = chartdisplay << report;

framebox2 = rbiv1[Frame Box( 1 )];

frame << Copy Frame Contents;

framebox2 << Paste Frame Contents;

The result is

I have 2 questions;
1. Is there anyway that I could draw convex hull directly into graph builder?
2. In the graph builder chart, if I would like to exclude or remove data data points, How I could get new convex hull constantly updated in the graph. For example, if I use local filter of graph builder to filter some data points

--> how could I get new convex hull according to filtered data points
--> how could I get X and Y matrix of new convex hull directly

Appreciate!

Re: How to make closewise continuous polygon with matrix

PhamBao — Sat, 19 Jul 2025 05:48:53 GMT

Hi @danschikore , @Craige_Hales and @Craige_Hales
Based on your suggestion, it works for me. I also would like to ask some questions whether I could make script become more interactive. Since I am not really good at scripting, I would like to clarify what I want and hopefully I could get inputs and help from you guys
In my data table, I have 2 columns named "A" and "B" and then I use Triangulation to get convex hull of data points

Triangulation

After getting convex hull, I draw polygon in box and copy frame content to graph builder

1. Is there any way that I could get convent hull and draw it directly in graph builder
2. If I would like to exclude some data points, how I could get instant convex hull updated in graph builder as well as to get new convex hull data points

There is my script:

dt= Open( "ww17_DATAALL.CSV");

tri = Triangulation( X( :A, :B), Y( :C ) );

// get contour around all data point

hulledge= tri << Get Hull Edges;

hullpoint =tri << Get Hull Points;

{xx, yy} = tri << Get Points();

tri2 = tri << Subset( tri << Get Hull Points ); // get data point of boundary

{tri2_xx, tri2_yy} = tri2 << Get Points();

show(tri2_xx);

show(tri2_yy);

ashape = Alpha Shape(tri);

ashape << Set Alpha(0.01);

{ax, ay} = ashape << Get Points();

atri = ashape << Get Triangles;

ashape2 = ashape<< Subset( ashape<< Get Hull Points ); // get data point of boundary

{ashape2_xx, ashape2_yy} = ashape2 << Get Points();

show(ashape2_xx);

show(ashape2_yy);

New Window( "Contour Seg Example",

g = Graph Box(

X Scale( Min( xx ) - .1, Max( xx ) + .1 ),

Y Scale( Min( yy ) - .1, Max( yy ) + .1 ),

Contour Seg(

tri,

[0, 400, 1000, 2000, 9000],

zColor( 5 + [64 32 0 16 48] ),

Transparency( [1, 1, 1, 1, 1] )

Shape Seg( {Path( ashape << Get Hull Path() )}, <<Set Color( "Red" ) ),

Shape Seg( {Path( tri << Get Hull Path() )}, <<Set Color( "Black" ) )

)

);

frame = g[FrameBox( 1 )];

fontobj = seg = (frame << Find Seg( Contour Seg( 1 ) ));

frame << Copy Frame Contents;

//graphbuilder

chartdisplay = dt << Graph Builder(

Size( 1011, 666 ),

Show Control Panel( 0 ),

Variables( X( :A ), Y( :B ) ),

Elements( Points( X, Y, Legend( 3 ) ), Smoother( X, Y, Legend( 4 ) ) ),

SendToReport(

Dispatch(

{},

"A",

ScaleBox,

{Min( Min( xx ) ), Max( Max( xx ) ), Inc( 100 ), Minor Ticks( 1 )}

Dispatch(

{},

"B",

ScaleBox,

{Min( min(yy) ), Max( Max(yy) ), Inc( 2 ), Minor Ticks( 1 )}

)

);

rbiv1 = chartdisplay << report;

framebox2 = rbiv1[Frame Box( 1 )];

frame << Copy Frame Contents;

framebox2 << Paste Frame Contents;

Re: How to make closewise continuous polygon with matrix

Craige_Hales — Sun, 20 Jul 2025 03:07:50 GMT

sorry, the spam trap is aggressive today! I released both.

Re: How to make closewise continuous polygon with matrix

Craige_Hales — Sun, 20 Jul 2025 06:00:09 GMT

maybe this

dt = Open( "$SAMPLE_DATA/Big Class.jmp" );

New Window( "hull test",
	Data Filter Context Box( // from the scripting index: how to make a data filter. the 'f' is needed.
		H List Box(
			f = dt << Data Filter( Local, Mode( Show( 1 ), Include( 1 ) ), Add Filter( columns( :age ) ) ),
			gb = dt << Graph Builder(
				Size( 660, 491 ),
				Show Control Panel( 0 ),
				Variables( X( :weight ), Y( :height ) ),
				Elements( Points( X, Y, Legend( 5 ) ) ), 

			)
		)
	)
);

Report( gb )[framebox( 1 )] << Add Graphics Script(
	// this script runs when the display needs to redraw.
	rows = f << getfilteredrows; // get the currently chosen rows from the filter
	If( Is Empty( rows ),
		rows = 0; // handle the 'nothing selected' case; 0 means 'all rows'
	);
	x_matrix = dt[rows, {weight}];
	y_matrix = dt[rows, {height}];
	t = Triangulation( x( x_matrix, y_matrix ) ); // from the current rows
	{x_matrix, y_matrix} = t << get points; // rearranged from input order!
	order = t << gethullpoints;
	xs = x_matrix[order |/ order[1]]; // repeat 1st point to close the loop
	ys = y_matrix[order |/ order[1]];
	Line( xs, ys );
);

@danschikore - I think I made an error above when I didn't use <<getpoints with <<gethullpoints, even though it appeared to work. Using <<gethullpath makes it easier.

Re: How to make closewise continuous polygon with matrix

PhamBao — Mon, 21 Jul 2025 14:47:44 GMT

Hi @Craige_Hales ,

Thank for your help. It works

I try to edit the code a little bit, but it does work. Is there anyway that I could add slider into

Add Graphics Script

so that I could get value from slider as variable

Thanks

Re: How to make closewise continuous polygon with matrix

Craige_Hales — Mon, 21 Jul 2025 15:09:29 GMT

I think the script in our other thread does exactly that.
A slider box doesn't go *in* the graphics script. It is a display box that is in the new window. The variable that the slider box sets can be referenced in the script.

Re: How to make closewise continuous polygon with matrix

PhamBao — Fri, 25 Jul 2025 01:49:26 GMT

Hi @Craige_Hales,

If I get points ashape2_xx,ashape2_yy from ashape2 = ashape<< Subset( ashape<< Get Hull Points ); // get data point of boundary {ashape2_xx, ashape2_yy} = ashape2 << Get Points(), then I use polygon(ahsape2_xx, ashape2_yy) instead of Path(), polygon is not continuous Do you know how I could sort ashape2_xx anshape2_yy, so that I could draw continuous polygon from Polygon() syntax Thank a lot,

ashape = Alpha Shape(tri);
ashape << Set Alpha(0.01);
{ax, ay} = ashape << Get Points();
atri = ashape << Get Triangles;
ashape2 = ashape<< Subset( ashape<< Get Hull Points ); // get data point of boundary
{ashape2_xx, ashape2_yy} = ashape2 << Get Points();

Re: How to make closewise continuous polygon with matrix

Craige_Hales — Sun, 27 Jul 2025 03:07:16 GMT

It might be worth backing up and describing what you need to do (perhaps in a new question).

I've played with alpha shape for a while and think I understand what you are fighting with:

Both the <<get hull path and <<get hull points return a bunch of segments in scrambled order. Path covers up the problem by drawing all the segments using a move/draw for each; this makes 1 or more visual polygons, but not with a sequential border that works for filling a polygon. The points version returns the same data (as indexes into the <<getpoints data), and it can be used just like the path version...but again, not for filling.

If there is only a single outline for one polygon, it isn't too hard to sort the segments into a nice loop. If there are multiple polygons that don't share vertices, it is only a little harder. But if there are shared points between polygons the problem seems quite hard. If you turn the alpha up much, there will often be multiple polygons sharing points.

If you want to experiment with sorting the polygon edges into a loop, consider using a JSL list to hold the indexes. You can put the first edge in the list something like this

plist = {};
ie = 1; // index to an edge
from = hullEdges[ie, 1];
dest = hullEdges[ie, 2];
Insert Into( plist, from ); // append to empty list
Insert Into( plist, dest );

you can then walk through the hulledge matrix looking for edges that connect at the beginning or end of plist:

					found = 1;
					While( found,
						found = 0;
						For( je = 1, je <= ne, je += 1,
							testfrom = hullEdges[je, 1];
							testdest = hullEdges[je, 2];
								If(
									from == testdest, 
										// add to left end
										Insert Into( plist, testfrom, 1 );
										from = testfrom;
										pointCounts[testfrom] -= 1;
										pointCounts[testdest] -= 1;
										found = 1;//
								, /*else */ dest == testfrom, //
										// add to right end
										Insert Into( plist, testdest );
										dest = testdest;
										pointCounts[testfrom] -= 1;
										pointCounts[testdest] -= 1;
										found = 1;
								);
							);
						);
					);

If you successfully collect the indexes to the points, you can make a polygon, something like this:

// {x2, y2} = ashape2 << getPoints;
					// gather the polygon x and y matrices
					idx = plist;
					xdata = x2[idx];
					ydata = y2[idx];
					Transparency( .2 );
					Fill Color( HLS Color( (ie + 1) / ne, .5, 1 ) );
					Polygon( xdata, ydata, <<fill( 1 ) );

you might want something like this to check if there are points used by more than two edges:

			np = ashape2 << getnpoints;
			// most points are in 2 segs. some are in 4 segs.
			pointCounts = J( np, 1, 0 );
			If( N Rows( hullEdges ) > 0,pointCounts[hullEdges]++);
			
			If( !All( pointCounts == 2 ),
				Print( "too complicated" )
			);

That middle statement uses a 2-d matrix to index a matrix of counts and increment the counts 0, 2, or 4 times.

if you have multiple polygons, you might need to keep up with which points have been used already and wrap another JSL loop around your code to find a new starting point.

Re: How to make closewise continuous polygon with matrix

PhamBao — Sun, 03 Aug 2025 04:10:20 GMT

Hi @Craige_Hales ,
Thank your instruction. I try to follow your instruction to create my code. Since I'm not good at coding, what is

pointCounts

Could you give me a full code?
Sincerely

Re: How to make closewise continuous polygon with matrix

Craige_Hales — Sun, 03 Aug 2025 11:58:39 GMT

The "J" function creates a matrix, so
pointCounts = J( np, 1, 0 );
Makes a np rows by 1 col matrix initialized to 0.
The next statement,
If( N Rows( hullEdges ) > 0,
pointCounts[hullEdges]++)
Checks if there are any edges in hulledges (also a matrix with 2 cols for the from and to vertices). If so, every point index in hulledges is used as an index into pointcounts. Most points occur twice (connecting two edges ), resulting in a count of 2. Some occur 4 if two polys touch at that point. Some occur 0 times in hulledges if they are not in a poly with edges.
You'll need to write and maintain this code; this community, the scripting index in the help menu, and the jsl scripting guide are great resources for the low level parts.

Re: How to make closewise continuous polygon with matrix

Craige_Hales — Sun, 03 Aug 2025 22:36:58 GMT

You don't have to use the pointcounts at all if you know there is exactly one polygon. You can comment out those statements to get started.

When your data makes multiple polygons that touch, you might want to know. The pointcounts will help you write the code to handle that case.

The 4th block of code should be first to set up the total counts if you need them.

The 2nd block is an example of using the counts by decrementing them after they are used. You might do that to help figure out which points are still not used up when ordering the edges of the polygons.

In the video, way above, you can see a frame with islands and holes. I've colored it by hand, maybe correctly. Blue is "in", tan is "out". The hard part will be dealing with polygons like 1 and 2.

If you never push the alpha parameter far enough to make islands and holes, then you only have a single continuous outline and the code above should sort it so it works with the polygon command.

Re: How to make closewise continuous polygon with matrix

PhamBao — Wed, 06 Aug 2025 00:57:50 GMT

Hi Craige_Hales,
I try to use your code as reference and apply it into my own



dt= Open( "C:\Users\lamquocb\OneDrive - Intel Corporation\Desktop\Python Script\Regression\RPLP682\trial.jmp");



//
tri = Triangulation( X( :FORCEDROPTIME_3, :ACTUAL_MAXCHASEHOLDFORCE_4), Y( :ACTUALHEIGHTHOLDTIME_2 ) );


// get contour around all data point
hulledge= tri << Get Hull Edges;
hullpoint =tri << Get Hull Points;
{xx, yy} = tri << Get Points();
tri2 = tri << Subset( tri << Get Hull Points ); // get data point of boundary
{tri2_xx, tri2_yy} = tri2 << Get Points();

////////////

ashape = Alpha Shape(tri);
ashape << Set Alpha(0.01);
{ax, ay} = ashape << Get Points();
atri = ashape << Get Triangles;
ashape2 = ashape<< Subset( ashape<< Get Hull Points ); // get data point of boundary
{ashape2_xx, ashape2_yy} = ashape2 << Get Points();


hullEdges=ashape << Get Hull Edges;
plist = {};
ie = 1; // index to an edge
from = hullEdges[ie, 1];
dest = hullEdges[ie, 2];
Insert Into( plist, from ); // append to empty list
Insert Into( plist, dest );
found = 1;
					While( found,
						found = 0;
						For( je = 1, je <= N Items(hullEdges), je += 1,
							testfrom = hullEdges[je, 1];
							testdest = hullEdges[je, 2];
								If(
									from == testdest, 
										// add to left end
										Insert Into( plist, testfrom, 1 );
										from = testfrom;
										
										found = 1;//
								, /*else */ dest == testfrom, //
										// add to right end
										Insert Into( plist, testdest );
										dest = testdest;
									
										found = 1;
								);
							);
						);

However I got the error :

invalid subscript (must be number or list of numbers) in access or evaluation of 'hullEdges[ /*###*/je,1]' , hullEdges[/*###*/je, 1]

Typically if I actual number into hullEdge[1,2] as an example instead of hullEdges[je, 2], I got the result returns

Do you have any idea to resolve the issue?

Re: How to make closewise continuous polygon with matrix

Craige_Hales — Wed, 06 Aug 2025 02:21:59 GMT

@Audrey_Shull

JMP's error message makes the problem hard to understand. it should say

"the first index to hulledges[ 33, 2 ] is 34 and out of bounds"

nitems returns the total number of elements, not the number of rows.

change

For( je = 1, je <= N Items(hullEdges), je += 1,

For( je = 1, je <= N Rows(hullEdges), je += 1,