topic Re: How to add a connection between the first point and the last point in this diagram? in Discussions

How to add a connection between the first point and the last point in this diagram?

lala — Thu, 26 Jun 2025 12:44:56 GMT

Thanks Experts!

dt=Open("$SAMPLE_DATA/Big Class.jmp");
Graph Builder(
	Variables( X( Transform Column( "Row", Formula( Row() ) ) ), Y( :weight ) ),
	Elements( Points( X, Y, Legend( 6 ) ) ),
	SendToReport(
		Dispatch(
			{},
			"400",
			ScaleBox,
			{Legend Model(
				6,
				Properties( 0, {Marker Size( 2 )}, Item ID( "weight", 1 ) )
			)}
		)
	)
)

Re: How to add a connection between the first point and the last point in this diagram?

jthi — Thu, 26 Jun 2025 13:19:56 GMT

Names Default To Here(1);

dt = Open("$SAMPLE_DATA/Big Class.jmp");
gb = dt << Graph Builder(
	Variables(X(Transform Column("Row", Formula(Row()))), Y(:weight)),
	Elements(Points(X, Y, Legend(6))),
	SendToReport(
		Dispatch({}, "400", ScaleBox,
			{Legend Model(6, Properties(0, {Marker Size(2)}, Item ID("weight", 1)))}
		)
	)
);


fb = Report(gb)[FrameBox(1)];
ms = fb << Find Seg(MarkerSeg(1));
xs = ms << Get X Values;
ys = ms << Get Y Values;

fb << Add Graphics Script(
	Line({xs[1], ys[1]}, {xs[N Items(xs)], ys[N Items(ys)]})
);

Re: How to add a connection between the first point and the last point in this diagram?

hogi — Thu, 26 Jun 2025 21:44:24 GMT

Via right Click you can add a Transform Column to Graph Builder

Use it to keep the first and last data point.
Then use the Line Plot to connect the 2 points.

if you don't want to see the lines between the original data points,

you can disable them:

The final graph:

Names Default To Here(1);

dt = Open("$SAMPLE_DATA/Big Class.jmp");
Graph Builder(
	Transform Column(
		"Transform[weight]",
		Formula( If( Row() == 1 | Row() == N Rows(), :weight ) )
	),
	Transform Column( "Row", Formula( Row() ) ),

	Variables( X( :Row ), Y( :weight ), Y( :"Transform[weight]"n, Position( 1 ) ) ),
	Elements( Points( X, Y( 1 ), Y( 2 ), Legend( 6 ) ), Line( X, Y( 2 ) ) )
);

Re: How to add a connection between the first point and the last point in this diagram?

lala — Thu, 26 Jun 2025 22:51:33 GMT

dt = Open("$SAMPLE_DATA/Big Class.jmp");
Graph Builder(
	Transform Column(
		"Transform[weight]",
		Formula( If( Row() == 1 | Row() == N Rows(), :weight ) )
	),
	Transform Column( "Row", Formula( Row() ) ),
	Size( 570, 698 ),
	Variables( X( :Row ), Y( :weight ), Y( :"Transform[weight]"n, Position( 1 ) ) ),
	Elements(
		Points( X, Y( 1 ), Y( 2 ), Legend( 1 ) ),
		Smoother( X, Y( 2 ), Legend( 5 ) )
	),
	SendToReport( Dispatch( {"Smoother"}, "", OutlineBox, {Close( 0 )} ) )
);

Thanks!

Re: How to add a connection between the first point and the last point in this diagram?

hogi — Fri, 27 Jun 2025 04:38:11 GMT

Yes, with two points, instead of Line, one can also use Smoother to connect the points.
The trick is again to use a Transform Column to dynamically generate the additional information (first an last point?).

Transform Column + checkmarks in the Variables menu: I love it!

Here, the line is a standard plot "element" and shows up in the legend.
This is why I prefer to use Transform Columns compared to other approaches / workarounds.

With the interactive capabilities of Graph builder, for colleagues without the knowledge about the plumbing layer in the background, it just behaves like any other plot element:

It can be selected and it's settings can be adjusted via the legend menu.

Actually, it doesn't behave EXACTLY like any other plot element.
Just add a Column switch - and it will behave "strange" / "surprisingly" for users who don't know the details on the plumbing layer.
If the user switches to "height" - the Transform Column will NOT:

is a wish that addresses this interplay between column switcher and Transform Columns.

For this special case here, one can fix the issue easily - by generating a Transform Column for the X values instead of the Y values.
In general, it takes some effort (e.g. a column switch handler an an additional table variable: ) to fix the interplay between Column Switcher and Transform Columns in the current version of JMP.

On the other extreme, for users with access / knowledge to the plumbing layer, there are other restrictions:
With some tiny the framework could made much more powerful!