topic Re: How to Select a quota sample from a data set in Discussions

How to Select a quota sample from a data set

Samira — Thu, 05 Dec 2024 05:28:16 GMT

Hello everyone

I am working on a research that implies working on a representative sample. I have already collected data, but I need to select a subset that fulfills the representation criteria that are 4: The sample should be with the following quotas to be met:
-
on gender: 50% males and 50% females.
-
on age: 1/3 from 18 to 30 years old, 1/3 from 31 to 50 years old and 1/3 over 51 years old.
-
on household income level: 1/3 from low , 1/3 from medium 7 and 1/3 from high .

1/5 of study population by each of the five regions of the city (North, South, Centre, East and West)

How can I create this sample?

I am using JMP pro 17

Re: How to Select a quota sample from a data set

hogi — Thu, 05 Dec 2024 13:59:56 GMT

sounds like a textbook exercise - is there a chapter with the solution?

Re: How to Select a quota sample from a data set

Samira — Fri, 06 Dec 2024 05:22:12 GMT

No
I actually was discussing this issue with a colleague to start the data analysis of a project with this quota sampling technique.

Re: How to Select a quota sample from a data set

txnelson — Fri, 06 Dec 2024 06:34:06 GMT

This is a complex problem. How large is your data table you are pulling data from. What size of a sample are you pulling? You have 90 combinations of your 4 columns. Did you and your colleague come up with and idea on how to approach the problem?

Re: How to Select a quota sample from a data set

hogi — Fri, 06 Dec 2024 08:25:25 GMT

And you don't want to pick the sample data by the actual share of the distribution, but by the artificial fraction?

How about female, > 51yrs, high income, north.
Should it be 1/2 * 1/3 * 1/3 * 1/5? (*)
This is very easy to compute - but maybe too strict - and not intended?
Just think of the case where there is no female, > 51yrs, high income, north in the original distribution.

On the other hand: If just the 1/2, 1/3, 1/3 and 1/5 have to be fulfilled, one could make up extreme cases with 0 sample data for female, > 51yrs, high income, north.

Re: How to Select a quota sample from a data set

dlehman1 — Fri, 06 Dec 2024 13:07:07 GMT

This is not elegant and I'm not even sure it will work, but it might. You can create 0,1 columns for each of your criteria and then combine them into a single 0,1 column where 1 means that all of the individual criterion columns were =1. That will give the desired subset. And, if you want a random selection from such rows, just use a validation column stratified by that 0,1 column. As I said, not elegant but might work.

Re: How to Select a quota sample from a data set

hogi — Fri, 06 Dec 2024 20:59:22 GMT

data table - ideal case:

New Table( "quota_samples",
	Add Rows( 100000 ),
	Compress File When Saved( 1 ),
	New Column( "gender",
		Character,
		Formula( Match( Floor( Random Uniform() * 2 ), 0, "M", "F" ) ),
		Compact(),
		Set Selected
	),
	New Column( "income",
		Character,
		Formula(
			Match( Floor( Random Uniform() * 3 ), 0, "low", 1, "medium", "high" )
		),
		Compact()
	),
	New Column( "region",
		Character,
		Formula(
			Match( Floor( Random Uniform() * 5 ),
				0, "N",
				1, "S",
				2, "W",
				3, "E",
				"C"
			)
		)
	),
	New Column( "age",
		Character,
		Formula(
			Match( Floor( Random Uniform() * 3 ), 0, "young", 1, "medium", "old" )
		)
	)
)

Re: How to Select a quota sample from a data set

hogi — Sun, 08 Dec 2024 12:11:41 GMT

For such an ideal table, (if the probabilities of your data set fit to the fractions you want), you can pick random samples - random samples per variant or a specific number of samples per variant - or a combination of all 3 ...
you will always get the subgroups with the requested fraction (1/2, 1/3, 1/3 and 1/5)

// random sampling : full data set
if(not(current data table() << has column ("cum_prob")),New Column( "cum_prob",
	Formula(
		Col Rank( random uniform()) / (
		Col Number( 1 ))
	)
));

// random sampling : per variant
if(not(current data table() << has column ("cum_prob_indiv")),New Column( "cum_prob_indiv",
	Formula(
	tmp = random uniform(); // tmp =1; // **)
		Col Rank( tmp, :gender, :income, :region, :age ) / (
		Col Number( tmp, :gender, :income, :region, :age ))
	)
));

// force ratios: 1/2, 1/3, 1/3, 1/5
if(not(current data table() << has column ("rank_indiv")),
New Column( "rank_indiv",
	Formula( Col Rank( random uniform(), :gender, :income, :region, :age ) )
));

Graph Builder(
	Size( 518, 448 ),
	Show Control Panel( 0 ),
	Graph Spacing( 4 ),
	Variables( X( :gender ), X( :income ), X( :region ), X( :age ) ),
	Elements( Position( 1, 1 ), Bar( X,  Summary Statistic( "N" ) ) ),
	Elements( Position( 2, 1 ), Bar( X,  Summary Statistic( "N" ) ) ),
	Elements( Position( 3, 1 ), Bar( X,  Summary Statistic( "N" ) ) ),
	Elements( Position( 4, 1 ), Bar( X,  Summary Statistic( "N" ) ) ),
	Local Data Filter(
        Title( "how many samples do you want ? " ),
		Add Filter(
			columns( :cum_prob, :cum_prob_indiv, :rank_indiv )
		)
	)
);

**) instead of using CDFs with random uniform(), one can randomizing the row order and use CDFs of "1".

Re: How to Select a quota sample from a data set

hogi — Fri, 06 Dec 2024 21:12:29 GMT

The last option also works for less systematic tables like the one below.
The only limitation: if there are few samples for one of the variants, there is this clear limit to the number of samples that can be selected.

It follows the simple rule:
If for one of the variants (A), there are just N samples, take those and pick the same number of random samples from the other variants. Actually, for variant A, this is NOT "sampling".
So, maybe pick just M << N random samples from each of the 90 variants.
You can take the same (JSL) logic - just adjust N to a lower value.

(view in My Videos)

variants = {};
For Each( {gender}, {"F", "M"},
	For Each( {age}, {"young", "medium", "old"},
		For Each( {income}, {"low", "medium", "high"},
			For Each( {region}, {"N", "S", "E", "W", "C"},
				Insert Into( variants, Concat Items( {gender, age, income, region} ) )
			)
		)
	)
);

	Eval(
		Eval Expr(
		new table(
	"unfair",
	add rows( 100000 ), 
	

			New Column( "variant",Character,
				formula(
					variants = As constant(Expr( variants ));
					Try(
						variants[Floor( Random Normal( 45, 30 ) )],
						"F young medium C"
					);
				)
			),
			
			New column ("gender",Character, formula(Word(1,:variant))),
			New column ("age",Character, formula(Word(2,:variant))),
			New column ("income",Character, formula(Word(3,:variant))),
			New column ("region",Character, formula(Word(4,:variant))),
		)
	)
);

Re: How to Select a quota sample from a data set

txnelson — Fri, 06 Dec 2024 15:33:23 GMT

I spent a good deal of time pondering this question, and did not come up with a good answer. I did generate a sample data table similar to @hogi. Below is modification to @hogi JSL with my code that I used. Basically, I think it is easier to read, and in the case of Age, it better represents the distribution as stated by @Samira .

New Table( "Samp",
	Add Rows( 100000 ),
	Compress File When Saved( 1 ),
	New Column( "gender",
		Character,
		Set Each Value( Match( Random Integer( 1, 2 ), 1, "Male", "Female" ) ),
		Compact()
	),
	New Column( "income",
		Character,
		Set Each Value(
			Match( Random Integer( 1, 3 ), 1, "Low", 2, "Medium", "High" )
		),
		Compact()
	),
	New Column( "region",
		Character,
		Set Each Value(
			Match( Random Integer( 1, 5 ),
				1, "North",
				2, "South",
				3, "West",
				4, "East",
				"Ccentre"
			)
		)
	),
	New Column( "age",
		Character,
		Set Each Value(
			temp = Random Integer( 18, 80 );
			If(
				temp <= 30, "Young",
				temp <= 50, "Middle Age",
				"Old"
			);
		)
	)
)

Re: How to Select a quota sample from a data set

Samira — Sat, 07 Dec 2024 05:41:32 GMT

Thanks for your reply

The idea is to conduct the research on a representative sample to the population living in the whole city

Re: How to Select a quota sample from a data set

Samira — Sat, 07 Dec 2024 06:18:47 GMT

Many thanks for your efforts

Your suggestion gave me a good idea to explore my dataset effectively by using local data filter in the graph builder first. For my data it seems that with some combinations (such as middle aged males living in the center region with IM income) the sample is 0

The whole idea of creating a representative sample by this way seems now to be not practical. The sampling technique that should have been used from the beginning is one of the Probability sampling techniques. May be Stratified Random Sampling, using only the 5 regions as strata. Then a random sample is collected from each strata.

Re: How to Select a quota sample from a data set

Samira — Sat, 07 Dec 2024 06:20:09 GMT

Many thanks for your time and efforts

Re: How to Select a quota sample from a data set

Samira — Sat, 07 Dec 2024 06:23:03 GMT

Thanks for your reply

I think you are right,

Re: How to Select a quota sample from a data set

txnelson — Sat, 07 Dec 2024 06:28:07 GMT

That sounds like a reasonable approach

Re: How to Select a quota sample from a data set

hogi — Sat, 07 Dec 2024 15:55:08 GMT

So, what you asked for in the original post is :

disproportionate stratified random sampling, right?

And the strata are the 90 subgroups of gender x age x income x region.

Re: How to Select a quota sample from a data set

Samira — Sun, 08 Dec 2024 09:24:10 GMT

After carefully revising different sampling techniques in textbooks, I found that my original idea did not fit with any of them. To get a representative sample you should choose one of the probability sampling techniques ( that offer each respondent of the study population an equal probability or chance of being included in the sample). These techniques include 4 types:

–Simple random sampling
–Systematic sampling
–Cluster sampling
–Stratified sampling

That's why I think stratified sampling could have been used to get the study sample from the beginning ( using only the 5 regions as strata. Then, a random sample is collected from each stratum). The stratified, cluster, and quota sampling techniques require classifying the population into mutually exclusive groups, which is not the situation in my question. That's why I think my original question is not correct in the first place.

Re: How to Select a quota sample from a data set

hogi — Sun, 08 Dec 2024 09:50:37 GMT

Hm, when we compare this case with DOE...

In a nicely designed DOE one doesn't even pick a (single) sample from each of the 90 subsets.

[1 sample from each of the 90 subsets: "full-factorial" -> way to "expensive"]

So, maybe together with some simplification of the model, here it's also OK to use a data set with missing entries in some intersection points? And a step further, maybe by intentionally removing (some data points from) some intersection points, one can get something useful between stratified input data and a balanced DOE?

@Victor_G might have a suggestion?

Re: How to Select a quota sample from a data set

hogi — Sun, 08 Dec 2024 12:06:19 GMT

Re: How to Select a quota sample from a data set

hogi — Sun, 08 Dec 2024 14:07:07 GMT

For the approach "random sampling - per variant" from
https://community.jmp.com/t5/Discussions/How-to-Select-a-quota-sample-from-a-data-set/m-p/821078/highlight/true#M100011

I created a JSL snippet to stratify arbitrary data - just select the columns and click OK.

librecall can be downloaded here:

Names Default To Here( 1 );
verbose=0;
//Include( ".\libRecall_v2.jsl" );

objects = {"si^myCols", "s^Ncolumns", "s^Nfolds"};
values = {{}, {1}, {5}};
Try( // issue with projects
	librecall:genArrays( objects, values, "Stratify", verbose )
);

dt = Current Data Table();

nw = New Window( "K Fold Creator",
	<<Type( "Modal Dialog" ),
	<<Return Result,
	<<On Validate(
		If( N Items( myCols << get items() ),
			1,
			Caption( "please select a column" );
			0;
		)
	),
	V List Box(
		Lineup Box( N Col( 2 ),
			Panel Box( "", fcs = Filter Col Selector() ),
			Panel Box( "",
				Lineup Box( N Col( 2 ),spacing( 3 ),
					Button Box( "stratify by", myCols << append( fcs << get selected ) ),
					myCols = Col List Box( width( 200 ), min items( 1 ), nlines( 11 ) )
				), 
				
				Lineup Box( N Col( 2 ), spacing( 3 ),
					Text Box( "create more than 1 column?" ),
					Ncolumns = Number Edit Box(
						1,
						4,
						<<setintegeronly( 1 ),
						<<setminimum( 1 ), 

					),
					Text Box( "Number of Folds (K)" ),
					Nfolds = Number Edit Box( 5, 4, <<setintegeronly( 1 ), <<setminimum( 2 ) )
				), 

			)
		), 
		
		H List Box(
			Button Box( "OK",
				librecall:storeRoles( "Stratify", verbose );
				// the modal dialog stores the selected columns.
				For Each( {item}, 1 :: N Items( myCols << Get Items() ), myCols << Set Selected( item, 1 ) );
			),
			Button Box( "recall", librecall:recallRoles( "Stratify", verbose ) ),
			Button Box( "clear", librecall:resetRoles( "Stratify", verbose ) ),
			Button Box( "cancel" )
		)
	)
);

If( Not( nw["button"] == 1 ),
	Stop()	
);


myCols = Transform Each( {col}, nw["myCols"], Name Expr( As Column( col ) ) );
// remove continuous and exotic values.
myCols = Filter each({col}, myCols, col << Get Modeling Type == "Nominal" | col << Get Modeling Type == "Ordinal" );

For( i = 1, i <= nw["Ncolumns"], i++, 

	rankExpr = Expr(
		Col Rank( tmp, Excluded() )
	);
	For Each( {col}, myCols, Insert Into( rankExpr, Name Expr( col ) ) );
	numberExpr = Substitute( Name Expr( rankExpr ), Expr( Col Rank() ), Expr( Col Number() ) );

	Eval(
		Substitute(
				Expr(
					New Column( "Fold",
						Formula(
							If( Excluded(),
								.,
								tmp = Random Uniform();
								Floor( (_rank_ - 1) / (_number_) * _folds_ ) + 1;
							)
						)
					)
				),
			Expr( _rank_ ), Name Expr( rankExpr ),
			Expr( _number_ ), Name Expr( numberExpr ),
			Expr( _folds_ ), nw["Nfolds"]
		)
	);
);