//1. Ouverture d’une table de données que l’on va remplir
dt = Open("/D:/Project JMP/Tables Données/TableData.jmp");

//2. Sélection d’une date à partir de laquelle on récupère les données
//Variable Date (01/01/2016)

var_date = 3534464856;

//3. Suppression des anciennes données de la table
dt:leid << Set Selected (1);

dt << Invert Column Selection;
dt << Delete Columns();

dt << Select All Rows();
dt << Delete Rows();


//4. Import des données depuis les fichiers sources .csv 

mfi = Multiple File Import(
			<<Set Folder( "L:\Production\Data_Base\" ),
			<<Set Show Hidden( 0 ),
			<<Set Subfolders( 1 ),
			<<Set Name Filter( "*.csv" ),
			<<Set Name Enable( 1 ),
			<<Set Size Filter( {1, .} ),
			<<Set Size Enable( 1 ),
			<<Set Date Filter( {var_date, .} ),
			<<Set Date Enable( 1 ),
			<<Set Add File Name Column( 1 ),
			<<Set Add File Size Column( 0 ),
			<<Set Add File Date Column( 0 ),
			<<Set Import Mode( "CSVData" ),
			<<Set Charset( "Meilleure supposition" ),
			<<Set Stack Mode( "Stack Similar" ),
			<<Set CSV Has Headers( 1 ),
			<<Set CSV Allow Numeric( 1 ),
			<<Set CSV First Header Line( 1 ),
			<<Set CSV Number Of Header Lines( 1 ),
			<<Set CSV First Data Line( 2 ),
			<<Set CSV EOF Comma( 0 ),
			<<Set CSV EOF Tab( 0 ),
			<<Set CSV EOF Space( 0 ),
			<<Set CSV EOF Spaces( 0 ), 
			<<Set CSV EOF Other("|"),
			<<Set CSV EOL CRLF( 1 ),
			<<Set CSV EOL CR( 1 ),
			<<Set CSV EOL LF( 1 ),
			<<Set CSV EOL Semicolon( 0 ),
			<<Set CSV EOL Other( "" ),
			<<Set CSV Quote( "\!"" ),
			<<Set CSV Escape( "" ),
			<<Set XML Method( "guess" ),
			<<Set XML Guess( "huge" ),
			<<Set XML Settings( XML Settings() ),
			<<Set JSON Method( "guess" ),
			<<Set JSON Guess( "huge" ),
			<<Set JSON Settings( JSON Settings() ),
			<<Set Import Callback( Empty() )
		);


dt_list = mfi << Import Data;

//5. Première mise en forme des données brutes

for(i=1, i<=N Items(dt_list), i++,

	dt_list[i] << Show Window (0);
	
	
	names_dti_columns = dt_list[i] << Get Column Names(string);
	
	
	dt_list[i] << Select Where (Contains(:Nom de fichier, "ID_1")!=0);
	dt_list[i] << Delete Rows ();
	
	dt_list[i] << Select Where (Contains(:Nom de fichier, "GOLDEN")!=0);
	dt_list[i] << Delete Rows ();
	
	
	nameFiles = Associative Array( Column( dt_list[i], "Nom de fichier" ) << Get Values ) << Get Keys;

	for(k=1, k<=N Items(nameFiles), k++,
		dt_list[i]<< Select Where(:Nom de fichier == nameFiles[k]);
		r = dt_list[i] << Get Selected Rows();
		last = r[N Items(r)];
		last_date = Num(Char(dt_list[i]:Date[last]));
		diff = Date Difference( var_date, last_date, "Day", "start");
		if(diff<=0,
			dt_list[i] << Delete Rows();
		)
	);
	
	//Selection des lignes en double
	dt_list[i]:Nom de fichier << Set Selected (1);
	dt_list[i] << Invert Column Selection;
	dt_list[i] << Select Duplicate Rows();
	dt_list[i] << Delete Rows ();
	
	//Compression des colonnes
	dt_list[i] <<  Select Columns( all );
	dt_list[i] << Compress Selected Columns();

	//Concaténation à la table principale
	dt << Concatenate(
		dt_list[i],
		Append To First Table
	);
		
	//Fermeture du fichier source
	Close(dt_list[i]);
);

//6. Compression et sauvegarde de la table  

dt <<  Select Columns( all );
dt << Compress Selected Columns();
dt << Save();
Close(dt);
Exit(NoSave);